Ինչպե՞ս ավտոմատ կերպով նշել էլփոստերը `ելնելով Outlook- ի հատուկ կցորդից:

Հատուկ կարևոր հավելվածով որոշ էլ-նամակներ ստանալիս կարող է անհրաժեշտ լինել դրանք դրոշմել, որպեսզի արագ և հեշտությամբ գտնեք դրանք հոսքի համար: Այս հոդվածում ես կխոսեմ այն ​​նամակների մասին, որոնք կցված են որոշակի անուններով:

VBA կոդով հատուկ կցորդի հիման վրա ավտոմատ կերպով նշեք նամակները

---

VBA կոդով հատուկ կցորդի հիման վրա ավտոմատ կերպով նշեք նամակները

Հատուկ հավելված պարունակող էլփոստերը ավտոմատ կերպով նշելու համար խնդրում ենք կիրառել հետևյալ VBA կոդը.

1, Գործարկեք Outlook- ը և այնուհետև պահեք այն ALT + F11 բացել ստեղները Microsoft Visual Basic հավելվածների համար պատուհան.

2, Մեջ Microsoft Visual Basic հավելվածների համար պատուհանը, կրկնակի սեղմեք ԱյսOutlookSession- ը - ից Project1 (VbaProject.OTM) պատուհանը `նոր ռեժիմ բացելու համար, ապա պատճենեք և կպցրեք հետևյալ կոդը դատարկ մոդուլի մեջ:

VBA կոդ. Հատուկ հավելվածի հիման վրա ավտոմատ նշեք էլփոստերը.

Public WithEvents GMailItems As Outlook.Items
Private Sub Application_Startup()
    Set GMailItems = Outlook.Application.Session.GetDefaultFolder(olFolderInbox).Items
End Sub

Private Sub GMailItems_ItemAdd(ByVal Item As Object)
    If Item.Class <> olMail Then Exit Sub
    FlagEmail_SpecificAttachments Item
End Sub

Sub FlagEmail_SpecificAttachments(Mail As Outlook.MailItem)
    Dim xAttachment As Outlook.Attachment
    Dim xExt As String
    Dim xFileName As String
    If Mail.Attachments.Count = 0 Then Exit Sub
    For Each xAttachment In Mail.Attachments
        xExt = SplitPath(xAttachment.FileName, 2)
        xFileName = SplitPath(xAttachment.FileName, 1)
        Select Case xExt
            Case "txt", "xlsx", "docx", "pdf"  'Add the file extension as you need
                If InStr(LCase(xFileName), LCase("KTO")) > 0 Then 'Change the text of the attachment name
                    With Mail
                        .ReminderSet = True
                        .ReminderTime = Now + 1
                        .MarkAsTask olMarkTomorrow
                        .Save
                    End With
                End If
        End Select
    Next
End Sub

Public Function SplitPath(FullPath As String, ResultFlag As Integer) As String
Dim xSplitPos As Integer, xDotPos As Integer
xSplitPos = InStrRev(FullPath, "/")
xDotPos = InStrRev(FullPath, ".")
Select Case ResultFlag
    Case 0
        SplitPath = Left(FullPath, xSplitPos - 1)
    Case 1
        If xDotPos = 0 Then xDotPos = Len(FullPath) + 1
        SplitPath = Mid(FullPath, xSplitPos + 1, xDotPos - xSplitPos - 1)
    Case 2
        If xDotPos = 0 Then xDotPos = Len(FullPath)
        SplitPath = Mid(FullPath, xDotPos + 1)
    Case Else
    Err.Raise vbObjectError + 1, "SplitPath Function", "Invalid Parameter!"
End Select
End Function

ՆշումՎերը նշված ծածկագրում կարող եք փոխել ֆայլի ընդլայնումը և կցորդի ֆայլի անունը ձեր պահանջի համաձայն:

3, Ապա պահեք կոդը և վերագործարկեք Outlook- ը ՝ ծածկագիրն ուժի մեջ մտնելու համար, հիմա էլ. Նամակներ ստանալիս, որոնց կցորդների անունները պարունակում են նշված տեքստը, Outlook- ը ավտոմատ կերպով կնշի այս էլ. Փոստը հետևելու համար, տեսեք,