Ինչպե՞ս նշանակել Excel- ի տվյալներից:

Ենթադրելով, որ դուք ունեք նշանակման տվյալների աղյուսակ Excel- ի աշխատանքային թերթում, ինչպես ցույց է տրված հետևյալ նկարը, այժմ ուզում եք ներմուծել այս տվյալները Outlook օրացույցում: Ինչպե՞ս կարող էիք արագ զբաղվել այս գործով:

doc արտահանման գերազանց տվյալներ նշանակմանը 1

VBA կոդով Excel- ի տվյալներից նշանակումներ ստեղծեք

VBA կոդով Excel- ի տվյալներից նշանակումներ ստեղծեք

Excel- ի տվյալներից նշանակումներ ստեղծելու համար կարող եք կիրառել հետևյալ VBA կոդը, խնդրում ենք արեք հետևյալ կերպ.

1, Գործարկել Outlook- ը և պահեք այն ALT + F11 բացել ստեղները Microsoft Visual Basic հավելվածների համար պատուհան.

2: Սեղմեք Տեղադրել > Մոդուլներ, և տեղադրեք հետևյալ կոդը Մոդուլներ Պատուհանը:

VBA կոդ. Excel- ի տվյալների ներմուծում նշանակման համար.

Public Sub CreateOutlookApptz()
    Dim xAppointmentItem As Outlook.AppointmentItem
    Dim xNameSpace As Outlook.NameSpace
    Dim xCalendarFld As Outlook.MAPIFolder, xSubFolder As Outlook.MAPIFolder
    Dim xCalendarStr As String
    Dim I As Long
    Dim xFileDialog As FileDialog
    Dim xFilePath As String
    Dim xExcelApp As Excel.Application
    Dim xWb As Workbook
    Dim xWs As Worksheet
    On Error GoTo Err_Execute
    Set xExcelApp = New Excel.Application
    Set xFileDialog = xExcelApp.FileDialog(msoFileDialogFilePicker)
    With xFileDialog
        .Title = "Select a file"
        .Filters.Add "Microsoft Excel", "*.xlsx"
    End With
    If xFileDialog.Show = 0 Then Exit Sub
    xFilePath = xFileDialog.SelectedItems(1)
    Set xWb = xExcelApp.Workbooks.Open(xFilePath)
    Set xNameSpace = Outlook.Application.Session
    Set xCalendarFld = xNameSpace.GetDefaultFolder(olFolderCalendar)
    I = 2
    Set xWs = xWb.Worksheets.Item(1)
    xCalendarStr = xWb.Name
    If FolderExist(xCalendarFld, xCalendarStr) = False Then
        Set xSubFolder = xCalendarFld.Folders.Add(xCalendarStr, olFolderCalendar)
    Else
        Set xSubFolder = xCalendarFld.Folders(xCalendarStr)
    End If
    Do Until Trim(xWs.Cells(I, 1).Value) = ""
        Set xAppointmentItem = xSubFolder.Items.Add(olAppointmentItem)
        With xAppointmentItem
            .Start = xWs.Cells(I, 5) + xWs.Cells(I, 6)
            .End = xWs.Cells(I, 7) + xWs.Cells(I, 8)
            .Subject = xWs.Cells(I, 1)
            .Location = xWs.Cells(I, 2)
            .Body = xWs.Cells(I, 3)
            .BusyStatus = olBusy
            .ReminderMinutesBeforeStart = xWs.Cells(I, 9)
            .ReminderSet = True
            .Categories = xWs.Cells(I, 4)
            .Save
        End With
        I = I + 1
    Loop
    Set xAppointmentItem = Nothing
    Set olApp = Nothing
    xExcelApp.Quit
    Set xExcelApp = Nothing
    MsgBox "Import successfully!", vbInformation, "Kutools for Outlook"
    Exit Sub
Err_Execute:
    MsgBox "An error occurred - Exporting items to Calendar.", vbInformation, "Kutools for Outlook"
End Sub
Function FolderExist(CalFolder As Folder, FolderName As String) As Boolean
    Dim I As Integer
    Dim xSubFolder As Folder
    For I = 1 To CalFolder.Folders.Count
        Set xSubFolder = CalFolder.Folders.Item(I)
        If xSubFolder.Name = FolderName Then
            FolderExist = True
            Exit Function
        End If
    Next I
End Function

3, Դեռևս Microsoft Visual Basic հավելվածների համար պատուհանը, սեղմեք Գործիքներ > Սայլակ գնալու համար Հղումներ-նախագիծ 1 երկխոսության տուփ և ստուգեք Microsoft Excel օբյեկտների գրադարան տարբերակը Հասանելի հղումներ ցուցակի տուփ, տես նկարի նկարը.

doc արտահանման գերազանց տվյալներ նշանակմանը 2

4. Այնուհետեւ կտտացրեք OK կոճակը, հիմա սեղմեք F5 այս կոդը գործարկելու բանալին, և ա Ընտրեք ֆայլ ցուցադրվում է պատուհանը, ընտրեք Excel ֆայլը, որը ցանկանում եք ներմուծել Outlook- ում, տես նկարի նկարը.

doc արտահանման գերազանց տվյալներ նշանակմանը 3