Ինչպե՞ս պահպանել կամ պահպանել ActiveX ցուցակի տուփերի ընտրությունները Excel- ում:

Ենթադրելով, որ դուք ստեղծել եք ցուցակների որոշ տուփեր և ընտրություններ եք կատարել ցուցակների տուփերում, այնուամենայնիվ, այս ցուցակների տուփերի բոլոր ընտրությունները անհետանում են, երբ փակվում և վերաբացվում է աշխատանքային գրքույկը: Doանկանու՞մ եք պահպանել ցուցակների տուփերում կատարված ընտրությունները, երբ աշխատանքային գիրքը փակվում և վերաբացվում է: Այս հոդվածի մեթոդը կարող է օգնել ձեզ:

Excel- ում պահեք կամ պահեք ActiveX ցուցակի տուփերի ընտրանքները VBA կոդով

Excel- ում պահեք կամ պահեք ActiveX ցուցակի տուփերի ընտրանքները VBA կոդով

Ստորև ներկայացված VBA կոդը կարող է օգնել ձեզ պահպանել կամ պահպանել ընտրությունները, եթե ActiveX ցուցակը տուփեր է Excel- ում: Խնդրում եմ արեք հետևյալ կերպ.

1. Աշխատանքային գրքում պարունակում է ActiveX ցուցակի տուփեր, որոնք ցանկանում եք պահել ընտրությունները, սեղմեք այն ալտ + F11 ստեղները միաժամանակ բացելու համար Microsoft Visual Basic հավելվածների համար պատուհան.

2. Մեջ Microsoft Visual Basic հավելվածների համար պատուհանը, կրկնակի սեղմեք Այս գործառույթը ձախ պատուհանում բացելու համար Այս գործառույթը Կոդ պատուհան Եվ ապա պատճենեք հետևյալ VBA կոդը ծածկագրի պատուհանում:

VBA կոդ. Excel- ում պահեք ActiveX ցուցակի տուփերի ընտրանքները

Private Sub Workbook_BeforeSave(ByVal SaveAsUI As Boolean, Cancel As Boolean)
    Dim I As Long
    Dim J As Long
    Dim K As Long
    Dim KK As Long
    Dim xSheet As Worksheet
    Dim xListBox As Object
    On Error GoTo Label
    Application.DisplayAlerts = False
    Application.ScreenUpdating = False
    K = 0
    KK = 0
    If Not Sheets("ListBox Data") Is Nothing Then
        Sheets("ListBox Data").Delete
    End If
Label:
    Sheets.Add(after:=Worksheets(Worksheets.Count)).Name = "ListBox Data"
    Set xSheet = Sheets("ListBox Data")
    For I = 1 To Sheets.Count
        For Each xListBox In Sheets(I).OLEObjects
            If xListBox.Name Like "ListBox*" Then
                With xListBox.Object
                For J = 0 To .ListCount - 1
                    If .Selected(J) Then
                        xSheet.Range("A1").Offset(K, KK).Value = "True"
                    Else
                        xSheet.Range("A1").Offset(K, KK).Value = "False"
                    End If
                    K = K + 1
                Next
                End With
                K = 0
                KK = KK + 1
            End If
        Next
    Next
    Application.ScreenUpdating = True
    Application.DisplayAlerts = True
End Sub

Private Sub Workbook_Open()
    Dim I As Long
    Dim J As Long
    Dim KK As Long
    Dim xRg As Range
    Dim xCell As Range
    Dim xListBox As Object
    Application.DisplayAlerts = False
    Application.ScreenUpdating = False
    KK = 0
    For I = 1 To Sheets.Count - 1
        For Each xListBox In Sheets(I).OLEObjects
            If xListBox.Name Like "ListBox*" Then
                With xListBox.Object
                    Set xRg = Intersect(Sheets("ListBox Data").Range("A1").Offset(0, KK).EntireColumn, Sheets("ListBox Data").UsedRange)
                    For J = 1 To .ListCount
                        Set xCell = xRg(J)
                        If xCell.Value = "True" Then
                            .Selected(J - 1) = True
                        End If
                    Next
                    KK = KK + 1
                End With
            End If
        Next
    Next
    Sheets("ListBox Data").Delete
    Application.ScreenUpdating = True
    Application.DisplayAlerts = True
End Sub

3. Սեղմեք ալտ + Q ստեղները փակելու համար Microsoft Visual Basic հավելվածների համար պատուհան.

4. Այժմ դուք պետք է պահեք աշխատանքային գիրքը որպես Excel-ի մակրո-միացված աշխատանքային գրքույկ: Խնդրում ենք սեղմել Ֆայլ > Պահել As > Թերթել.

5. Մեջ Պահել As երկխոսության տուփ, ընտրեք թղթապանակ՝ աշխատանքային գիրքը պահելու համար, վերանվանեք այն ըստ անհրաժեշտության, ընտրեք Excel մակրոներով աշխատունակ գիրք է Պահել որպես տիպ բացվող ցուցակը և վերջապես կտտացրեք Փրկել կոճակ Տեսեք,

Խնդրում ենք պահպանել աշխատանքային գրքույկը ամեն անգամ, երբ թարմացնում եք ցուցակի տուփերը: Այնուհետև բոլոր նախորդ ընտրությունները կպահվեն ցուցակի վանդակներում՝ աշխատանքային գրքույկը վերաբացելուց հետո:

ՆշումԱշխատանքային գրքույկը պահելիս աշխատաթերթը «ListBox-ի տվյալներ”-ն ավտոմատ կերպով կստեղծվի ձեր աշխատանքային գրքի բոլոր աշխատաթերթերի վերջում, խնդրում ենք անտեսել այս աշխատաթերթը, քանի որ այն ինքնաբերաբար կվերանա, երբ աշխատանքային գիրքը փակվի: