Ինչպե՞ս Excel- ում առաջացնել կամ թվարկել բոլոր հնարավոր փոխարկումները:

Օրինակ, ես ունեմ երեք նիշ XYZ, հիմա ուզում եմ թվարկել այս երեք նիշերի հիման վրա բոլոր հնարավոր փոխարկումները, որպեսզի ստանամ վեց տարբեր արդյունքներ ՝ XYZ, XZY, YXZ, YZX, ZXY և ZYX: Excel- ում ինչպե՞ս կարող էիք արագ գեներացնել կամ թվարկել բոլոր փոխարկումները ՝ հիմնված տարբեր թվերի նիշերի վրա:

VBA կոդով նիշերի հիման վրա ստեղծեք կամ թվարկեք բոլոր հնարավոր փոխարկումները

VBA կոդով նիշերի հիման վրա ստեղծեք կամ թվարկեք բոլոր հնարավոր փոխարկումները

Հետևյալ VBA կոդը կարող է օգնել ձեզ թվարկել բոլոր փոխարկումները ՝ հիմնվելով ձեր հատուկ տառերի վրա, խնդրում ենք կատարել հետևյալը.

1, Պահեք պահեք ALT + F11 բացել ստեղները Microsoft Visual Basic հավելվածների համար պատուհան.

2: Սեղմեք Տեղադրել > Մոդուլներ, և տեղադրեք հետևյալ կոդը Մոդուլներ Պատուհանը:

VBA կոդ. Excel- ում թվարկեք բոլոր հնարավոր փոխարկումները

Sub GetString()
'Updateby Extendoffice
    Dim xStr As String
    Dim FRow As Long
    Dim xScreen As Boolean
    xScreen = Application.ScreenUpdating
    Application.ScreenUpdating = False
    xStr = Application.InputBox("Enter text to permute:", "Kutools for Excel", , , , , , 2)
    If Len(xStr) < 2 Then Exit Sub
    If Len(xStr) >= 8 Then
        MsgBox "Too many permutations!", vbInformation, "Kutools for Excel"
        Exit Sub
    Else
        ActiveSheet.Columns(1).Clear
        FRow = 1
        Call GetPermutation("", xStr, FRow)
    End If
    Application.ScreenUpdating = xScreen
End Sub
Sub GetPermutation(Str1 As String, Str2 As String, ByRef xRow As Long)
    Dim i As Integer, xLen As Integer
    xLen = Len(Str2)
    If xLen < 2 Then
        Range("A" & xRow) = Str1 & Str2
        xRow = xRow + 1
    Else
        For i = 1 To xLen
            Call GetPermutation(Str1 + Mid(Str2, i, 1), Left(Str2, i - 1) + Right(Str2, xLen - i), xRow)
        Next
    End If
End Sub

3, Դրանից հետո սեղմեք F5 այս կոդն աշխատեցնելու բանալին, և դուրս է գալիս հուշման տուփ ՝ հիշեցնելու համար այն նիշերը մուտքագրելու մասին, որոնք ցանկանում եք թվարկել բոլոր փոփոխությունները, տես նկարի նկարը.

4, Նիշերը մուտքագրելուց հետո սեղմեք OK կոճակը, բոլոր հնարավոր փոխարկումները ցուցադրվում են ակտիվ աշխատաթերթի A սյունակում: Տեսեք,

ՆշումԵթե ​​մուտքագրված նիշի երկարությունը հավասար է կամ գերազանցում է 8 նիշը, այս կոդը չի աշխատի, քանի որ չափազանց շատ տեղաշարժեր կան: