Ինչպե՞ս Outlook-ում ավտոմատ կերպով տարբեր տեսակի ջնջված տարրեր տեղափոխել տարբեր թղթապանակներ:

Outlook-ում բոլոր տեսակի ջնջված նյութերը (նամակներ, առաջադրանքներ, կոնտակտներ և այլն) կտեղափոխվեն «Ջնջված նյութեր» պանակ: Եթե ցանկանում եք տարրերը տեղափոխել տարբեր թղթապանակներ՝ ելնելով «Ջնջված տարրեր» պանակում գտնվող տարրի տիպից, ինչպես ցույց է տրված ստորև ներկայացված սքրինշոթը, ինչպե՞ս կարող եք այն դարձնել Outlook-ում:

Տարբեր տեսակի ջնջված տարրերը ավտոմատ կերպով տեղափոխեք տարբեր թղթապանակներ VBA կոդով

Ստորև բերված VBA կոդը կարող է օգնել ձեզ ջնջված տարրերը ավտոմատ կերպով տեղափոխել տարբեր թղթապանակներ, խնդրում ենք անել այսպես.

1. Գործարկեք Outlook-ը, այնուհետև սեղմեք ALT + F11 բացել ստեղները Microsoft Visual Basic հավելվածների համար պատուհան.

2, Հետո կրկնակի կտտացրեք ԱյսOutlookSession- ը - ից Projectրագիր-Projectրագիր 1 պատուհան, այնուհետև պատճենեք և տեղադրեք ստորև բերված կոդը դատարկ կոդի պատուհանում.

VBA կոդ. Տարբեր տեսակի ջնջված տարրեր ինքնաբերաբար տեղափոխեք տարբեր թղթապանակներ

Public WithEvents GDeletedFolder As Outlook.Folder
Public WithEvents GDeletedItems As Outlook.Items
Private Sub Application_Startup()
  Set GDeletedFolder = Application.Session.GetDefaultFolder(olFolderDeletedItems)
  Set GDeletedItems = GDeletedFolder.Items
End Sub
Private Sub GDeletedItems_ItemAdd(ByVal Item As Object)
'Updateby ExtendOffice
Dim xTargetFolder As Outlook.Folder
On Error Resume Next
Select Case TypeName(Item)
  Case "MailItem", "PostItem", "ReportItem", "MeetingItem"
    Set xTargetFolder = GDeletedFolder.Folders("Deleted Mails")
    If xTargetFolder Is Nothing Then
      Set xTargetFolder = GDeletedFolder.Folders.Add("Deleted Mails", olFolderInbox)
    End If
  Case "AppointmentItem"
    Set xTargetFolder = GDeletedFolder.Folders("Deleted Appointments")
    If xTargetFolder Is Nothing Then
      Set xTargetFolder = GDeletedFolder.Folders.Add("Deleted Appointments", olFolderCalendar)
    End If
  Case "ContactItem", "DistListItem"
    Set xTargetFolder = GDeletedFolder.Folders("Deleted Contacts")
    If xTargetFolder Is Nothing Then
      Set xTargetFolder = GDeletedFolder.Folders.Add("Deleted Contacts", olFolderContacts)
    End If
  Case "TaskItem"
    Set xTargetFolder = GDeletedFolder.Folders("Deleted Tasks")
    If xTargetFolder Is Nothing Then
      Set xTargetFolder = GDeletedFolder.Folders.Add("Deleted Tasks", olFolderTasks)
    End If
  Case "JournalItem"
    Set xTargetFolder = GDeletedFolder.Folders("Deleted Journals")
    If xTargetFolder Is Nothing Then
      Set xTargetFolder = GDeletedFolder.Folders.Add("Deleted Journals", olFolderJournal)
    End If
  Case "NoteItem"
    Set xTargetFolder = GDeletedFolder.Folders("Deleted Notess")
    If xTargetFolder Is Nothing Then
      Set xTargetFolder = GDeletedFolder.Folders.Add("Deleted Notess", olFolderNotes)
    End If
End Select
If xTargetFolder Is Nothing Then Exit Sub
Item.Move xTargetFolder
Set xTargetFolder = Nothing
End Sub

3. Այնուհետև պահեք այս կոդը և վերագործարկեք Outlook-ը՝ այս կոդը ակտիվացնելու համար:

4. Այսուհետ, երբ դուք ջնջեք որևէ տարր, այն կտեղափոխվի տակ գտնվող համապատասխան տեսակի թղթապանակ Ջնջված իրերը թղթապանակ ինքնաբերաբար:

5. Արդյունքը դիտելու համար խնդրում ենք սեղմել պատկերակը թղթապանակի վահանակի ներքևում, այնուհետև կտտացրեք Թղթապանակներ վահանակի բոլոր թղթապանակները ընդլայնելու համար տես սքրինշոթները.