Excel-ում, թեև IF ֆունկցիան էական նշանակություն ունի հիմնական տրամաբանական թեստերի համար, բարդ պայմանները հաճախ պահանջում են IF հայտարարություններ՝ տվյալների ընդլայնված մշակման համար: Այս համապարփակ ուղեցույցում մենք մանրամասնորեն կանդրադառնանք nested IF-ի հիմունքներին՝ շարահյուսությունից մինչև գործնական կիրառումներ, ներառյալ AND/OR պայմանների հետ տեղադրված IF-ի համակցությունները: Ի լրումն, մենք կկիսվենք, թե ինչպես բարելավել տեղադրվող IF ֆունկցիաների ընթեռնելիությունը, ինչպես նաև որոշ խորհուրդներ nested IF-ի մասին, և կուսումնասիրենք հզոր այլընտրանքներ, ինչպիսիք են VLOOKUP-ը, IFS-ը և ավելին, որպեսզի բարդ տրամաբանական գործողություններն ավելի հեշտ օգտագործվեն և ավելի արդյունավետ:

• Ներդրված IF-ի շարահյուսություն
• Ներդրված IF-ի գործնական օրինակներ
• Ներդրված է, եթե AND / OR պայմանով

• Ներդրված IF-ը հեշտ ընթերցվող դարձնելը
• Ներդրված IF ֆունկցիաների հերթականությունը
• Թվերին և տեքստին պետք է այլ կերպ վերաբերվել
• Ներդրված IF-ի սահմանափակումները

• Օգտագործելով VLOOKUP
• Օգտագործելով IFS
• Օգտագործելով CHOOSE և MATCH

Excel IF ֆունկցիան ընդդեմ Nested IF հայտարարությունների

IF ֆունկցիան և IF-ի մեջ տեղադրված հայտարարությունները Excel-ում ծառայում են նմանատիպ նպատակների, բայց զգալիորեն տարբերվում են իրենց բարդությամբ և կիրառմամբ:

Ներդրված IF-ի օգտագործումը

Այս բաժինը ցույց է տալիս Excel-ում տեղադրված IF հայտարարությունների հիմնական օգտագործումը, ներառյալ շարահյուսությունը, գործնական օրինակները և ինչպես օգտագործել դրանք AND կամ OR պայմաններով:

Ներդրված IF-ի շարահյուսություն

Ֆունկցիայի շարահյուսությունը հասկանալը Excel-ում դրա ճիշտ և արդյունավետ կիրառման հիմքն է: Սկսենք nested if հայտարարությունների շարահյուսությունից։

շարահյուսություն:

=IF(condition1, result1, IF(condition2, result2, IF(condition3, result3, result4)))

Արձանագրություններ:

• Condition1, Condition2, Condition3: These are the conditions you want to test. Each condition is evaluated in order, starting with Condition1.
• Result1: This is the value returned if Condition1 is TRUE.
• Result2: This value is returned if Condition1 is FALSE and Condition2 is TRUE. It's important to note that Result2 is only evaluated if Condition1 is FALSE.
• Result3: This value is returned if both Condition1 and Condition2 are FALSE, and Condition3 is TRUE. Essentially, for Result3 to be evaluated, the previous conditions (Condition1 and Condition2) must both be FALSE.
• Result4: This result is returned if all the conditions (Condition1, Condition2, and Condition3) are FALSE.
  
  In short, this expression can be interpreted as follows:
  Test condition1, if TRUE, return result1, if FALSE,
  test condition2, if TRUE, return result2, if FALSE,
  test condition3, if TRUE, return result3, if FALSE,
  return result4

Հիշեք, որ տեղադրված IF կառուցվածքում յուրաքանչյուր հաջորդ պայման գնահատվում է միայն այն դեպքում, եթե բոլոր նախորդ պայմանները FALSE են: Այս հաջորդական ստուգումը չափազանց կարևոր է հասկանալու համար, թե ինչպես են գործում տեղադրված IF-ները:

Ներդրված IF-ի գործնական օրինակներ

Հիմա եկեք երկու գործնական օրինակով անդրադառնանք տեղադրված IF-ի օգտագործմանը:

Օրինակ 1. Գնահատման համակարգ

Ինչպես ցույց է տրված ստորև ներկայացված սքրինշոթում, ենթադրենք, որ դուք ունեք ուսանողների միավորների ցուցակ և ցանկանում եք գնահատականներ նշանակել այս միավորների հիման վրա: Այս առաջադրանքը կատարելու համար կարող եք օգտագործել nested IF-ը:

Ընտրեք դատարկ բջիջ (այս դեպքում՝ C2), մուտքագրեք հետևյալ բանաձևը և սեղմեք Մտնել արդյունք ստանալու համար։ Այնուհետև քաշեք Լրացրեք բռնակ ներքեւ՝ մնացած արդյունքները ստանալու համար:

=IF(B2>=90,$F$2,IF(B2>=80,$F$3,IF(B2>=70,$F$4,IF(B2>=60,$F$5,$F$6))))

Օրինակ 2. Վաճառքի հանձնաժողովի հաշվարկ

Պատկերացրեք մի սցենար, երբ վաճառքի ներկայացուցիչները ստանում են տարբեր միջնորդավճարներ՝ ելնելով իրենց վաճառքի ձեռքբերումներից: Ինչպես ցույց է տրված ստորև ներկայացված սքրինշոթում, դուք ցանկանում եք հաշվարկել վաճառողի միջնորդավճարը՝ հիմնվելով այս տարբեր վաճառքի շեմերի վրա, և IF-ի մեջ տեղադրված հայտարարությունները կարող են օգնել ձեզ այս հարցում:

Ընտրեք դատարկ բջիջ (այս դեպքում՝ C2), մուտքագրեք հետևյալ բանաձևը և սեղմեք Մտնել արդյունք ստանալու համար։ Այնուհետև քաշեք Լրացրեք բռնակ ներքեւ՝ մնացած արդյունքները ստանալու համար:

=B2*IF(B2>20000,$F$2,IF(B2>=10000,$F$3,$F$4))

Ներդրված է, եթե AND / OR պայմանով

Այս բաժնում ես փոփոխում եմ վերը նշված առաջին օրինակը՝ «գնահատման համակարգը»՝ ցույց տալու, թե ինչպես կարելի է համատեղել IF-ը AND կամ OR պայմանի հետ Excel-ում: Վերանայված գնահատման օրինակում ես լրացուցիչ պայման եմ ներկայացրել «Հաճախումների տոկոսադրույքի» հիման վրա։

Օգտագործելով nested if-ը AND պայմանով

Եթե ​​ուսանողը համապատասխանում է և՛ միավորի, և՛ հաճախելիության չափանիշներին, նա կստանա գնահատականի բարձրացում: Օրինակ, ուսանողի, ում միավորը 60 կամ ավելի է, իսկ հաճախելիության մակարդակը 95% կամ ավելի է, նրանց գնահատականը կբարձրացվի մեկ մակարդակով, օրինակ՝ A-ից A+, B-ից B+ և այլն: Այնուամենայնիվ, եթե հաճախելիության մակարդակը 95%-ից ցածր է, գնահատումը կհետևի սկզբնական միավորների վրա հիմնված չափանիշներին: Նման դեպքերում մենք պետք է օգտագործենք IF դրույթ՝ AND պայմանով:

Ընտրեք դատարկ բջիջ (այս դեպքում D2), մուտքագրեք հետևյալ բանաձևը և սեղմեք Մտնել արդյունք ստանալու համար։ Այնուհետև քաշեք Լրացրեք բռնակ ներքեւ՝ մնացած արդյունքները ստանալու համար:

=IF(AND(B2>=60, C2>=95%),IF(B2>=90, "A+", IF(B2>=80, "B+", IF(B2>=70, "C+", "D+"))),IF(B2>=90, "A", IF(B2>=80, "B", IF(B2>=70, "C", IF(B2>=60, "D", "F")))))

Օգտագործելով nested if with OR պայմանով

Այս դեպքում ուսանողի գնահատականը մեկ աստիճանով կբարձրացվի, եթե նրա միավորը 95 կամ ավելի է, կամ եթե հաճախելիության մակարդակը 95% կամ ավելի է: Ահա թե ինչպես մենք կարող ենք դա իրականացնել՝ օգտագործելով IF և OR պայմանները:

Ընտրեք դատարկ բջիջ (այս դեպքում D2), մուտքագրեք հետևյալ բանաձևը և սեղմեք Մտնել արդյունք ստանալու համար։ Այնուհետև քաշեք Լրացրեք բռնակ ներքեւ՝ մնացած արդյունքները ստանալու համար:

=IF(OR(B2>=95, C2>=95%),IF(B2>=90, "A+", IF(B2>=80, "B+", IF(B2>=70, "C+", IF(B2>=60, "D+", "F+")))),IF(B2>=90, "A", IF(B2>=80, "B", IF(B2>=70, "C", IF(B2>=60, "D", "F")))))

Խորհուրդներ և հնարքներ տեղադրված IF-ի համար

Այս բաժինը ներառում է չորս օգտակար խորհուրդներ և հնարքներ ներդիր IF-ի համար:

Ներդրված IF-ը հեշտ ընթերցվող դարձնելը

Տիպիկ տեղադրված IF հայտարարությունը կարող է կոմպակտ թվալ, բայց դժվար է վերծանել:

Հետևյալ բանաձևում դժվար է արագ որոշել, թե որտեղ է ավարտվում մի պայմանը և սկսվում մյուսը, հատկապես, երբ բարդությունը մեծանում է:

=IF(A2>=90, "A", IF(A2>=80, "B", IF(A2>=70, "C", IF(A2>=60, "D", "F"))))

Լուծում. Գծի ընդմիջումների և ներքևի ավելացում

Ներդրված IF-ը հեշտ ընթեռնելի դարձնելու համար դուք կարող եք բանաձևը բաժանել մի քանի տողերի՝ յուրաքանչյուր տեղադրված IF-ի հետ նոր տողում: Բանաձևում պարզապես տեղադրեք կուրսորը IF-ի առաջ և սեղմեք Alt + Enter ստեղները:

Վերոնշյալ բանաձևը խախտելուց հետո այն կցուցադրվի հետևյալ կերպ.

=IF(A2>=90, "A",
      IF(A2>=80, "B",
          IF(A2>=70, "C",
              IF(A2>=60, "D", "F")))
)

Այս ձևաչափը ավելի պարզ է դարձնում, թե որտեղ է գտնվում յուրաքանչյուր պայման և համապատասխան ելք՝ ավելացնելով բանաձևի ընթեռնելիությունը:

Ներդրված IF ֆունկցիաների հերթականությունը

Ներդրված IF բանաձևում տրամաբանական պայմանների կարգը կարևոր է, քանի որ այն որոշում է, թե ինչպես է Excel-ը գնահատում այս պայմանները և այդպիսով ազդում բանաձևի վերջնական արդյունքի վրա:

Ճիշտ բանաձեւ

Գնահատման համակարգի օրինակում մենք օգտագործում ենք հետևյալ բանաձևը՝ միավորների հիման վրա գնահատականներ նշանակելու համար:

=IF(B2>=90, "A", IF(B2>=80, "B", IF(B2>=70, "C", IF(B2>=60, "D", "F"))))

Excel-ը հաջորդաբար գնահատում է IF բանաձևի պայմանները՝ առաջին պայմանից մինչև վերջինը: Այս բանաձևը նախ ստուգում է ամենաբարձր միավորի շեմը (>=90 «Ա»-ի համար), այնուհետև տեղափոխվում է ստորին շեմեր: Այն ապահովում է, որ միավորը համեմատվում է այն ամենաբարձր գնահատականի հետ, որին այն համապատասխանում է: Եթե ​​առաջին պայմանը ճշմարիտ է (A2>=90), այն վերադարձնում է «A» և չի գնահատում որևէ այլ պայման:

Սխալ պատվիրված բանաձև

Եթե ​​պայմանների հերթականությունը փոխվեր՝ սկսած ամենացածր շեմից, այն սխալ արդյունքներ կբերեր:

=IF(B2>=60, "D", IF(B2>=70, "C", IF(B2>=80, "B", IF(B2>=90, "A", "F"))))

Այս սխալ բանաձևում 95 միավորը անմիջապես կհամապատասխանի առաջին պայմանին B2>=60 և նրան սխալ է նշանակվում «D» գնահատականը:

Թվերին և տեքստին պետք է այլ կերպ վերաբերվել

Այս բաժինը ցույց կտա ձեզ, թե ինչպես են թվերը և տեքստը տարբեր կերպ են վերաբերվում IF հայտարարություններում:

Համարներ

Թվերն օգտագործվում են թվաբանական համեմատությունների և հաշվարկների համար։ Ներդրված IF հայտարարություններում դուք կարող եք ուղղակիորեն համեմատել թվերը՝ օգտագործելով օպերատորներ, ինչպիսիք են >, <, =, >= և <=:

Տեքստ

Ներդրված IF հայտարարություններում տեքստը պետք է լինի փակցված է կրկնակի չակերտների մեջ. Տես A, B, C, D և F հետևյալ բանաձևը.

=IF(A2>=90, "A", IF(A2>=80, "B", IF(A2>=70, "C", IF(A2>=60, "D", "F"))))

Ներդրված IF-ի սահմանափակումները

Այս բաժնում թվարկված են ներդիր IF-ի մի քանի սահմանափակումներ և թերություններ:

Բարդություն և ընթերցելիություն.

Թեև Excel-ը թույլ է տալիս տեղադրել մինչև 64 տարբեր IF ֆունկցիաներ, ամենևին էլ նպատակահարմար չէ դա անել: Որքան շատ են բնադրման մակարդակները, այնքան ավելի բարդ է դառնում բանաձևը: Սա կարող է հանգեցնել այնպիսի բանաձևերի, որոնք դժվար է կարդալ, հասկանալ և պահպանել:

Սխալների հակվածություն.

Ավելին, բարդ ներդիր IF հայտարարությունները կարող են հակված լինել սխալների և դժվարացնել վրիպազերծումը կամ փոփոխումը:

Դժվար է ընդլայնել կամ չափավորել.

Եթե ​​ձեր տրամաբանությունը փոխվում է, կամ դուք պետք է ավելացնեք ավելի շատ պայմաններ, խորապես տեղադրված IF-ները կարող են դժվար լինել փոփոխել կամ երկարացնել:

Այս սահմանափակումների ըմբռնումը առանցքային է Excel-ում տեղադրված IF հայտարարությունների արդյունավետ օգտագործման համար: Հաճախ, ներդիր IF-ների համատեղումը այլ գործառույթների հետ կամ այլընտրանքային մոտեցումներ փնտրելը կարող է հանգեցնել ավելի արդյունավետ և պահպանվող լուծումների:

Nested IF-ի այլընտրանքներ

Այս բաժնում թվարկված են մի քանի գործառույթներ Excel-ում, որոնք կարող են օգտագործվել որպես այլընտրանքային IF հայտարարություններ:

Օգտագործելով VLOOKUP

Վերոհիշյալ երկու գործնական օրինակներն իրականացնելու համար դուք կարող եք օգտագործել VLOOKUP ֆունկցիան՝ տեղադրված IF հայտարարությունների փոխարեն: Ահա թե ինչպես կարող եք դա անել.

Օրինակ 1. Գնահատման համակարգ VLOOKUP-ով

Այստեղ ես ցույց կտամ, թե ինչպես կարելի է օգտագործել VLOOKUP-ը՝ գնահատականների հիման վրա գնահատելու համար:

Քայլ 1. Ստեղծեք գնահատականների որոնման աղյուսակ

Նախ, դուք պետք է ստեղծեք որոնման աղյուսակ (օրինակ՝ E1:F6 այս դեպքում) միավորների միջակայքի և համապատասխան գնահատականների համար: Նշում: Աղյուսակի առաջին սյունակի միավորները պետք է դասավորված լինեն աճման կարգով:

Քայլ 2. Կիրառեք VLOOKUP ֆունկցիան գնահատականներ նշանակելու համար

Ընտրեք դատարկ բջիջ (այս դեպքում՝ C2), մուտքագրեք հետևյալ բանաձևը և սեղմեք կոճակը Մտնել բանալին առաջին դասարան ստանալու համար: Ընտրեք այս բանաձևի բջիջը և քաշեք այն Լրացրեք բռնակ ներքեւ՝ մնացած գնահատականները ստանալու համար:

=VLOOKUP(B2,$E$2:$F$6,2,TRUE)

Օրինակ 2. Վաճառքի միջնորդավճարի հաշվարկ VLOOKUP-ով

Կարող եք նաև օգտագործել VLOOKUP-ը Excel-ում վաճառքի միջնորդավճարի հաշվարկն իրականացնելու համար: Խնդրում ենք անել հետևյալը.

Քայլ 1. Ստեղծեք գնահատականների որոնման աղյուսակ

Նախ, դուք պետք է ստեղծեք որոնման աղյուսակ վաճառքի և համապատասխան միջնորդավճարի համար, օրինակ՝ E2:F4 այս դեպքում: ՆշումԱղյուսակի առաջին սյունակի վաճառքները պետք է տեսակավորվեն աճման կարգով:

Քայլ 2. Կիրառեք VLOOKUP ֆունկցիան գնահատականներ նշանակելու համար

Ընտրեք դատարկ բջիջ (այս դեպքում՝ C2), մուտքագրեք հետևյալ բանաձևը և սեղմեք Enter ստեղնը՝ առաջին հանձնաժողովը ստանալու համար: Ընտրեք այս բանաձևի բջիջը և քաշեք դրա լրացման բռնակը ներքև՝ մնացած արդյունքները ստանալու համար:

=B2*VLOOKUP(B2,$E$2:$F$4,2,TRUE)

Օգտագործելով IFS

The IFS ֆունկցիա հեշտացնում է գործընթացը՝ վերացնելով բույն դնելու անհրաժեշտությունը և հեշտացնում է բանաձևերի ընթերցումը և կառավարումը: Այն մեծացնում է ընթերցանությունը և հեշտացնում է բազմաթիվ պայմանական ստուգումների իրականացումը: IFS ֆունկցիան օգտագործելու համար համոզվեք, որ օգտագործում եք Excel 2019 կամ ավելի նոր տարբերակ, կամ ունեք Office 365 բաժանորդագրություն: Տեսնենք, թե ինչպես կարելի է այն կիրառել գործնական օրինակներով։

Օրինակ 1. Գնահատման համակարգ IFS-ով

Ենթադրելով գնահատման նույն չափանիշները, ինչ նախկինում, IFS ֆունկցիան կարող է օգտագործվել հետևյալ կերպ.

Ընտրեք դատարկ բջիջ, օրինակ՝ C2, մուտքագրեք հետևյալ բանաձևը և սեղմեք Մտնել առաջին արդյունքը ստանալու համար: Ընտրեք այս արդյունքի բջիջը և քաշեք այն Լրացրեք բռնակ ներքեւ՝ մնացած արդյունքները ստանալու համար:

=IFS(B2>=90,"A",B2>=80,"B",B2>=70,"C",B2>=60,"D",B2<60,"F")

Օրինակ 2. Վաճառքի հանձնաժողովի հաշվարկ IFS-ով

Վաճառքի միջնորդավճարի հաշվարկման սցենարի համար IFS ֆունկցիան կիրառվում է հետևյալ կերպ.

Ընտրեք դատարկ բջիջ, օրինակ՝ C2, մուտքագրեք հետևյալ բանաձևը և սեղմեք Մտնել առաջին արդյունքը ստանալու համար: Ընտրեք այս արդյունքի բջիջը և քաշեք այն Լրացրեք բռնակ ներքեւ՝ մնացած արդյունքները ստանալու համար:

=B2*IFS(B2>20000,20%,B2>=10000,15%,TRUE,10%)

Օգտագործելով CHOOSE և MATCH

CHOOSE և MATCH մոտեցումը կարող է ավելի արդյունավետ և հեշտ կառավարելի լինել՝ համեմատած IF հայտարարությունների հետ: Այս մեթոդը պարզեցնում է բանաձևը և ավելի պարզ դարձնում թարմացումները կամ փոփոխությունները: Ստորև ես ցույց կտամ, թե ինչպես օգտագործել CHOOSE և MATCH գործառույթների համադրությունը այս հոդվածի երկու գործնական օրինակները լուծելու համար:

Օրինակ 1. Գնահատման համակարգ CHOOSE-ով և MATCH-ով

Դուք կարող եք օգտագործել CHOOSE և MATCH ֆունկցիաների համակցությունը՝ տարբեր միավորների հիման վրա գնահատականներ նշանակելու համար:

Քայլ 1. Ստեղծեք որոնման զանգված՝ որոնման արժեքներով

Նախ, դուք պետք է ստեղծեք մի շարք բջիջներ, որոնք պարունակում են շեմային արժեքներ, որոնց միջով կփնտրի MATCH, օրինակ՝ $E$2:$E$6 այս դեպքում: Նշում: Այս տիրույթի թվերը պետք է դասավորված լինեն աճման կարգով, որպեսզի MATCH ֆունկցիան ճիշտ աշխատի, երբ օգտագործվում է համապատասխանության մոտավոր տեսակ:

Քայլ 2. Գնահատականներ նշանակելու համար կիրառեք CHOOSE և MATCH

Ընտրեք դատարկ բջիջ (այս դեպքում՝ C2), մուտքագրեք հետևյալ բանաձևը և սեղմեք կոճակը Մտնել բանալին առաջին դասարան ստանալու համար: Ընտրեք այս բանաձևի բջիջը և քաշեք այն Լրացրեք բռնակ ներքեւ՝ մնացած արդյունքները ստանալու համար:

=CHOOSE(MATCH(B2, $E$2:$E$6, 1), "F", "D", "C", "B", "A")

Օրինակ 2. Վաճառքի հանձնաժողովի հաշվարկ IFS-ով

Վաճառքի միջնորդավճարի հաշվարկման համար CHOOSE և MATCH համակցության օգտագործումը կարող է նաև արդյունավետ լինել, հատկապես, երբ միջնորդավճարները հիմնված են վաճառքի սահմանված շեմերի վրա: Տեսնենք, թե ինչպես կարող ենք անել:

Քայլ 1. Ստեղծեք որոնման զանգված՝ որոնման արժեքներով

Նախ, դուք պետք է ստեղծեք մի շարք բջիջներ, որոնք պարունակում են շեմային արժեքներ, որոնց միջով կփնտրի MATCH, օրինակ՝ $E$2:$E$4 այս դեպքում: Նշում: Այս տիրույթի թվերը պետք է դասավորված լինեն աճման կարգով, որպեսզի MATCH ֆունկցիան ճիշտ աշխատի, երբ օգտագործվում է համապատասխանության մոտավոր տեսակ:

Քայլ 2. Արդյունքներ ստանալու համար կիրառեք CHOOSE and MATCH

Ընտրեք դատարկ բջիջ (այս դեպքում՝ C2), մուտքագրեք հետևյալ բանաձևը և սեղմեք կոճակը Մտնել բանալին առաջին դասարան ստանալու համար: Ընտրեք այս բանաձևի բջիջը և քաշեք այն Լրացրեք բռնակ ներքեւ՝ մնացած արդյունքները ստանալու համար:

=B2*CHOOSE(MATCH(B2, $E$2:$E$4, 1), 10%, 15%, 20%)

Եզրափակելով, Excel-ում տեղադրված IF հայտարարությունների յուրացումը արժեքավոր հմտություն է, որը մեծացնում է տվյալների վերլուծության և որոշումների կայացման գործընթացներում բարդ տրամաբանական սցենարներ վարելու ձեր ունակությունը: Թեև տեղադրված IF-ները հզոր են բարդ տրամաբանական գործողությունների համար, կարևոր է հաշվի առնել դրանց սահմանափակումները: Ավելի պարզ այլընտրանքները, ինչպիսիք են VLOOKUP-ը, IFS-ը և CHOOSE with MATCH-ը, կարող են ավելի պարզ լուծումներ տալ որոշակի սցենարներում: Զինված այս պատկերացումներով՝ այժմ կարող եք վստահորեն կիրառել Excel-ի ամենահարմար տեխնիկան ձեր տվյալների վերլուծության առաջադրանքների համար՝ ապահովելով ձեր աղյուսակների հստակությունը, ճշգրտությունը և արդյունավետությունը: Նրանց համար, ովքեր ցանկանում են ավելի խորանալ Excel-ի հնարավորությունների մեջ, մեր կայքը պարծենում է բազմաթիվ ձեռնարկներով: Բացահայտեք Excel-ի ավելի շատ խորհուրդներ և հնարքներ այստեղ.

Առնչվող հոդվածներ