Excel-ի ուսուցում – հանեք տեքստը կամ թիվը ըստ կոնկրետ դիրքի
Շատ դեպքերում ձեզ կարող է անհրաժեշտ լինել միայն բջջի նախադասությունից կամ տեքստային տողից օգտակար բովանդակություն հանել, օրինակ՝ հասցեից հանել գավառը, նախադասությունից էլփոստի հասցեն հանել, խոսակցությունից սուրհանդակային հաշիվը հանել, եւ այլն։ Այս ձեռնարկը նեղացնում է արդյունահանումը բջջի որոշակի դիրքի վրա և հավաքում է տարբեր մեթոդներ՝ օգնելու Excel-ում բջիջից տեքստ կամ թվեր հանել ըստ հատուկ դիրքի:
Բովանդակություն: [Թաքցնել]
Տեքստը հանել ըստ դիրքի
Այս բաժինը հավաքում է ընդհանուր դիրքեր, որտեղ տեքստը կարելի է հանել բջիջից և տրամադրում է համապատասխան մեթոդներ՝ դրանք քայլ առ քայլ մշակելու համար: Լրացուցիչ մանրամասների համար կարող եք թերթել:
1. Ձախից կամ աջից հանեք նիշերի քանակը
Տողի ձախ կամ աջ կողմից նիշերի քանակը հանելու համար կարող եք փորձել ստորև նշված մեթոդներից մեկը:
1.1 Բանաձևերով հանեք առաջին կամ վերջին N նիշերը
Ենթադրելով, որ դուք ունեք տեքստային տողերի ցանկ B սյունակում, ինչպես ցույց է տրված ստորև ներկայացված սքրինշոթում, յուրաքանչյուր տողից առաջին 2 նիշերը և վերջին 2 նիշերը հանելու համար կարող եք կիրառել հետևյալ բանաձևերը:
Տեքստային տողից հանեք առաջին N նիշերը
LEFT ֆունկցիան կարող է օգնել հեշտությամբ հանել առաջին N նիշերը Excel-ում տեքստային տողից:
Ընդհանուր բանաձև
=LEFT(text_string,[num_chars])
Արձանագրություններ
Այժմ դուք կարող եք կիրառել այս բանաձևը՝ B սյունակի բջիջներից առաջին 2 նիշերը հանելու համար:
1. Ընտրեք դատարկ բջիջ, պատճենեք կամ մուտքագրեք ստորև բերված բանաձևը և սեղմեք կոճակը Մտնել բանալին առաջին արդյունքը ստանալու համար: Ընտրեք արդյունքի բջիջը և քաշեք դրա Autofill Handle-ը՝ բանաձևը այլ բջիջների վրա կիրառելու համար:
=LEFT(B5,2)
Այժմ հանվել են B2:B5 տիրույթի յուրաքանչյուր բջիջի առաջին 10 նիշերը:
Տեքստային տողից հանեք վերջին N նիշերը
Այստեղ մենք կիրառում ենք RIGHT ֆունկցիան Excel-ում տեքստային տողից վերջին N նիշերը հանելու համար:
Ընդհանուր բանաձև
=RIGHT(text_string,[num_chars])
Արձանագրություններ
Ընտրեք դատարկ բջիջ, պատճենեք կամ մուտքագրեք ստորև բերված բանաձևը և սեղմեք կոճակը Մտնել արդյունք ստանալու բանալին: Այնուհետև ընտրեք այս արդյունքի բջիջը և քաշեք դրա Ինքնալրացման կարգավորիչը՝ այլ արդյունքներ ստանալու համար:
=RIGHT(B5,2)
1.2 Հանեք առաջին կամ վերջին N նիշերը զարմանալի գործիքով
Թեև վերը նշված բանաձևերը պարզ են, տեքստային տողերի երկար ցուցակից առաջին կամ վերջին n նիշը հանելու համար, դուք դեռ պետք է քաշեք AutoFill Handle-ը վերևից ներքև, ինչը միգուցե մի փոքր ժամանակատար է: Այստեղ խորհուրդ է տալիս Excel- ի համար նախատեսված գործիքներ'S Քաղվածք տեքստ օգտակար ծրագիր, որն օգնում է զանգվածաբար դուրս բերել առաջին կամ վերջին N նիշերը տեքստային տողերի ցանկից:
1. Ընտրեք տեքստային տողերի ցանկը, որից ցանկանում եք նախապես հանել տեքստը և սեղմեք Կուտոլս > Տեքստ > Քաղվածք տեքստ.
2. Պատուհանման մեջ Քաղվածք տեքստ երկխոսության տուփ, դուք պետք է կազմաձևեք հետևյալը.
ՆշումՏեքստային տողի փոփոխության դեպքում արդյունքը դինամիկ դարձնելու համար կարող եք ստուգել Տեղադրեք որպես բանաձև տուփ:
3. Հաջորդ պատուհանում Քաղվածք տեքստ երկխոսության վանդակում, ընտրեք բջիջ, որը կարտահանվի արդյունահանված նիշերը և կտտացրեք OK.
Այնուհետև նշված առաջին կամ վերջին N նիշերը զանգվածաբար հանվում են ընտրված բջիջներից:
Կտտացրեք ՝ այս գործառույթի մասին ավելին իմանալու համար:
Եթե ցանկանում եք ունենալ այս օգտակար ծառայության անվճար փորձարկում (30-օրյա), խնդրում ենք կտտացնել այն ներբեռնելու համար, և այնուհետև անցեք գործողությունը կիրառելու վերը նշված քայլերին համապատասխան:
2. Քաղեք տեքստը որոշակի նիշից/բառից առաջ կամ հետո
Որոշ նիշից կամ բառից առաջ կամ հետո տեքստ հանելու համար այս բաժնի տարբեր սցենարները կբավարարեն ձեր կարիքները:
2.1 Քաղեք տեքստ առաջին սահմանազատիչից առաջ կամ հետո (նիշ)
Ինչպես ցույց է տրված ստորև ներկայացված սքրինշոթում, B4:B10 միջակայքի յուրաքանչյուր բջիջից առաջին բաժանիչից առաջ կամ հետո տեքստ հանելու համար կարող եք կիրառել ստորև նշված մեթոդներից մեկը:
2.1.1 Քաղեք տեքստը առաջին սահմանազատիչից առաջ բանաձևով
LEFT և FIND ֆունկցիաների վրա հիմնված բանաձևի կիրառումը կարող է օգնել տեքստը հանել բջիջից առաջին սահմանազատիչից առաջ: Այն իրականացնելու համար կարող եք հետևել ստորև նշված քայլերին:
Ընդհանուր բանաձև
=LEFT(text_string,FIND("delimiter",text_string,1)-1)
Արձանագրություններ
Ընտրեք դատարկ բջիջ, պատճենեք կամ մուտքագրեք դրա մեջ ստորև բերված բանաձևը և սեղմեք կոճակը Մտնել բանալին առաջին արդյունքը ստանալու համար: Ընտրեք արդյունքի առաջին բջիջը և քաշեք դրա Ինքնալրացման բռնիչը ներքև՝ մյուս բջիջների առաջին սահմանազատիչից առաջ տեքստերը ստանալու համար:
=LEFT(B5,FIND("-",B5,1)-1)
2.1.2 Քաղեք տեքստ առաջին սահմանազատիչից հետո բանաձևով
Ստորև բերված բանաձևն օգնում է Excel-ի բջիջից առաջին սահմանազատիչից հետո տեքստ հանել:
Ընդհանուր բանաձև
=MID(text_string,FIND("delimiter",text_string)+1,LEN(text_string))
Արձանագրություններ
=MID(B5,FIND("-",B5)+1,LEN(B5))
2.1.3 Հանեք տեքստը առաջին սահմանազատիչից առաջ կամ հետո զարմանալի գործիքով
Այստեղ բարձր խորհուրդ է տրվում Քաղվածք տեքստ օգտակարությունը Kutools Excel- ի համար. Այս ֆունկցիայի միջոցով դուք հեշտությամբ կարող եք տեքստեր հանել առաջին սահմանազատիչից առաջ կամ հետո մի շարք բջիջներից զանգվածաբար:
1. Ընտրեք այն բջիջների շրջանակը, որտեղ ցանկանում եք հանել տեքստը, այնուհետև սեղմեք Կուտոլս > Տեքստ > Քաղվածք տեքստ.
2. Մեջ Քաղվածք տեքստ երկխոսության տուփ, դուք պետք է կազմաձևեք հետևյալը.
Նշում: Արդյունքը դինամիկ դարձնելու համար, երբ տեքստային տողը փոխվում է, կարող եք ստուգել «Տեղադրել որպես բանաձև» վանդակը:
3. Հետո մեկ այլ Քաղվածք տեքստ Երկխոսության տուփը բացվում է, ընտրեք բջիջ՝ արդյունքները դուրս բերելու համար և սեղմեք OK.
Այնուհետև ընտրված բջիջներից միանգամից արդյունահանվում են առաջին սահմանազատիչից առաջ կամ հետո տեքստերը:
Այս հատկության մասին ավելին իմանալու համար այցելեք՝ Արագ հանեք որոշակի տեքստ Excel-ի բջիջներից.
Եթե ցանկանում եք ունենալ այս օգտակար ծառայության անվճար փորձարկում (30-օրյա), խնդրում ենք կտտացնել այն ներբեռնելու համար, և այնուհետև անցեք գործողությունը կիրառելու վերը նշված քայլերին համապատասխան:
2.2 Քաղեք տեքստը վերջին սահմանազատիչից առաջ կամ հետո (նիշ)
Վերոնշյալ քայլերում մենք սովորեցինք տեքստը բջիջից առաջին սահմանազատիչից առաջ կամ հետո հանելու մեթոդները: Ինչպես ցույց է տրված ստորև ներկայացված սքրինշոթում, այս բաժինը ձեզ ցույց կտա երկու բանաձև՝ տեքստը բջիջից վերջին բաժանիչից առաջ կամ հետո հանելու համար: Այն իրականացնելու համար կարող եք հետևել ստորև նշված քայլերին:
2.2.1 Քաղեք տեքստը վերջին սահմանազատիչից առաջ բանաձևով
Բջջից վերջին սահմանազատիչից առաջ տեքստ հանելու համար կարող եք օգտագործել SEARCH, LEN և SUBSTITUTE գործառույթները LEFT ֆունկցիայի ներսում:
Ընդհանուր բանաձև
=LEFT(text_string,SEARCH("#",SUBSTITUTE(text_string,"delimiter","#",LEN(text_string)-LEN(SUBSTITUTE(text_string,"delimiter",""))))-1)
Արձանագրություններ
Ընտրեք բջիջ, մուտքագրեք ստորև բերված բանաձևը և սեղմեք կոճակը Մտնել արդյունք ստանալու բանալին: Ընտրեք արդյունքի այս բջիջը և քաշեք դրա Ինքնալրացման կարգավորիչը ներքև՝ նույն սյունակի տեքստային այլ տողերից տեքստերը հանելու համար:
=LEFT(B5,SEARCH("#",SUBSTITUTE(B5,"-","#",LEN(B5)-LEN(SUBSTITUTE(B5,"-",""))))-1)
2.2.2 Քաղեք տեքստը վերջին սահմանազատիչից հետո բանաձևով
Բջջից վերջին սահմանազատիչից առաջ տեքստը հանելուց հետո կարող եք կիրառել ստորև բերված բանաձևը՝ տեքստը վերջին սահմանազատիչից հետո հանելու համար, ինչպես ձեզ անհրաժեշտ է:
Ընդհանուր բանաձև
=RIGHT(text_string,LEN(text_string)-SEARCH("#",SUBSTITUTE(text_string,"delimiter","#",LEN(text_string)-LEN(SUBSTITUTE(text_string,"delimiter","")))))
Արձանագրություններ
Ընտրեք բջիջ, մուտքագրեք ստորև բերված բանաձևը և սեղմեք կոճակը Մտնել արդյունք ստանալու բանալին: Ընտրեք արդյունքի այս բջիջը և քաշեք դրա Ինքնալրացման կարգավորիչը ներքև՝ նույն սյունակի տեքստային այլ տողերից տեքստերը հանելու համար:
=RIGHT(B5,LEN(B5)-SEARCH("#",SUBSTITUTE(B5,"-","#",LEN(B5)-LEN(SUBSTITUTE(B5,"-","")))))
2.3 Քաղեք տեքստը n-րդ նիշից հետո
Նայեք ստորև բերված օրինակին, կա տեքստային տողերի ցանկ B4:B10 միջակայքում, յուրաքանչյուր բջիջից երրորդ նիշից հետո տեքստը հանելու համար կարող եք կիրառել բանաձև՝ հիմնված MID ֆունկցիայի և LEN ֆունկցիայի վրա:
Ընդհանուր բանաձև
=MID(text_string,nth_char+1,LEN(text_string))
Արձանագրություններ
Ընտրեք դատարկ բջիջ, պատճենեք կամ մուտքագրեք դրա մեջ ստորև բերված բանաձևը և սեղմեք կոճակը Մտնել արդյունք ստանալու բանալին: Ընտրեք այս արդյունքի բջիջը և քաշեք դրա ավտոմատ լրացման բռնիչը՝ այլ արդյունքներ ստանալու համար:
=MID(B5,3+1,LEN(B5))
2.4 Տեքստային տողից հանիր n-րդ բառը
Ենթադրենք, որ դուք ունեք տեքստային տողերի ցանկ, ինչպես ցույց է տրված ստորև ներկայացված սքրինշոթում, և ցանկանում եք տեքստային տողից հանել միայն n-րդ բառը, այս բաժինը տրամադրում է երեք եղանակ՝ այն կատարելու համար:
2.4.1 Բանաձևով հանի՛ր n-րդ բառը
Դուք կարող եք համատեղել TRIM, MID, SUBSTITUTE, REPT և LEN գործառույթները՝ վանդակում տեքստային տողից n-րդ բառը հանելու համար:
Ընդհանուր բանաձև
=TRIM(MID(SUBSTITUTE(text_string," ",REPT(" ",LEN((text_string))), (N-1)*LEN((text_string)+1, LEN((text_string)))
Արձանագրություններ
Այս դեպքում B5:B10 միջակայքը պարունակում է տեքստային տողեր, D5:D10-ը պարունակում է n-րդ բառը ներկայացնող թվեր, եկեք կիրառենք այս բանաձևը՝ n-րդ բառը տեքստային տողից հանելու համար:
Ընտրեք դատարկ բջիջ, պատճենեք կամ մուտքագրեք դրա մեջ ստորև բերված բանաձևը և սեղմեք կոճակը Մտնել բանալին առաջին արդյունքը ստանալու համար: Ընտրեք այս արդյունքի բջիջը և քաշեք դրա Autofill Handle-ը ներքև՝ մյուս բջիջների n-րդ բառը ստանալու համար:
=TRIM(MID(SUBSTITUTE(B5," ",REPT(" ",LEN(B5))), (D5-1)*LEN(B5)+1, LEN(B5)))
Նշում: Դուք կարող եք ուղղակիորեն մուտքագրել n-րդ թիվը բանաձևում հետևյալ կերպ.
=TRIM(MID(SUBSTITUTE(B5," ",REPT(" ",LEN(B5))), (2-1)*LEN(B5)+1, LEN(B5)))
2.4.2 Հանեք n-րդ բառը Օգտատիրոջ կողմից սահմանված գործառույթով
Բացի վերը նշված բանաձևից, դուք կարող եք նաև կիրառել օգտվողի կողմից սահմանված գործառույթ Excel-ի բջիջից n-րդ բառը հանելու համար:
1. Սեղմեք ալտ + F11 բացել ստեղները Microsoft Visual Basic հավելվածների համար պատուհան.
2. Մեջ Microsoft Visual Basic հավելվածների համար պատուհանը, սեղմեք Տեղադրել > Մոդուլ, և ապա պատճենեք ներքևում գտնվող VBA-ն կոդի պատուհանում:
VBA կոդը. հանեք n-րդ բառը բջիջի տեքստային տողից
Function ExtractTheNthWord(Source As String, Position As Integer)
'Update by Extendoffice 20211202
Dim arr() As String
arr = VBA.Split(Source, " ")
xCount = UBound(arr)
If xCount < 1 Or (Position - 1) > xCount Or Position < 0 Then
FindWord = ""
Else
FindWord = arr(Position - 1)
End If
End Function
3. Սեղմեք ալտ + Q ստեղները փակելու համար Microsoft Visual Basic հավելվածների համար պատուհան.
4. Վերադարձեք աշխատաթերթ, որը պարունակում է տեքստային տողեր, որոնցից ցանկանում եք հանել n-րդ բառը: Ընտրեք դատարկ բջիջ, պատճենեք կամ մուտքագրեք դրա մեջ ստորև բերված բանաձևը և սեղմեք կոճակը Մտնել բանալին՝ n-րդ բառը ստանալու համար:
=FindWord(B5,D5)
Or
=FindWord(B5,2)
Նշում: բանաձևում D5-ը այն բջիջն է, որը պարունակում է n-րդ բառը ներկայացնող թիվ: Որպես այլընտրանք, դուք կարող եք ուղղակիորեն փոխարինել բջջային հղումը թվով:
5. Ընտրեք արդյունքի բջիջը և քաշեք դրա AutoFill Handle-ը ներքև՝ այլ բջիջների տեքստային տողերից n-րդ բառը հանելու համար:
2.4.3 Հանեք n-րդ բառը զարմանալի գործիքով
Եթե դուք չեք ցանկանում ձեռքով կիրառել վերը նշված բանաձևը կամ օգտագործողի կողմից սահմանված գործառույթը, այստեղ խորհուրդ է տրվում Kutools-ը Excel-ի համար: Բջջում դուրս բերել իններորդ բառը օգտակար. Այս հատկանիշով դուք կարող եք հեշտությամբ հանել n-րդ բառը բջիջի տեքստային տողից միայն մի քանի կտտոցով:
1. Արդյունքը տեղադրելու համար ընտրեք բջիջ և սեղմեք Կուտոլս > Բանաձևի օգնական > Տեքստ > Էքստրակտ բջջի n-րդ բառը, Տեսեք,
2. Մեջ Բանաձևեր օգնողը երկխոսության տուփ, դուք պետք է կազմաձևեք հետևյալը.
3. Այնուհետև n-րդ (երկրորդ) բառը հանվում է B5 բջիջի տեքստային տողից, և դուք կարող եք տեսնել, որ միևնույն ժամանակ ստեղծվել է բանաձև: Ընտրեք այս արդյունքի բջիջը և քաշեք դրա Ինքնալրացման բռնիչը ներքև՝ այլ տեքստային տողերից n-րդ բառը ստանալու համար:
Կտտացրեք ՝ այս գործառույթի մասին ավելին իմանալու համար:
Եթե ցանկանում եք ունենալ այս օգտակար ծառայության անվճար փորձարկում (30-օրյա), խնդրում ենք կտտացնել այն ներբեռնելու համար, և այնուհետև անցեք գործողությունը կիրառելու վերը նշված քայլերին համապատասխան:
2.5 Քաղեք տեքստը սահմանազատողի n-րդ հայտնվելուց առաջ կամ հետո
Ենթադրենք, որ դուք ունեք տեքստային տողերի ցանկ, ինչպես ցույց է տրված ստորև ներկայացված սքրինշոթում: Տեքստը տարածության երկրորդ հայտնվելուց առաջ կամ հետո հանելու համար այս բաժինը տրամադրում է երկու բանաձև, որոնք կօգնեն ձեզ կատարել այն:
2.5.1 Քաղեք տեքստը նախքան սահմանազատողի n-րդ հայտնվելը
Դուք կարող եք օգտագործել LEFT ֆունկցիան SUBSTITUTE և FIND ֆունկցիաների հետ միասին՝ Excel-ի բջիջից n-րդ հայտնությունից առաջ տեքստ հանելու համար:
Ընդհանուր բանաձև
=LEFT(SUBSTITUTE(text_string,"delimiter",CHAR(9),n),FIND(CHAR(9),SUBSTITUTE(text_string,"delimiter",CHAR(9),n),1)-1)
Արձանագրություններ
Ընտրեք բջիջ, պատճենեք կամ մուտքագրեք ստորև բերված բանաձևը և սեղմեք կոճակը Մտնել արդյունք ստանալու բանալին: Ընտրեք այս արդյունքի բջիջը և քաշեք այն Ինքնալրացման կարգավորիչը ներքև՝ ցանկում այլ արդյունքներ ստանալու համար:
=LEFT(SUBSTITUTE(B5," ",CHAR(9),2),FIND(CHAR(9),SUBSTITUTE(B5," ",CHAR(9),2),1)-1)
Նշում: Բանաձևում B5-ը տեքստային տող պարունակող բջիջն է, որից ցանկանում եք հանել տեքստը. «» այստեղ ներկայացնում է բացատ, իսկ 2 թիվը ներկայացնում է տարածության երկրորդ առաջացումը: Դուք կարող եք դրանք փոխել ըստ ձեր կարիքների:
2.5.2 Քաղեք տեքստը սահմանազատողի n-րդ հանդիպումից հետո
Սահմանազատիչի n-րդ հանդիպումից հետո տեքստ հանելու համար կարող եք կիրառել RIGHT ֆունկցիան SUBSTITUTE, LEN և FIND գործառույթներով:
Ընդհանուր բանաձև
=RIGHT(SUBSTITUTE(text_string, "delimiter", CHAR(9), n), LEN(text_string)- FIND(CHAR(9), SUBSTITUTE(text_string, "delimiter", CHAR(9), n), 1) + 1)
Արձանագրություններ
Այժմ դուք կարող եք կիրառել այս բանաձևը՝ B5:B10 միջակայքի յուրաքանչյուր բջիջից տարածության երկրորդ հայտնվելուց հետո տեքստը հանելու համար հետևյալ կերպ.
Ընտրեք բջիջ, մուտքագրեք ստորև բերված բանաձևը և սեղմեք կոճակը Մտնել արդյունք ստանալու բանալին: Ընտրեք այս արդյունքի բջիջը և քաշեք այն Ինքնալրացման կարգավորիչը ներքև՝ այլ արդյունքներ ստանալու համար:
=RIGHT(SUBSTITUTE(B5, " ", CHAR(9), 2), LEN(B5)- FIND(CHAR(9), SUBSTITUTE(B5, " ", CHAR(9), 2), 1) + 1)
2.6 Քաղեք տեքստը տողի ընդմիջումից առաջ կամ հետո
Ենթադրենք, որ դուք ունեք պատվերների ցանկ B սյունակում և ցանկանում եք յուրաքանչյուր բջիջից հանել միայն ամսաթվի մասը և արտադրանքի համարը: Դա կատարելու համար կարող եք օգտագործել ստորև բերված Excel բանաձևերը:
2.6.1 Քաղեք տեքստը մինչև առաջին տողի ընդմիջումը բանաձևով
Ինչպես տեսնում եք վերևի սքրինշոթում, ամսաթվի մասը տեղակայվում է բջջի առաջին տողի ընդմիջումից առաջ: Այս բաժինը ցույց կտա LEFT ֆունկցիան SEARCH ֆունկցիայի հետ միասին, որը կօգնի ձեզ հանել տեքստը նախքան բջիջի առաջին տողի ընդմիջումը:
Ընդհանուր բանաձև
=LEFT(cell, SEARCH(CHAR(10), cell)-1)
Արձանագրություններ
Ընտրեք դատարկ բջիջ, պատճենեք կամ մուտքագրեք դրա մեջ ստորև բերված բանաձևը և սեղմեք կոճակը Մտնել արդյունք ստանալու բանալին: Ընտրեք այս արդյունքի բջիջը և այնուհետև քաշեք դրա Autofill Handle-ը՝ այս բանաձևը այլ բջիջների վրա կիրառելու համար:
=LEFT(B5, SEARCH(CHAR(10), B5)-1)
Այնուհետև կարող եք տեսնել տեքստը մինչև B5:B8 տիրույթի յուրաքանչյուր բջիջի առաջին տողի ընդմիջումը, ինչպես ցույց է տրված ստորև ներկայացված սքրինշոթում:
Նշում: Բանաձևում CHAR(10)-ը ներկայացնում է Windows-ի տողերի ընդմիջում:
2.6.2 Վերջին տողի ընդմիջումից հետո հանել տեքստը բանաձևով
Նախորդ քայլում մենք խոսեցինք այն մասին, թե ինչպես կարելի է տեքստ հանել մինչև բջջի առաջին տողի ընդմիջումը: Եվ այս մասը կուղղորդի ձեզ, թե ինչպես կարելի է տեքստ հանել վերջին տողի ընդմիջումից հետո մեկ այլ բանաձևով բջիջում:
Ընդհանուր բանաձև
=TRIM(RIGHT(SUBSTITUTE(cell,CHAR(10),REPT(" ",200)),200))
Արձանագրություններ
Ընտրեք դատարկ բջիջ, մուտքագրեք ստորև բերված բանաձևը և սեղմեք կոճակը Մտնել արդյունք ստանալու բանալին: Ընտրեք այս արդյունքի բջիջը և այնուհետև քաշեք դրա Autofill Handle-ը ներքև՝ բանաձևը այլ բջիջների վրա կիրառելու համար:
=TRIM(RIGHT(SUBSTITUTE(B5,CHAR(10),REPT(" ",200)),200))
Այնուհետև ապրանքը հ. Ցանկի յուրաքանչյուր բջիջի մի մասը արդյունահանվում է, ինչպես ցույց է տրված վերևի սքրինշոթում:
Նշում: Բանաձևում CHAR(10)-ը ներկայացնում է Windows-ի տողերի ընդմիջում:
2.7 Քաղեք տեքստ բառից առաջ կամ հետո
Նախորդ մասերում մենք սովորեցինք, թե ինչպես կարելի է տեքստ հանել նիշից կամ սահմանազատիչից առաջ կամ հետո: Ի՞նչ պետք է անեք ամբողջ բառից առաջ կամ հետո տեքստ հանելու համար: Այս բաժինը կներկայացնի երեք մեթոդ, որոնք կօգնեն ձեզ կատարել այս խնդիրը:
2.7.1 Որոշակի բառից առաջ տեքստ հանել բանաձևով
Հետևյալ բանաձևը օգնում է ձեզ տեքստ հանել Excel-ի բջջի ներսում որոշակի բառից առաջ:
Ընդհանուր բանաձև
=IFERROR(LEFT(cell,FIND(word,cell)-1),cell)
Արձանագրություններ
Ընտրեք դատարկ բջիջ, մուտքագրեք ստորև բերված բանաձևը և սեղմեք կոճակը Մտնել արդյունք ստանալու բանալին: Ընտրեք այս արդյունքի բջիջը և այնուհետև քաշեք դրա Autofill Handle-ը՝ այս բանաձևը այլ բջիջների վրա կիրառելու համար:
Այս օրինակում մենք պատրաստվում ենք հանել բոլոր տեքստերը «Excel» բառից առաջ, այնպես որ մենք ուղղակիորեն մուտքագրում ենք բառը բանաձևում և փակցնում այն կրկնակի չակերտների մեջ: Կամ կարող եք հղում կատարել «Excel» բառը պարունակող բջիջին:
=IFERROR(LEFT(B5,FIND("Excel",B5)-1),B5)
Նշումներ:
2.7.2 Որոշ բառից հետո տեքստ հանել բանաձևով
Որոշակի բառից հետո տեքստ հանելու համար կարող եք կիրառել հետևյալ բանաձևը՝ այն իրականացնելու համար.
Ընդհանուր բանաձև
=TRIM(MID(cell,SEARCH(word,cell)+LEN(word),255))
Արձանագրություններ
Ընտրեք բջիջ, մուտքագրեք ստորև բերված բանաձևը և սեղմեք կոճակը Մտնել արդյունք ստանալու բանալին: Ընտրեք արդյունքի բջիջը և այնուհետև քաշեք դրա AutoFill Handle-ը ներքև՝ այս բանաձևը այլ բջիջների վրա կիրառելու համար:
=TRIM(MID(B5,SEARCH("Excel",B5)+LEN("Excel"),255))
Այնուհետև կարող եք տեսնել բոլոր տեքստերը յուրաքանչյուր բջիջում «Excel» բառից հետո, ինչպես ցույց է տրված ստորև ներկայացված սքրինշոթում:
Նշումներ:
2.7.3 Զարմանահրաշ գործիքով հանել տեքստը որոշակի բառից առաջ կամ հետո
Եթե կարծում եք, որ բանաձևի օգտագործումը կարող է շատ անհարմարություններ առաջացնել, այստեղ խորհուրդ ենք տալիս Քաղվածք տեքստ օգտակարությունը Excel- ի համար նախատեսված գործիքներ. Այս հատկությունը օգնում է ավտոմատացնել Extraction առաջադրանքը Excel-ում ընդամենը մի քանի կտտոցով:
1: սեղմեք Կուտոլս > Տեքստ > Քաղվածք տեքստ այս հնարավորությունը միացնելու համար:
2. Մեջ Քաղվածք տեքստ երկխոսության տուփ, կատարեք հետևյալ կարգավորումները:
Նշումներ: Եթե ցանկանում եք ստեղծել դինամիկ արդյունքներ, ստուգեք Տեղադրեք որպես բանաձև տուփ. Այնուհետև արդյունքներն ինքնաբերաբար կթարմացվեն, երբ տիրույթի տվյալները փոխվեն:
3. Հետո ան Քաղվածք տեքստ Երկխոսության տուփը բացվում է, դուք պետք է ընտրեք բջիջ արդյունքը դուրս բերելու համար, այնուհետև սեղմեք կոճակը OK կոճակը:
Այնուհետև ընտրված տիրույթի յուրաքանչյուր բջիջի որոշակի բառից առաջ կամ հետո տեքստերն անմիջապես հանվում են:
Նշում: Այս հատկանիշը մեծատառերի զգայուն է:
Կտտացրեք ՝ այս գործառույթի մասին ավելին իմանալու համար:
Եթե ցանկանում եք ունենալ այս օգտակար ծառայության անվճար փորձարկում (30-օրյա), խնդրում ենք կտտացնել այն ներբեռնելու համար, և այնուհետև անցեք գործողությունը կիրառելու վերը նշված քայլերին համապատասխան:
3. Քաղվածք նիշերի/բառերի միջև
Եթե ցանկանում եք տեքստ հանել որոշակի նիշերի կամ բառերի միջև, փորձեք հետևյալ մեթոդները.
3.1 Քաղեք տեքստ երկու նիշերի միջև
Երկու նիշերի միջև տեքստ հանելու համար, որոնք կարող են լինել նույն կամ տարբեր նիշերը: Այս բաժնում ներկայացված են մի քանի մեթոդներ, և դուք կարող եք ընտրել դրանցից մեկը՝ ըստ ձեր կարիքների:
3.1.1 Քաղեք տեքստ երկու նույն նիշերի միջև բանաձևով
Ինչպես ցույց է տրված ստորև նկարում, B սյունակում կա տեքստային տողերի ցանկ, և դուք ցանկանում եք տիրույթի յուրաքանչյուր բջիջից հանել «/» նիշերի միջև թվային մասը, հետևյալ բանաձևը կարող է ձեզ լավություն անել:
Ընտրեք դատարկ բջիջ, պատճենեք կամ մուտքագրեք ստորև բերված բանաձևը և սեղմեք կոճակը Մտնել արդյունք ստանալու բանալին: Ընտրեք արդյունքի բջիջը և այնուհետև քաշեք այն Ինքնալրացում Handle ներքև՝ ցանկի այլ բջիջների արդյունքները ստանալու համար:
=SUBSTITUTE(MID(SUBSTITUTE("/" & B5&REPT(" ",6),"/",REPT(",",255)),2*255,255),",","")
Այնուհետև տեքստը երկու նույն նիշերի միջև «/» հանվում է տիրույթի յուրաքանչյուր բջիջից: Տես սքրինշոթը.
Նշում:
3.1.2 Քաղեք տեքստ երկու տարբեր նիշերի միջև բանաձևով
Բջիջում երկու նույն նիշերի միջև տեքստ հանել սովորելուց հետո, այստեղ մենք կցուցադրենք բանաձև՝ երկու տարբեր նիշերի միջև տեքստ հանելու համար: Ինչպես ցույց է տրված ստորև ներկայացված սքրինշոթում, B սյունակի յուրաքանչյուր բջիջից միայն էլփոստի հասցեն հանելու համար «<»-ի և «>»-ի միջև, կարող եք անել հետևյալը.
Ընդհանուր բանաձև
=MID(LEFT(cel,FIND("end_char",cell)-1),FIND("start_char",cell)+1,LEN(cell))
Արձանագրություններ
Ընտրեք դատարկ բջիջ, պատճենեք կամ մուտքագրեք ստորև բերված բանաձևը և սեղմեք կոճակը Մտնել արդյունք ստանալու բանալին: Ընտրեք այս արդյունքի բջիջը և այնուհետև քաշեք դրա Autofill Handle-ը՝ այս բանաձևը այլ բջիջների վրա կիրառելու համար:
=MID(LEFT(B5,FIND(">",B5)-1),FIND("<",B5)+1,LEN(B5))
Դուք կարող եք տեսնել, որ միայն նշված նիշերի միջև եղած տեքստն է արդյունահանվում, ինչպես ցույց է տրված վերևի սքրինշոթում:
3.1.3 Հանեք տեքստ երկու նիշերի միջև զարմանալի գործիքով
Այստեղ բարձր խորհուրդ է տրվում Տողեր հանիր նշված տեքստի միջև առանձնահատկությունը Excel- ի համար նախատեսված գործիքներ օգնել ձեզ հեշտությամբ հանել տեքստը երկու նույն կամ տարբեր նիշերի միջև Excel-ի բջիջում:
1. Ընտրեք դատարկ բջիջ `արդյունքը դուրս բերելու համար, ապա կտտացրեք Կուտոլս > Բանաձևի օգնական > Բանաձևի օգնական.
2. Մեջ Բանաձևեր օգնողը երկխոսության տուփ, կատարեք հետևյալ կարգավորումները:
3. Այնուհետև արդյունահանվում է միայն B5 բջիջի «<» և «>» տեքստը: Միևնույն ժամանակ, ստեղծվել է բանաձև, որի արդյունքում կարող եք ընտրել այս արդյունքի բջիջը և այնուհետև քաշել դրա AutoFill Handle-ը ներքև՝ նույն ցանկի այլ բջիջներից տեքստեր հանելու համար:
Կտտացրեք ՝ այս գործառույթի մասին ավելին իմանալու համար:
Եթե ցանկանում եք ունենալ այս օգտակար ծառայության անվճար փորձարկում (30-օրյա), խնդրում ենք կտտացնել այն ներբեռնելու համար, և այնուհետև անցեք գործողությունը կիրառելու վերը նշված քայլերին համապատասխան:
3.1.4 Քաղեք տեքստ երկու նիշերի միջև (ներառյալ նիշերը) ըստ կանոնի
Եթե ցանկանում եք պահպանել երկու նիշերը հանելուց հետո, փորձեք կիրառել կանոն Excel-ի համար Kutools-ի Extract Text հատկանիշում:
1: սեղմեք Կուտոլս > Տեքստ > Քաղվածք տեքստ.
2. Մեջ Քաղվածք տեքստ երկխոսության տուփ, կատարեք հետևյալ կարգավորումները:
3. Մեկ այլ Քաղվածք տեքստ Երկխոսության տուփը բացվում է, խնդրում ենք ընտրել բջիջ՝ արդյունքը դուրս բերելու համար, այնուհետև սեղմել կոճակը OK կոճակը:
Այնուհետև նշված նիշերի միջև եղած տեքստը (ներառյալ նիշերը) զանգվածաբար հանվում են ընտրված տիրույթի յուրաքանչյուր բջիջից:
Եթե ցանկանում եք ունենալ այս օգտակար ծառայության անվճար փորձարկում (30-օրյա), խնդրում ենք կտտացնել այն ներբեռնելու համար, և այնուհետև անցեք գործողությունը կիրառելու վերը նշված քայլերին համապատասխան:
3.2 Քաղեք տեքստ երկու բառի միջև
Բացի երկու նիշերի միջև տեքստ հանելուց, կարող է անհրաժեշտ լինել նաև տեքստ հանել երկու բառերի միջև: Օրինակ, հանեք բոլոր տեքստային տողերը երկու «KTE» և «հատկանիշ» բառերի միջև B սյունակի յուրաքանչյուր բջիջից, ինչպես ցույց է տրված ստորև ներկայացված սքրինշոթում: Դա անելու համար կարող եք փորձել հետևյալ մեթոդներից մեկը:
3.2.1 Քաղեք տեքստ երկու բառի միջև բանաձևով
Դուք կարող եք օգտագործել բանաձև, որը հիմնված է MID ֆունկցիայի և SEARCH ֆունկցիայի վրա՝ բջջի մեջ գտնվող երկու բառերի միջև բոլոր տեքստային տողերը հանելու համար:
Ընդհանուր բանաձև
=MID(cell,SEARCH("start_word",cell)+3,SEARCH("end_word",cell)-SEARCH("start_word",cell)-4)
Արձանագրություններ
Ընտրեք դատարկ բջիջ, պատճենեք կամ մուտքագրեք ստորև բերված բանաձևը և սեղմեք կոճակը Մտնել արդյունք ստանալու բանալին: Ընտրեք այս արդյունքի բջիջը և այնուհետև քաշեք դրա Autofill Handle-ը՝ այս բանաձևը այլ բջիջների վրա կիրառելու համար:
=MID(B5,SEARCH("KTE",B5)+3,SEARCH("feature",B5)-SEARCH("KTE",B5)-4)
ՆշումԲանաձևում 3 թիվը ներկայացնում է «KTE» բառի նիշերի երկարությունը. 4 թիվը ներկայացնում է «KTE» բառի երկարությունը՝ գումարած 1:
Դուք կարող եք տեսնել բոլոր տեքստային տողերը նշված երկու բառերի միջև, որոնք հանված են B սյունակի յուրաքանչյուր բջիջից:
3.2.2 Զարմանալի գործիքով տեքստ հանեք երկու բառի միջև
Excel-ի շատ օգտվողների համար բանաձևերը կարող են դժվար լինել հիշել և մշակել: Այստեղ, հետ Տողեր հանիր նշված տեքստի միջև առանձնահատկությունը Excel- ի համար նախատեսված գործիքներ, կարող եք հեշտությամբ տեքստ հանել երկու բառի միջև ընդամենը մի քանի կտտոցով:
1. Ընտրեք բջիջ՝ արդյունքը դուրս բերելու համար, այնուհետև սեղմեք Կուտոլս > Բանաձևի օգնական > Բանաձևի օգնական
2. Մեջ Բանաձևի օգնական երկխոսության տուփ, դուք պետք է կազմաձևեք հետևյալը.
3. Այնուհետև բոլոր տեքստային տողերը երկու «KTE» և «feature» բառերի միջև հանվում են B5 բջիջում: Միևնույն ժամանակ, ստեղծվել է բանաձև, որի արդյունքում կարող եք ընտրել այս արդյունքի բջիջը և այնուհետև քաշել դրա AutoFill Handle-ը ներքև՝ նույն ցանկի այլ բջիջներից տեքստեր հանելու համար:
Եթե ցանկանում եք ունենալ այս օգտակար ծառայության անվճար փորձարկում (30-օրյա), խնդրում ենք կտտացնել այն ներբեռնելու համար, և այնուհետև անցեք գործողությունը կիրառելու վերը նշված քայլերին համապատասխան:
Թվերը հանել ըստ դիրքի
Ալֆան-թվային տողերի ցանկի համար կարող է լինել երեք դեպք.
- Թիվը տեքստի սկզբում է;
- Թիվը տեքստի վերջում է;
- Թիվը կարող է լինել տեքստի ցանկացած կետում.
Այս բաժնում մենք կտրամադրենք տարբեր մեթոդներ, որոնք կարող են օգտագործվել վերը նշված յուրաքանչյուր դեպքում թվերը հանելու համար:
1 Հանեք համարը տողի ձախից
Այս մասում կներկայացվի բանաձև, որը կօգնի ձեզ հանել միայն այն թվերը, որոնք հայտնվում են բջջի տեքստից առաջ:
Ընդհանուր բանաձև
=LEFT(cell, MATCH(FALSE, ISNUMBER(MID(cell, ROW(INDIRECT("1:"&LEN(cell)+1)), 1) *1), 0) -1)
Արձանագրություններ
Նշում:
Ընտրեք դատարկ բջիջ, մուտքագրեք ստորև բերված բանաձևը և սեղմեք Ctrl + Հերթափոխություն + Մտնել or Մտնել արդյունք ստանալու բանալին: Ընտրեք այս արդյունքի բջիջը և այնուհետև քաշեք դրա Ինքնալրացման բռնիչը ներքև՝ այլ բջիջների թվեր ստանալու համար:
=LEFT(B5, MATCH(FALSE, ISNUMBER(MID(B5, ROW(INDIRECT("1:"&LEN(B5)+1)), 1) *1), 0) -1)
Նշումներ:
2 Տողի աջից հանիր թիվը
Ինչպես ցույց է տրված ստորև ներկայացված սքրինշոթում, վանդակում տեքստից հետո երևացող միայն թվերը հանելու համար փորձեք հետևյալ բանաձևը.
Ընդհանուր բանաձև
=RIGHT(cell, LEN(cell) - MAX(IF(ISNUMBER(MID(cell, ROW(INDIRECT("1:"&LEN(cell))), 1) *1)=FALSE, ROW(INDIRECT("1:"&LEN(cell))), 0)))
Արձանագրություններ
Նշում:
Ընտրեք դատարկ բջիջ, մուտքագրեք ստորև բերված բանաձևը և սեղմեք Ctrl + Հերթափոխություն + Մտնել or Մտնել արդյունք ստանալու բանալին: Ընտրեք այս արդյունքի բջիջը և այնուհետև քաշեք դրա Ինքնալրացման բռնիչը ներքև՝ այլ բջիջների թվեր ստանալու համար:
=RIGHT(B5, LEN(B5) - MAX(IF(ISNUMBER(MID(B5, ROW(INDIRECT("1:"&LEN(B5))), 1) *1)=FALSE, ROW(INDIRECT("1:"&LEN(B5))), 0)))
Նշումներ:
3. Տեքստային տողի ցանկացած դիրքից հանիր բոլոր թվերը
Վերոհիշյալ մեթոդները օգնում են համարը հանել միայն տեքստային տողի ձախից կամ աջից: Եթե ցանկանում եք դուրս հանել բոլոր թվերը տեքստային տողի ցանկացած կետից, այստեղ մենք ձեզ տրամադրում ենք երեք եղանակ՝ այն իրականացնելու համար:
3.1 Բանաձևով հանեք բոլոր թվերը տողի ցանկացած կետից
Դուք կարող եք կիրառել հետևյալ բանաձևը՝ Excel-ում բոլոր թվերը տեքստային տողի ցանկացած կետից հանելու համար:
1. Ընտրեք դատարկ բջիջ, պատճենեք կամ մուտքագրեք ստորև բերված բանաձևը և սեղմեք կոճակը Մտնել բանալին՝ B5 բջիջից բոլոր թվերը ստանալու համար:
=SUMPRODUCT(MID(0&B5, LARGE(INDEX(ISNUMBER(--MID(B5, ROW(INDIRECT("1:"&LEN(B5))), 1)) * ROW(INDIRECT("1:"&LEN(B5))), 0), ROW(INDIRECT("1:"&LEN(B5))))+1, 1) * 10^ROW(INDIRECT("1:"&LEN(B5)))/10)
2. Ընտրեք արդյունքի բջիջը և այնուհետև քաշեք դրա AutoFill Handle-ը ներքև՝ այլ բջիջների բոլոր թվերը ստանալու համար:
3.2 VBA-ով դուրս հանեք բոլոր թվերը տողի ցանկացած կետից
Վերևի բանաձևը չափազանց երկար և բարդ է Excel-ի շատ օգտվողների համար: Փաստորեն, Excel-ում առաջադրանքը ավտոմատացնելու համար կարող եք գործարկել VBA սկրիպտը: Դուք կարող եք անել հետևյալը.
1. Սեղմեք ալտ + F11 բացել ստեղները Microsoft Visual Basic հավելվածների համար պատուհան.
2. Բացման մեջ Microsoft Visual Basic հավելվածների համար պատուհանը, սեղմեք Տեղադրել > Մոդուլ. Այնուհետև պատճենեք ներքևում գտնվող VBA-ն Module կոդը պատուհանում:
VBA կոդ. հանեք բոլոր թվերը տեքստային տողի ցանկացած կետից
Sub ExtrNumbersFromRange()
'Updated by Extendoffice 20220106
Dim xRg As Range
Dim xDRg As Range
Dim xRRg As Range
Dim nCellLength As Integer
Dim xNumber As Integer
Dim strNumber As String
Dim xTitleId As String
Dim xI As Integer
xTitleId = "KutoolsforExcel"
Set xDRg = Application.InputBox("Please select text strings:", xTitleId, "", Type:=8)
If TypeName(xDRg) = "Nothing" Then Exit Sub
Set xRRg = Application.InputBox("Please select output cell:", xTitleId, "", Type:=8)
If TypeName(xRRg) = "Nothing" Then Exit Sub
xI = 0
strNumber = ""
For Each xRg In xDRg
xI = xI + 1
nCellLength = Len(xRg)
For xNumber = 1 To nCellLength
If IsNumeric(Mid(xRg, xNumber, 1)) Then
strNumber = strNumber & Mid(xRg, xNumber, 1)
End If
Next xNumber
xRRg.Item(xI) = strNumber
strNumber = ""
Next xRg
End Sub
3. Սեղմեք F5 ծածկագիրը գործելու համար: Բացման մեջ KutoolsforExcel երկխոսության վանդակում ընտրեք բջիջների այն շրջանակը, որտեղ ցանկանում եք հանել բոլոր թվերը յուրաքանչյուր բջիջից, այնուհետև կտտացրեք կոճակին OK կոճակը:
4. Հետո մեկ այլ KutoolsforExcel երկխոսության տուփը հայտնվում է: Այս երկխոսության վանդակում ընտրեք նպատակակետ բջիջ և սեղմեք OK.
Այնուհետև բոլոր թվերը զանգվածաբար հանվում են ընտրված տիրույթի յուրաքանչյուր բջիջից:
4. Քաղեք թվեր կոնկրետ տեքստից հետո
Ինչպես ցույց է տրված ստորև ներկայացված սքրինշոթում, «Ոչ» հատուկ տեքստից հետո որևէ թվեր հանելու համար այս բաժինը տրամադրում է երկու մեթոդ, որոնք կօգնեն ձեզ դա անել:
4.1 Քաղեք թվեր կոնկրետ տեքստից հետո բանաձևով
Excel-ի բջջի կոնկրետ տեքստից հետո թվեր հանելու համար կարող եք կիրառել հետևյալ բանաձևը:
Ընդհանուր բանաձև.
=LOOKUP(10^6,1*MID(cell,MIN(FIND({0,1,2,3,4,5,6,7,8,9},cell&"0123456789",FIND("text"," "&cell&" "))),{2,3,4,5,6}))
Արձանագրություններ
Ընտրեք դատարկ բջիջ, պատճենեք կամ մուտքագրեք ստորև բերված բանաձևը և սեղմեք կոճակը Մտնել արդյունք ստանալու բանալին: Ընտրեք այս արդյունքի բջիջը և այնուհետև քաշեք դրա Autofill Handle-ը՝ այս բանաձևը այլ բջիջների վրա կիրառելու համար:
=LOOKUP(10^6,1*MID(B5,MIN(FIND({0,1,2,3,4,5,6,7,8,9},B5&"0123456789",FIND("No."," "&B5&" "))),{2,3,4,5,6}))
Նշումներ:
4.2 Քաղեք թվեր կոնկրետ տեքստից հետո՝ օգտագործողի կողմից սահմանված գործառույթով
Օգտատիրոջ կողմից սահմանված հետևյալ գործառույթը կարող է նաև օգնել բջջի որոշակի տեքստից հետո թվեր հանել: Խնդրում ենք անել հետևյալը.
1. Սեղմեք ալտ + F11 բացել ստեղները Microsoft Visual Basic հավելվածների համար պատուհան.
2. Մեջ Microsoft Visual Basic հավելվածների համար պատուհանը, սեղմեք Տեղադրել > Մոդուլ, և այնուհետև պատճենեք ներքևում գտնվող VBA կոդը Մոդուլի կոդի պատուհանում:
VBA կոդ. հանել թվերը բջջի որոշակի տեքստից հետո
Function GetNumberAfterTheChar(Rng As Range, Char As String)
'Updated by Extendoffice 20220106
Dim xValue As String
Dim xRntString As String
Dim xStart As Integer
Dim xC
xValue = Rng.Text
xStart = InStr(1, xValue, Char, vbTextCompare)
If IsEmpty(xStart) Then
GetNumberAfterTheChar = ""
Exit Function
End If
If xStart < 1 Then
GetNumberAfterTheChar = ""
Exit Function
End If
xStart = xStart - 1 + Len(Char)
If xStart < 1 Then
GetNumberAfterTheChar = ""
Exit Function
End If
xValue = Mid(xValue, xStart + 1)
xRntString = ""
For xI = 1 To Len(xValue)
xC = Mid(xValue, xI, 1)
Select Case Asc(xC)
Case 48 To 57
xRntString = xRntString & xC
Case Else
Exit For
End Select
Next
GetNumberAfterTheChar = xRntString
End Function
3. Սեղմեք ալտ + Q ստեղները փակելու համար Microsoft Visual Basic հավելվածների համար պատուհան.
4. Ընտրեք բջիջ, մուտքագրեք ստորև բերված բանաձևը և սեղմեք կոճակը Մտնել բանալի. Ընտրեք այս արդյունքի բջիջը և այնուհետև քաշեք դրա Autofill Handle-ը՝ այս բանաձևը այլ բջիջների վրա կիրառելու համար:
=GetNumberAfterTheChar(B5,"No. ")
Նշումներ:
Առնչվող հոդվածներ քանակը:
Excel ձեռնարկ՝ բաժանել տեքստի, թվի և ամսաթվի բջիջները (առանձնացնել մի քանի սյունակների)
Այս ձեռնարկը բաժանված է երեք մասի՝ բաժանված տեքստային բջիջներ, բաժանված թվային բջիջներ և բաժանված ամսաթվի բջիջներ: Յուրաքանչյուր մաս տալիս է տարբեր օրինակներ, որոնք կօգնեն ձեզ իմանալ, թե ինչպես վարվել բաժանման աշխատանքը, երբ բախվում եք նույն խնդրին:
Կտտացրեք ավելին իմանալու համար ...
Excel-ը տեքստ և համար ավելացրեք բջջի նշված դիրքում
Excel-ում բջիջներին տեքստեր կամ թվեր ավելացնելը շատ տարածված աշխատանք է: Օրինակ՝ անունների միջև տարածություն ավելացնելը, բջիջներին նախածանց կամ վերջածանց ավելացնելը, սոցիալական թվերին գծիկներ ավելացնելը: Այստեղ, այս ձեռնարկում, այն թվարկում է Excel-ում ավելացնելու գրեթե բոլոր սցենարները և տրամադրում է ձեզ համապատասխան մեթոդներ:
Կտտացրեք ավելին իմանալու համար ...
Excel-ը հեռացնում է նիշերը, բառերը, թվերը տեքստային տողերից
Ենթադրենք, դուք ունեք տեքստային տողերի երկար ցուցակ, որոնք պարունակում են նիշեր, թվեր կամ այլ հատուկ նշաններ: Որոշակի դեպքերում ձեզ կարող է անհրաժեշտ լինել հեռացնել որոշ նիշեր՝ ելնելով դիրքից, օրինակ՝ աջից, ձախից կամ միջինից տեքստային տողերից, կամ ջնջել որոշ անցանկալի նիշեր, թվեր տողերի ցանկից: Մեկ առ մեկ լուծումներ գտնելը ձեզ գլխացավանք կառաջացնի, այս ձեռնարկը հավաքում է Excel-ում նիշերը, բառերը կամ թվերը հեռացնելու բոլոր տեսակի մեթոդները:
Կտտացրեք ավելին իմանալու համար ...
Գրասենյակի արտադրողականության լավագույն գործիքները
Լրացրեք ձեր Excel-ի հմտությունները Kutools-ի հետ Excel-ի համար և փորձեք արդյունավետությունը, ինչպես երբեք: Kutools-ը Excel-ի համար առաջարկում է ավելի քան 300 առաջադեմ առանձնահատկություններ՝ արտադրողականությունը բարձրացնելու և ժամանակ խնայելու համար: Սեղմեք այստեղ՝ Ձեզ ամենաշատ անհրաժեշտ հատկանիշը ստանալու համար...
Office Tab- ը Tabbed ինտերֆեյսը բերում է Office, և ձեր աշխատանքը շատ ավելի դյուրին դարձրեք
- Միացնել ներդիրներով խմբագրումը և ընթերցումը Word, Excel, PowerPoint- ով, Հրատարակիչ, Access, Visio և Project:
- Բացեք և ստեղծեք բազմաթիվ փաստաթղթեր նույն պատուհանի նոր ներդիրներում, այլ ոչ թե նոր պատուհաններում:
- Բարձրացնում է ձեր արտադրողականությունը 50%-ով և նվազեցնում մկնիկի հարյուրավոր սեղմումները ձեզ համար ամեն օր: