Ինչպե՞ս միանգամից մի քանի նախագիծ ուղարկել Outlook- ում:

Եթե ​​ձեր Drafts թղթապանակում կան բազմաթիվ նախագիծ հաղորդագրություններ, և այժմ, դուք ցանկանում եք դրանք միանգամից ուղարկել առանց մեկ առ մեկ ուղարկելու: Ինչպե՞ս կարող եք արագ և հեշտությամբ զբաղվել այս գործով Outlook- ում:

Միանգամից ուղարկեք բոլոր նախագծերի հաղորդագրությունները Outlook- ում `VBA կոդով

Միանգամից ուղարկեք բոլոր նախագծերի հաղորդագրությունները Outlook- ում `VBA կոդով

Հետևյալ VBA կոդերը կարող են օգնել ձեզ միանգամից ուղարկել բոլոր կամ ընտրված նամակների նախագիծը Drafts թղթապանակից, արեք հետևյալ կերպ.

1, Պահեք պահեք ALT + F11 բացել ստեղները Microsoft Visual Basic հավելվածների համար պատուհան.

2. Այնուհետեւ կտտացրեք Տեղադրել > Մոդուլներ, պատճենեք և տեղադրեք կոդը ներքևում բացված դատարկ մոդուլի մեջ, տես նկարի նկարը.

VBA կոդ. Ուղարկեք բոլոր նամակների նախագիծը միանգամից Outlook- ում.

Sub SendAllDraftEmails()
Dim xAccount As Account
Dim xDraftFld As Folder
Dim xItemCount As Integer
Dim xCount As Integer
Dim xDraftsItems As Outlook.Items
Dim xPromptStr As String
Dim xYesOrNo As Integer
Dim i As Long
Dim xCurFld As Folder
Dim xTmpFld As Folder
On Error Resume Next
xItemCount = 0
xCount = 0
Set xTmpFld = Nothing
Set xCurFld = Application.ActiveExplorer.CurrentFolder
For Each xAccount In Outlook.Application.Session.Accounts
    Set xDraftFld = xAccount.DeliveryStore.GetDefaultFolder(olFolderDrafts)
    xItemCount = xItemCount + xDraftFld.Items.Count
    If xDraftFld.EntryID = xCurFld.EntryID Then
        Set xTmpFld = xCurFld.Parent
    End If
Next xAccount
Set xDraftFld = Nothing
If xItemCount > 0 Then
   xPromptStr = "Are you sure to send out all the drafts?"
    xYesOrNo = MsgBox(xPromptStr, vbQuestion + vbYesNo, "Kutools for Outlook")
    If xYesOrNo = vbYes Then
        If Not xTmpFld Is Nothing Then
            Set Application.ActiveExplorer.CurrentFolder = xTmpFld
        End If
        VBA.DoEvents
        For Each xAccount In Outlook.Application.Session.Accounts
            Set xDraftFld = xAccount.DeliveryStore.GetDefaultFolder(olFolderDrafts)
            Set xDraftsItems = xDraftFld.Items
            For i = xDraftsItems.Count To 1 Step -1
                If xDraftsItems.Item(i).Recipients.Count <> 0 Then
                    xDraftsItems.Item(i).sEnd
                    xCount = xCount + 1
                End If
            Next
        Next xAccount
        VBA.DoEvents
        Set Application.ActiveExplorer.CurrentFolder = xCurFld
        MsgBox "Successfully sent " & xCount & " messages", vbInformation, "Kutools for Outlook"
    End If
Else
    MsgBox "No Drafts!", vbInformation + vbOKOnly, "Kutools for Outlook"
End If
End Sub

3, Ապա պահեք կոդը և սեղմեք F5 Այս կոդն աշխատեցնելու բանալին, կհայտնվի հուշման տուփ ՝ բոլոր նախագիծը ուղարկելու դեպքում հիշեցնելու համար, կտտացրեք այո, տես նկարի նկարը.

4, Եվ դուրս կգա երկխոսության պատուհան `հիշեցնելու համար, թե քանի նամակ է ուղարկվել, տես նկարի նկարը.

5. Եվ այնուհետեւ կտտացրեք OK կոճակը, բոլոր էլ. փոստերը Նախագծեր թղթապանակը կուղարկվի միանգամից, տես նկարի նկարը.

Նշումներ:

1. Վերոհիշյալ կոդը ձեր Outlook- ի բոլոր հաշիվներից կուղարկի բոլոր նամակների նախագիծը:

2. Եթե դուք պարզապես ցանկանում եք ուղարկել որոշակի էլ-նամակներ Drafts թղթապանակից, խնդրում ենք կիրառել հետևյալ VBA կոդը.

VBA կոդ. Ուղարկված ընտրված էլ-նամակները ուղարկեք Drafts թղթապանակից.

Sub SendSelectedDraftEmails()
Dim xSelection As Selection
Dim xPromptStr As String
Dim xYesOrNo As Integer
Dim i As Long
Dim xAccount As Account
Dim xCurFld As Folder
Dim xDraftsFld As Folder
Dim xTmpFld As Folder
Dim xArr() As String
Dim xCount As Integer
Dim xMail As MailItem
On Error Resume Next
xCount = 0
Set xTmpFld = Nothing
Set xCurFld = Application.ActiveExplorer.CurrentFolder
For Each xAccount In Outlook.Application.Session.Accounts
    Set xDraftsFld = xAccount.DeliveryStore.GetDefaultFolder(olFolderDrafts)
    If xDraftsFld.EntryID = xCurFld.EntryID Then
        Set xTmpFld = xCurFld.Parent
    End If
Next xAccount
If xTmpFld Is Nothing Then
    MsgBox "The current folder is not a draft folder", vbInformation, "Kutools for Outlook"
    Exit Sub
End If
Set xSelection = Outlook.Application.ActiveExplorer.Selection
If xSelection.Count > 0 Then
    xPromptStr = "Are you sure to send out the selected " & xSelection.Count & " draft item(s)?"
    xYesOrNo = MsgBox(xPromptStr, vbQuestion + vbYesNo, "Kutools for Outlook")
    If xYesOrNo = vbYes Then
        ReDim xArr(xSelection.Count - 1)
        For i = 1 To xSelection.Count
            xArr(i - 1) = xSelection.Item(i).EntryID
        Next
        Set Application.ActiveExplorer.CurrentFolder = xTmpFld
        VBA.DoEvents
        For i = 0 To UBound(xArr)
            Set xMail = Application.Session.GetItemFromID(xArr(i))
            If xMail.Recipients.Count <> 0 Then
                xMail.sEnd
                xCount = xCount + 1
            End If
        Next
        VBA.DoEvents
        Set Application.ActiveExplorer.CurrentFolder = xCurFld
        MsgBox "Successfully sent " & xCount & " messages", vbInformation, "Kutools for Outlook"
    End If
Else
    MsgBox "No items selected!", vbInformation, "Kutools for Outlook"
End If
End Sub

Related Articles:

Ինչպե՞ս էլեկտրոնային փոստով ուղարկել մի քանի հասցեատերերի անհատապես Outlook- ում:

Ինչպե՞ս անհատականացված զանգվածային էլ-նամակներ Excel- ից ցուցակ ուղարկել Outlook- ի միջոցով:

Ինչպե՞ս օրացույց ուղարկել Outlook- ում անհատապես մի քանի ստացողի:

Ինչպե՞ս էլեկտրոնային նամակ ուղարկել մի քանի հասցեատերերի ՝ առանց նրանց Outlook- ի իմացության:

---

Kutools Outlook- ի համար. 100 առաջադեմ առանձնահատկություններ է բերում Outlook- ին և շատ ավելի հեշտացնում աշխատանքը:

• Auto CC / BCC կանոններով `էլ. նամակ ուղարկելիս; Ավտոմեքենաների փոխանցում Բազմաթիվ նամակներ ըստ սովորույթի; Ավտոմատ պատասխան առանց փոխանակման սերվերի և ավելի ավտոմատ հատկությունների ...
• Նախազգուշացում BCC- ի համար - ցույց տալ հաղորդագրությունը, երբ փորձում ես պատասխանել բոլորին եթե ձեր փոստի հասցեն գտնվում է BCC ցուցակում; Հիշեցրեք հավելվածները բաց թողնելիսև ավելին հիշեցնում են հատկությունները ...
• Պատասխանեք (բոլորը) փոստի խոսակցության բոլոր կցորդներով; Պատասխանեք շատ նամակների վայրկյանների ընթացքում; Ավտոմատ ավելացնել ողջույնները երբ պատասխանել; Ավելացնել ամսաթիվը վերնագրում ...
• Կցման գործիքներ. Կառավարեք բոլոր կցորդները բոլոր փոստերում, Ավտոմատ անջատում, Սեղմել բոլորը, Վերանվանել բոլորը, պահպանել բոլորը ... Արագ զեկույց, Հաշվեք ընտրված նամակները...
• Հզոր անպիտան նամակներ ըստ սովորույթի; Հեռացրեք կրկնօրինակ նամակները և կոնտակտները... Հնարավորություն տվեք Outlook- ում ավելի խելացի, արագ և լավ կատարել:

Կարդալ ավելին... Ներբեռնել հիմա...