Ինչպե՞ս Outlook- ում անհատապես օրացույց ուղարկել բազմաթիվ ստացողներին:

Սովորաբար, ստացողին կարող եք արագ և հեշտությամբ օրացույց ուղարկել ստացողին Էլեկտրոնային օրացույց առանձնահատկությունը Outlook- ում: Եթե ցանկանում եք անհատապես մի քանի կոնտակտների ուղարկել iCalendar ֆայլ որպես կցված օրացույց, ապա այն պետք է մեկ առ մեկ ուղարկեք: Այս հոդվածում ես կխոսեմ Outlook- ում անհատապես բազմաթիվ ստացողներին օրացույց ուղարկելու հեշտ եղանակի մասին:

Ուղարկեք օրացույց անհատապես բազմաթիվ ստացողներին ՝ VBA կոդով

Ուղարկեք օրացույց անհատապես բազմաթիվ ստացողներին ՝ VBA կոդով

Բազմաթիվ ստացողների օրացույցը առանձին ուղարկելու համար հետևյալ VBA կոդը կարող է օգնել ձեզ, արեք հետևյալ կերպ.

1, Նավարկել դեպի Կապ Մեզ Հետ պատուհանը և ընտրեք այն կոնտակտները, որոնց ուզում եք օրացույց ուղարկել:

2, Ապա պահեք ALT + F11 բացել ստեղները Microsoft Visual Basic հավելվածների համար պատուհան.

3: Սեղմեք Տեղադրել > Մոդուլներ, պատճենեք և տեղադրեք կոդը ներքևում բացված դատարկ մոդուլի մեջ, տես նկարի նկարը.

VBA կոդ. Ուղարկեք օրացույց անհատապես բազմաթիվ ստացողների

Sub EmailCalendarToMultiplePersonsSeparately()
Dim xSelection As Outlook.Selection
Dim xCalendarFolder As Outlook.Folder
Dim xCalendarExporter As Outlook.CalendarSharing
Dim xStartDate, xEndDate As Date
Dim xCalendarFile As String
Dim xContactItem As Outlook.ContactItem
Dim xDistListItem As Outlook.DistListItem
Dim xItem As Object
Dim xMailItem As Outlook.MailItem
Dim xFilePath, xFileName, xEmailAddress As String
Dim xRecipient As Recipient
On Error Resume Next
xFilePath = CreateObject("WScript.Shell").SpecialFolders(16) & "\MyCalendar"
If Dir(xFilePath, vbDirectory) = "" Then MkDir xFilePath
If Outlook.Application.ActiveExplorer.CurrentFolder.DefaultItemType <> olContactItem Then
    MsgBox "Please Select contacts first!", vbExclamation + vbOKOnly, "Kutools for Outlook"
    Exit Sub
End If
Set xSelection = Outlook.Application.ActiveExplorer.Selection
If xSelection Is Nothing Then Exit Sub
Set xCalendarFolder = Outlook.Application.Session.PickFolder
If xCalendarFolder Is Nothing Then Exit Sub
If xCalendarFolder.DefaultItemType <> olAppointmentItem Then Exit Sub
Set xCalendarExporter = xCalendarFolder.GetCalendarExporter
xStartDate = InputBox("Enter the start date:", "Kutools for Outlook", "")
If Len(Trim(xStartDate)) = 0 Then Exit Sub
xEndDate = InputBox("Enter the end date:", "Kutools for Outlook", "")
If Len(Trim(xEndDate)) = 0 Then Exit Sub
If xStartDate = #1/1/4501# Or xEndDate = #1/1/4501# Then Exit Sub
xFileName = "Calendar (" & Format(xStartDate, "YYYYMMDD") & " - " & Format(xEndDate, "YYYYMMDD") & ").ics"
xCalendarFile = xFilePath & "\" & xFileName
With xCalendarExporter
    .IncludeWholeCalendar = False
    .StartDate = xStartDate
    .EndDate = xEndDate
    .CalendarDetail = olFullDetails
    .IncludeAttachments = True
    .IncludePrivateDetails = False
    .RestrictToWorkingHours = False
    .SaveAsICal xCalendarFile
End With
For Each xItem In xSelection
    If xItem.Class = olContact Then
        Set xContactItem = xItem
        Set xMailItem = Outlook.Application.CreateItem(olMailItem)
        With xMailItem
            .To = xContactItem.Email1Address
            .Recipients.ResolveAll
            .Subject = xFileName
            .Attachments.Add xCalendarFile
            .Body = "Dear " & xContactItem.FullName & "," & vbCrLf & "Type body here..."
            .Display
        End With
    End If
    If xItem.Class = olDistributionList Then
        Set xDistListItem = xItem
        For i = 1 To xDistListItem.MemberCount
            Set xRecipient = xDistListItem.GetMember(i)
            Set xMailItem = Outlook.Application.CreateItem(olMailItem)
            With xMailItem
                .To = xRecipient.AddressEntry.Address
                .Recipients.ResolveAll
                .Subject = xFileName
                .Attachments.Add xCalendarFile
                .Body = "Dear " & xRecipient.Name & "," & vbCrLf & "Type body here..."
                .Display
            End With
        Next i
    End If
Next
End Sub

4, Կոդը տեղադրելուց հետո սեղմեք F5 այս կոդը գործարկելու բանալին, և ա Ընտրեք թղթապանակը երկխոսության տուփը դուրս է եկել, ընտրեք օրացույց, որը ցանկանում եք ուղարկել, տեսեք,

5. Սեղմել OKև ապա նշեք ամսաթվերի միջակայքը, որը ցանկանում եք ուղարկել օրացույցը հետևյալ արագ տուփերում, տե՛ս նկարը.

6, Եվ հետո, կտտացրեք OK, նոր էլփոստի հասցեները, որոնց կցված է օրացույցը, ստեղծվել են այնպես, ինչպես ցույց է տրված սքրինշոթը ցույց տալու համար, ապա պարզապես անհրաժեշտ է դրանք ուղարկել մեկ առ մեկ: