Ինչպե՞ս սովորաբար պատասխանել Outlook- ի ուղարկված իրերի պանակում: 

Սովորաբար, երբ Դուք ուղարկված մարդկանց համար մեկ այլ լրացուցիչ հաղորդագրություն ուղարկելու համար կտտացնում եք Պատասխան հատկությունը Ուղարկված իրերի պանակում, ձեր սեփական էլ. Փոստի հասցեն կցուցադրվի Դեպ դաշտում, ինչպես ցույց է տրված հետևյալ նկարը: Սա կարող է տհաճ լինել ձեզ համար, որ ամեն անգամ փոխեք հասցեն: Ինչպե՞ս կարելի է ստիպել Outlook- ին օգտագործել ոչ թե ձեր, այլ ստացողի բուն հասցեն:

Սովորաբար պատասխանեք Ուղարկված իրերի թղթապանակում Outlook- ից ՝ Պատասխանել բոլոր հնարավորությամբ

Սովորաբար պատասխանեք Ուղարկված իրերի թղթապանակում Outlook- ից ՝ VBA կոդով

---

Սովորաբար պատասխանեք Ուղարկված իրերի թղթապանակում Outlook- ից ՝ Պատասխանել բոլոր հնարավորությամբ

Outlook- ում, Պատասխանել բոլորը առանձնահատկությունը կարող է օգնել ձեզ լուծել այս խնդիրը, խնդրում ենք արեք հետևյալ կերպ.

Երբ դուք պետք է պատասխանեք ուղարկված էլ.փոստին կրկին ուղարկելու համար `ստացողի սկզբնական հասցեն պահելու համար, սեղմեք Պատասխանել բոլորը կոճակը, և ստացողի սկզբնական հասցեն գտնվում է այստեղ Դեպի դաշտը, ինչպես ցույց է տրված հետևյալ նկարը.

---

Սովորաբար պատասխանեք Ուղարկված իրերի թղթապանակում Outlook- ից ՝ VBA կոդով

Երբեմն կարող եք մոռանալ այն Պատասխանել բոլորը գործառույթը ուղարկված հաղորդագրությունը պատասխանելիս, այնպես որ ստորև ներկայացված VBA կոդը կարող է օգնել ձեզ նորմալ պատասխանել Ուղարկված նյութերի պանակում ՝ օգտագործելով Պատասխանել հնարավորությունը: Կատարեք հետևյալ քայլերով.

1, Պահեք պահեք ALT + F11 բացել ստեղները Microsoft Visual Basic հավելվածների համար պատուհան.

2, Մեջ Microsoft Visual Basic հավելվածների համար պատուհանը, կրկնակի սեղմեք ԱյսOutlookSession- ը - ից Project1 (VbaProject.OTM) ռեժիմը բացելու պատուհանը, այնուհետև պատճենեք և կպցրեք հետևյալ կոդը դատարկ մոդուլի մեջ:

VBA կոդ: Սովորաբար պատասխանեք Outlook- ից Ուղարկված իրերի պանակում.

Option Explicit
Private WithEvents GExplorer As Explorer
Private WithEvents GMailItem As MailItem
Private Sub Application_Startup()
    Set GExplorer = Application.ActiveExplorer
End Sub
Private Sub GExplorer_SelectionChange()
   On Error Resume Next
   Set GMailItem = GExplorer.Selection.Item(1)
End Sub
Private Sub GMailItem_Reply(ByVal Response As Object, Cancel As Boolean)
Dim xResponse As MailItem
Dim xRecipients As Outlook.Recipients
Dim xRecipient As Outlook.Recipient
Dim i As Integer
Dim xTo As String, xCC As String, xBCC As String, xName As String
On Error Resume Next
If Application.ActiveExplorer.CurrentFolder <> Session.GetDefaultFolder(olFolderSentMail) Then
    Exit Sub
End If
Cancel = True
Set xResponse = GMailItem.Reply
Set xRecipients = GMailItem.Recipients
For i = xRecipients.Count To 1 Step -1
    Set xRecipient = xRecipients.Item(i)
    xName = xRecipient.Name
    If Left(xName, 1) = "'" Then
        xName = Mid(xName, 2, Len(xRecipient.Name) - 2)
    End If
    Select Case xRecipient.Type
        Case olTo
            xTo = xName & ";" & xTo
        Case olCC
            xCC = xName & ";" & xCC
        Case olBCC
            xBCC = xName & ";" & xBCC
    End Select
Next
With xResponse
    .To = xTo
    .CC = xCC
    .BCC = xBCC
End With
xResponse.Recipients.ResolveAll
xResponse.Display
End Sub

3, Դրանից հետո, պահեք կոդը և վերագործարկեք Outlook- ը ՝ կոդի էֆեկտն ստանալու համար, այժմ ՝ կտտացնելով պատասխանել փոստը նորից ուղարկելու համար Ուղարկված նյութեր թղթապանակ, ստացողի բնօրինակի հասցեն ցուցադրվում է To դաշտում, որքան անհրաժեշտ է: