Ինչպե՞ս պահել կատեգորիան ՝ Outlook- ում էլ-նամակը պատասխանելիս կամ փոխանցելիս: 

Սովորաբար, երբ դուք պատասխանում կամ փոխանցում եք իմ կողմից դասակարգված էլ-նամակը, կատեգորիան ինքնաբերաբար կհեռացվի ուղարկված էլ. Եթե ​​ցանկանում եք կատեգորիան պահել պատասխանող կամ վերահասցեավորող ելքային էլ. Նամակների վրա, այս հոդվածը կներկայացնի դրա հետ վարվելու մեթոդ:

Պահեք կատեգորիան `միաժամանակ պատասխանելով կամ փոխանցելով նամակները VBA կոդով

---

Պահեք կատեգորիան `միաժամանակ պատասխանելով կամ փոխանցելով նամակները VBA կոդով

1. Անջատեք ALT + F11 բացել ստեղները Microsoft Visual Basic հավելվածների համար պատուհան.

2, Մեջ Microsoft Visual Basic հավելվածների համար պատուհանը, կրկնակի սեղմեք ԱյսOutlookSession- ը - ից Project1 (VbaProject.OTM) ռեժիմը բացելու պատուհանը, այնուհետև պատճենեք և կպցրեք հետևյալ կոդը դատարկ մոդուլի մեջ:

VBA կոդ. Էլ. Փոստին պատասխանելիս կամ փոխանցելիս պահեք կատեգորիան.

Private WithEvents GExplorer As Outlook.Explorer
Private WithEvents GInspectors As Outlook.Inspectors
Private WithEvents GMailItem As Outlook.MailItem
Private GCategories As String
Private Sub Application_Startup()
    Dim xApp As Outlook.Application
    Set xApp = Outlook.Application
    Set GExplorer = xApp.ActiveExplorer
    Set GInspectors = xApp.Inspectors
End Sub
Private Sub GExplorer_SelectionChange()
    On Error Resume Next
    If TypeName(GExplorer.Selection.Item(1)) <> "MailItem" Then Exit Sub
    Set GMailItem = GExplorer.Selection.Item(1)
    GCategories = GMailItem.Categories
End Sub
Private Sub GInspectors_NewInspector(ByVal Inspector As Inspector)
    On Error Resume Next
    If TypeName(Inspector.CurrentItem) <> "MailItem" Then Exit Sub
   Set GMailItem = Inspector.CurrentItem
    GCategories = GMailItem.Categories
End Sub
Private Sub GMailItem_Forward(ByVal Forward As Object, Cancel As Boolean)
    Call GetCategories(Forward)
End Sub
Private Sub GMailItem_Reply(ByVal Response As Object, Cancel As Boolean)
    Call GetCategories(Response)
End Sub
Private Sub GMailItem_ReplyAll(ByVal Response As Object, Cancel As Boolean)
    Call GetCategories(Response)
End Sub
Private Sub GetCategories(ByVal NewMail As Object)
    If NewMail.Class <> olMail Then Exit Sub
    NewMail.Categories = GCategories
End Sub

3, Ապա պահեք և փակեք այս կոդի պատուհանը, փակեք և վերագործարկեք Outlook- ը, այժմ, երբ դուք պատասխանեք կամ էլեկտրոնային նամակ ուղարկեք կատեգորիայի հետ, կատեգորիան կպահպանվի ելքային հաղորդագրության մեջ Ուղարկված նյութեր, տես նկարի նկարը.