Ինչպե՞ս տպել առաջադրանքները, որոնք հիմնված են կատեգորիայի վրա Outlook- ում:

Ենթադրենք, որ ձեր Outlook առաջադրանքներում կան տարբեր գույների կատեգորիաներ, և այժմ դուք ցանկանում եք տպել առաջադրանքների ցուցակները ՝ հիմնված կատեգորիաների վրա, տարբեր էջերում: Ինչպե՞ս կարող եք լուծել այս աշխատանքը Outlook- ում:

Տպեք առաջադրանքները ՝ հիմնված կատեգորիաների վրա տարբեր էջերում, ձեռքով մեկ առ մեկ

Տպեք առաջադրանքներ ՝ հիմնված կատեգորիաների վրա տարբեր էջերում ՝ VBA կոդով

Տպեք առաջադրանքները ՝ հիմնված կատեգորիաների վրա տարբեր էջերում, ձեռքով մեկ առ մեկ

Outlook- ում դուք կարող եք ձեռքով տպել տարբեր կատեգորիաների հիման վրա առաջադրանքները մեկ առ մեկ տարբեր էջերում, խնդրում ենք արեք հետևյալ կերպ.

1, Գործարկեք Outlook- ը և անցեք Առաջադրանքների վահանակ և ընտրեք առաջադրանքի թղթապանակը, որը ցանկանում եք տպել, ապա սեղմել Ctrl + E ակտիվացնել Որոնել տուփ, ապա ՝ տակ Որոնել էջանշանը, սեղմեք Կատեգորիա պատկերակը և ընտրեք մեկ գունավոր կատեգորիա, որը դուք պետք է տպեք, տեսեք ՝

փաստաթղթերի տպագրության առաջադրանքներն ըստ 1 կատեգորիայի

2, Եվ հետո, հատուկ գունային կատեգորիայի հետ կապված բոլոր առաջադրանքները միանգամից թվարկված են, տես նկարի նկարը.

փաստաթղթերի տպագրության առաջադրանքներն ըստ 2 կատեգորիայի

3, Դրանից հետո անցեք կտտացնելով Ֆայլ > տպել այս առաջադրանքների ցուցակը տպելու համար, ինչպես ցույց է տրված հետևյալ նկարը.

փաստաթղթերի տպագրության առաջադրանքներն ըստ 3 կատեգորիայի

4. Կրկնեք վերոհիշյալ քայլերը ՝ մյուս գույների կատեգորիաներով առաջադրանքների ցուցակները մեկ առ մեկ ձեռքով տպելու համար:

Տպեք առաջադրանքներ ՝ հիմնված կատեգորիաների վրա տարբեր էջերում ՝ VBA կոդով

Ահա VBA կոդ, որը կօգնի ձեզ միանգամից տարբեր էջերում տպել առաջադրված խնդիրները ՝ հիմնված կատեգորիայի վրա, կատարեք հետևյալ քայլերով.

1. Գնալ դեպի Խնդիր պատուհանը և ընտրեք առաջադրանքի թղթապանակը, որը ցանկանում եք տպել:

2, Ապա, պահեք պահումը ALT + F11 բացել ստեղները Microsoft Visual Basic հավելվածների համար պատուհան.

3, Եվ հետո, կտտացրեք Տեղադրել > Մոդուլներ, պատճենեք և տեղադրեք կոդը ներքևում բացված դատարկ մոդուլի մեջ.

VBA կոդ. Տպեք առաջադրանքները ՝ հիմնված կատեգորիաների վրա տարբեր էջերում.

Sub PrintTaskList_SpecificColorCategory()
    Dim xTaskItems As Outlook.Items
    Dim xTask As Outlook.TaskItem
    Dim xDictionary As Scripting.Dictionary
    Dim xCategoryArr As Variant, xCategory As Variant
    Dim xExcelApp As Excel.Application
    Dim xExcelWorkbook As Excel.Workbook
    Dim xExcelWorksheet As Excel.Worksheet
    Dim xSheet As Excel.Worksheet
    Dim xKey As Variant
    Dim xKeyStr As String
    Dim i As Long, xLastRow As Integer
    On Error Resume Next
    If Application.ActiveExplorer.CurrentFolder.DefaultItemType <> olTaskItem Then Exit Sub
    Set xTaskItems = Application.ActiveExplorer.CurrentFolder.Items
    Set xDictionary = New Scripting.Dictionary
    For Each xTask In xTaskItems
        xCategoryArr = Split(xTask.Categories, ",")
        For Each xCategory In xCategoryArr
            If xDictionary.Exists(Trim(xCategory)) = False Then
               xDictionary.Add Trim(xCategory), 0
            End If
        Next
    Next
    If xDictionary.Count = 0 Then
        MsgBox "The current Task doesn’t have any category", vbOKOnly + vbInformation, "Kutools for Outlook"
        Exit Sub
    End If
    Set xExcelApp = New Excel.Application
    Set xExcelWorkbook = xExcelApp.Workbooks.Add
    xExcelApp.Visible = True
    i = 0
    If xDictionary.Count > xExcelWorkbook.Sheets.Count Then
        xExcelWorkbook.Sheets.Add Count:=xDictionary.Count - xExcelWorkbook.Sheets.Count
    End If
    For Each xKey In xDictionary.Keys
        xKeyStr = CStr(xKey)
        i = i + 1
        Set xExcelWorksheet = xExcelWorkbook.Sheets(i)
        xExcelWorksheet.Name = xKeyStr
        With xExcelWorksheet
             .Range("A1") = xKeyStr
             .Range("A1").Font.Bold = True
             .Range("A1").Font.Size = 18
             .Range("A1", "C1").HorizontalAlignment = xlCenter
             .Range("A1", "C1").VerticalAlignment = xlCenter
             .Range("A1", "C1").Merge
             .Range("A2") = "Subject"
             .Range("A2").Font.Bold = True
             .Range("B2") = "Start Date"
             .Range("B2").Font.Bold = True
             .Range("C2") = "Due Date"
             .Range("C2").Font.Bold = True
        End With
        For Each xTask In xTaskItems
            If InStr(xTask.Categories, xKeyStr) > 0 Then
               xLastRow = xExcelWorksheet.UsedRange.Rows.Count + 1
               With xExcelWorksheet
                    .Range("A" & xLastRow) = xTask.Subject
                    .Range("B" & xLastRow) = xTask.StartDate
                    .Range("C" & xLastRow) = xTask.DueDate
               End With
            End If
        Next
        xExcelWorksheet.Columns("A:C").AutoFit
    Next
    For Each xSheet In xExcelWorkbook.Sheets
        xSheet.PrintOut
    Next
    xExcelWorkbook.Close False
    xExcelApp.Quit
End Sub

4. Այնուհետեւ կտտացրեք Գործիքներ > Սայլակ է Microsoft Visual Basic հավելվածների համար պատուհանը դուրս եկավ Հղումներ-նախագիծ 1 երկխոսության տուփ, ստուգեք Microsoft Excel օբյեկտների գրադարան և Microsoft Scripting Runtime ընտրանքներ Հասանելի հղումներ ցուցակի տուփ, տես նկարի նկարը.

փաստաթղթերի տպագրության առաջադրանքներն ըստ 4 կատեգորիայի

5, Եվ հետո, կտտացրեք OK կոճակը, հիմա սեղմեք F5 Այս ծածկագիրն աշխատեցնելու բանալին, ծածկագիրն ավարտելուց հետո տարբեր կատեգորիաներով առաջադրանքների ցուցակները կտպագրվեն տարբեր էջերում: