Outlook. Ինչպե՞ս ավտոմատ կերպով նորից ուղարկել էլփոստը, եթե պատասխան չկա

Երբ նամակ եք ուղարկում ձեր գործընկերոջը կամ կոոպերատիվ գործընկերոջը կամ ինչ-որ մեկին և շտապ պատասխանի կարիք ունեք, կարող եք կարգավորել էլփոստի ավտոմատ վերաուղարկման կարգավորումը, եթե պատասխանը չի հասել սահմանված ժամից շուտ:

Օգտագործելով Reminder-ը և VBA-ն՝ ավտոմատ վերաուղարկելու համար, եթե պատասխան չկա

Օգտագործելով Reminder-ը և VBA-ն՝ ավտոմատ վերաուղարկելու համար, եթե պատասխան չկա

Մաս 1. սահմանեք հիշեցում, որը հիշեցնում է նշված ժամանակում

1. Աջ սեղմեք էլփոստի վրա (Ուղարկված իրեր պանակից), որը ցանկանում եք նորից ուղարկել, եթե պատասխան չկա, բացվող համատեքստի ընտրացանկում սեղմեք Հետեւեք Up > Ավելացնել հիշեցում.

2. Բռնում Սովորություն երկխոսություն, պահիր Հիշեցում Նշեք վանդակը, այնուհետև ներքևի բացվող վանդակներում ընտրեք ամսաթիվ և ժամը, որից ցանկանում եք, որ պատասխանը ստացվի, ինչպես նաև կարող եք ուղղակիորեն մուտքագրել ամսաթիվը և ժամը վանդակներում: Սեղմել OK.

Մաս 2. Տեղադրեք VBA՝ նամակները նորից ուղարկելու համար, եթե նշված ժամանակում պատասխան չլինի

3. Մամուլ ալտ + F11 ստեղները ՝ Microsoft Visual Basic հավելվածների համար պատուհան.

4. Կրկնակի սեղմում ԱյսOutlookSession- ը է Նախագիծ – Նախագիծ 1 պատուհան՝ դատարկ սկրիպտ ստեղծելու համար, և պատճենեք և տեղադրեք ստորև VBA կոդը դատարկ սցենարի մեջ:

VBA. Եթե պատասխան չկա, նորից ուղարկեք էլ

Public WithEvents GInboxItems As Outlook.Items
'UpdatebyExtendoffice20220413
Private Sub Application_Startup()
  Dim xInboxFld As Folder
  Set xInboxFld = Application.Session.GetDefaultFolder(olFolderInbox)
  Set GInboxItems = xInboxFld.Items
End Sub

'Judge
Private Sub GInboxItems_ItemAdd(ByVal Item As Object)
  Dim xSentItems As Outlook.Items
  Dim xMail As MailItem
  Dim i As Long
  Dim xSubject As String
  Dim xItemSubject As String
  Dim xSendTime As String
  On Error Resume Next
  Set xSentItems = Application.Session.GetDefaultFolder(olFolderSentMail).Items
  If Item.Class <> olMail Then Exit Sub
  For i = xSentItems.Count To 1 Step -1
    If xSentItems.Item(i).Class = olMail Then
      Set xMail = xSentItems.Item(i)
      xSubject = LCase(xMail.Subject)
      xSendTime = xMail.SentOn
      xItemSubject = LCase(Item.Subject)
      If (xItemSubject = "re: " & xSubject) Or (InStr(xItemSubject, xSubject) > 0) Then
        If Item.SentOn > xSendTime Then
           With xMail
             .ClearTaskFlag
             .ReminderSet = False
             .Save
           End With
        End If
      End If
    End If
  Next i
End Sub

'Reminder
Private Sub Application_Reminder(ByVal Item As Object)
  Dim xPrompt As String
  Dim xResponse As Integer
  Dim xFollowUpMail As Outlook.MailItem
  Dim xRcp As Recipient
  On Error Resume Next
  'Resend
  If (Item.Class <> olMail) Then Exit Sub
  xPrompt = "You haven't yet recieved the reply of " & Chr(34) & Item.Subject & Chr(34) & " within your expected time. Do you want to send a follow-up notification email?"
  xResponse = MsgBox(xPrompt, vbYesNo + vbQuestion, "Kutools for Outlook")
  If xResponse = vbNo Then Exit Sub
  Set xFollowUpMail = Application.CreateItem(olMailItem)
  With xFollowUpMail
    For Each xRcp In Item.Recipients
      .Recipients.Add (xRcp.Address)
    Next
    .Recipients.ResolveAll
    .Subject = "Follow Up: " & Chr(34) & Item.Subject & Chr(34)
    .Body = "Please respond to my email " & Chr(34) & Item.Subject & Chr(34) & "as soon as possible"
    .Attachments.Add Item
    .Display
  End With
End Sub

5. Պահպանեք կոդը, ապա վերադարձեք հիմնական ինտերֆեյս, սեղմեք Ֆայլ > Ընտրանքներ իսկ թե Outlook Ընտրանքներ պատուհանը, սեղմեք Վստահության կենտրոն ձախ պատուհանում և կտտացրեք Վստահության կենտրոնի կարգավորումները հնարավորություն ընձեռել Վստահության կենտրոն պատուհան Սեղմել Մակրո կարգավորումներ և համոզվեք, որ Միացնել բոլոր մակրոները (խորհուրդ չի տրվում. Պոտենցիալ վտանգավոր ծածկագիրը կարող է գործարկվել) տարբերակը ընտրված է աջ հատվածում: Սեղմել OK > OK.

6. Այժմ, եթե ուղարկված նամակը, որը սահմանված է հիշեցումով, պատասխան չի ստանում, երբ հասնում է նշված ժամանակը, բացվող երկխոսություն է հայտնվում՝ հիշեցնելու, թե արդյոք պետք է նորից էլփոստ ուղարկել՝ ծանուցում կատարելու համար:

7: սեղմեք այո, բացվում է հաղորդագրության պատուհան և կցում է նախորդ էլ ուղարկել էլփոստը նորից ուղարկելու համար..

8: սեղմեք Ոչ, հիշեցումը կջնջվի։

Նշում： Եթե նամակին պատասխանել են նշված ժամից շուտ, հիշեցումը կհեռացվի VBA-ի կողմից:

---

Գրասենյակի արտադրողականության լավագույն գործիքները

Outlook- ի համար նախատեսված գործիքներ - Ավելի քան 100 հզոր գործառույթ՝ ձեր Outlook-ը լիցքավորելու համար

🤖 AI Փոստի օգնական: Ակնթարթային պրոֆեսիոնալ նամակներ AI մոգությամբ. մեկ սեղմումով հանճարեղ պատասխաններ, կատարյալ հնչերանգներ, բազմալեզու վարպետություն: Փոխակերպեք էլ. փոստը առանց ջանքերի: ...

📧 Email ավտոմատացում: Գրասենյակից դուրս (հասանելի է POP-ի և IMAP-ի համար)  /  Ժամանակացույց ուղարկել նամակներ  /  Ավտոմատ CC/BCC էլփոստ ուղարկելիս կանոններով  /  Ավտոմատ փոխանցում (Ընդլայնված կանոններ)   /  Ավտոմատ ավելացնել ողջույնները   /  Ավտոմատ կերպով բաժանել բազմասերիստացող նամակները առանձին հաղորդագրությունների ...

📨 էլեկտրոնային կառավարման: Հեշտությամբ հիշեք նամակները  /  Արգելափակել խարդախության նամակները ըստ առարկաների և այլոց  /  Deleteնջել կրկնօրինակ նամակները  /  Ընդլայնված որոնում  /  Համախմբել Թղթապանակները ...

📁 Հավելվածներ Pro: Խմբաքանակի պահպանում  /  Խմբաքանակի անջատում  /  Խմբաքանակային կոմպրես  /  Auto Save- ը   /  Ավտոմատ անջատում  /  Ավտոմատ սեղմում ...

🌟 Ինտերֆեյս Magic: 😊Ավելի գեղեցիկ և զով էմոջիներ   /  Բարձրացրեք ձեր Outlook-ի արտադրողականությունը ներդիրներով դիտումների միջոցով  /  Նվազագույնի հասցնել Outlook-ը փակելու փոխարեն ...

???? Մեկ սեղմումով Հրաշքներ: Պատասխանել բոլորին մուտքային հավելվածներով  /   Հակաֆիշինգի էլ. նամակներ  /  🕘Ցուցադրել ուղարկողի ժամային գոտին ...

👩🏼‍🤝‍👩🏻 Կոնտակտներ և օրացույց: Խմբաքանակի ավելացրեք կոնտակտներ ընտրված էլ  /  Կոնտակտային խումբը բաժանեք առանձին խմբերի  /  Հեռացնել ծննդյան հիշեցումները ...

Over 100 Նկարագրություն Սպասեք ձեր հետազոտությանը: Սեղմեք այստեղ՝ ավելին բացահայտելու համար:

Կարդալ ավելին       Անվճար ներբեռնում      Ձեռք բերել