Outlook. Ինչպե՞ս չեղարկել հանդիպումը օրացույցում որպես կազմակերպիչ:

Outlook-ում, որպես հանդիպման կազմակերպիչ, երբ չեղարկեք հանդիպումը, հանդիպումն ինքնաբերաբար կջնջվի օրացույցից: Որոշ դեպքերում դուք կարող եք չեղարկված հանդիպումները պահել օրացույցում՝ որոշ գնահատականներ անելու համար: Այնուամենայնիվ, Outlook-ում ներկառուցված գործառույթներ չկան, որոնք կարող են կարգավորել այս աշխատանքը: Այս ձեռնարկում այն ​​տրամադրում է երկու VBA կոդ՝ չեղարկելիս հանդիպումը որպես հանդիպում պահելու համար:

VBA կոդեր՝ չեղարկված հանդիպումը որպես հանդիպում պատճենելու համար

VBA կոդեր՝ չեղարկված հանդիպումը որպես հանդիպում պատճենելու համար

Ահա երկու կոդ՝ հանդիպումը չեղարկելու և այն որպես հանդիպում միաժամանակ պատճենելու և տեղադրելու համար։

Նշում. նախքան կոդը միացնելը, համոզվեք, որ այս երկու տարբերակները նշված են.

Միացնել Outlook- ը, կտտացրեք Ֆայլ > Ընտրանքներ, Outlook Options պատուհանում սեղմեք Վստահության կենտրոն էջանիշը և կտտացրեք Վստահության կենտրոնի կարգավորումները, ապա վստահության կենտրոնի պատուհանում սեղմեք Մակրո կարգավորումներ էջանշանը, ստուգեք Միացնել բոլոր մակրոները (խորհուրդ չի տրվում. Պոտենցիալ վտանգավոր ծածկագիրը կարող է գործարկվել) և Կիրառեք մակրո անվտանգության կարգավորումները տեղադրված հավելումների վրա տարբերակները. Սեղմել OK > OK պատուհանները փակելու համար. Վերսկսել Հեռանկար

1. Անցեք դեպի Outlook Օրացույցի դիտում և ընտրեք այն հանդիպումը, որը ցանկանում եք չեղարկել Սեղմեք ալտ + F11 ստեղներ ՝ Microsoft Visual Basic հավելվածների համար պատուհանը միացնելու համար:

2: սեղմեք Տեղադրել > Մոդուլներ նոր դատարկ մոդուլ տեղադրելու համար: Այնուհետև պատճենեք և տեղադրեք ստորև նշված կոդը դրան:

Կոդ. Պատճենեք հանդիպումը որպես հանդիպում և չեղարկեք այն

Sub CopyMeetingAsAppointmentBeforeCancel()
'UpdatebyExtendoffice20221129
Dim xAppointmentItem As AppointmentItem
Dim xMeetingItem As AppointmentItem
On Error Resume Next
Set xMeetingItem = GetCurrentItem()
Set xAppointmentItem = Application.CreateItem(olAppointmentItem)
With xAppointmentItem
  .Subject = "Canceled: " & xMeetingItem.Subject
  .Start = xMeetingItem.Start
  .Duration = xMeetingItem.Duration
  .Location = xMeetingItem.Location
  .Body = xMeetingItem.Body
  .Save
  .Move Application.ActiveExplorer.CurrentFolder
End With
With xMeetingItem
  .MeetingStatus = olMeetingCanceled
  .Send
  .Delete
End With
Set xAppointmentItem = Nothing
Set xMeetingItem = Nothing
End Sub

Function GetCurrentItem() As Object
  On Error Resume Next
  Select Case TypeName(Application.ActiveWindow)
    Case "Explorer"
      Set GetCurrentItem = Application.ActiveExplorer.Selection.Item(1)
    Case "Inspector"
      Set GetCurrentItem = Application.ActiveInspector.CurrentItem
  End Select
End Function

3: սեղմեք Վազում կոճակը կամ սեղմել F5 բանալին, այժմ ընտրված հանդիպումը չեղարկվել է, և նոր հանդիպում՝ Չեղարկված և ենթակա:

Եթե ​​ցանկանում եք պատճենել և տեղադրել հանդիպումը որպես հանդիպում մեկ այլ օրացույցում, ապա չեղարկել հանդիպումը, օգտագործեք ստորև նշված կոդը.

Կոդ. Պատճենեք հանդիպումը որպես հանդիպում մեկ այլ օրացույցում և չեղարկեք այն

Sub CopyMeetingAsAppointmentToCalenderBeforeCancel()
'Updatebyextendoffice20221129
Dim xDestCalendar As Outlook.MAPIFolder
Dim xNameSpace As Outlook.NameSpace
Dim xAppointmentItem As AppointmentItem
Dim xMeetingItem As AppointmentItem
On Error Resume Next
Set xNameSpace = Application.GetNamespace("MAPI")
Set xDestCalendar = xNameSpace.PickFolder
If xDestCalendar.DefaultItemType <> olAppointmentItem Then
  MsgBox "Please Select calendar folder. ", vbOKOnly + vbInformation, "Kutools for Outlook"
  Exit Sub
End If
Set xMeetingItem = GetCurrentItem()
Set xAppointmentItem = Application.CreateItem(olAppointmentItem)
With xAppointmentItem
  .Subject = "Canceled: " & xMeetingItem.Subject
  .Start = xMeetingItem.Start
  .Duration = xMeetingItem.Duration
  .Location = xMeetingItem.Location
  .Body = xMeetingItem.Body
  .Save
  .Move xDestCalendar
End With
With xMeetingItem
  .MeetingStatus = olMeetingCanceled
  .Send
  .Delete
End With
Set xDestCalendar = Nothing
Set xNameSpace = Nothing
Set xAppointmentItem = Nothing
Set xMeetingItem = Nothing
End Sub

Function GetCurrentItem() As Object
  On Error Resume Next
  Select Case TypeName(Application.ActiveWindow)
    Case "Explorer"
      Set GetCurrentItem = Application.ActiveExplorer.Selection.Item(1)
    Case "Inspector"
      Set GetCurrentItem = Application.ActiveInspector.CurrentItem
  End Select
End Function

Սեղմել Վազում կոճակը կամ սեղմել F5 ստեղնը, «Ընտրել թղթապանակ» երկխոսությունը դուրս է գալիս, որպեսզի ընտրեք օրացուցային թղթապանակ՝ հանդիպումը տեղադրելու համար, այնուհետև սեղմեք «OK»:

Այժմ հանդիպումը չեղարկվել է և պատճենվել և տեղադրվել է ձեր ընտրած օրացույցի պանակում որպես հանդիպում: