Excel-ի ձեռնարկ. բաժանել տեքստը, համարը և ամսաթվի բջիջները (առանձնացնել մի քանի սյունակների)
Excel-ից օգտվելիս որոշ նպատակների համար կարող է անհրաժեշտ լինել մեկ բջիջից տեքստը բաժանել մի քանի բջիջների: Այս ձեռնարկը բաժանված է երեք մասի՝ բաժանված տեքստային բջիջներ, բաժանված թվային բջիջներ և բաժանված ամսաթվի բջիջներ: Յուրաքանչյուր մաս տալիս է տարբեր օրինակներ, որոնք կօգնեն ձեզ իմանալ, թե ինչպես վարվել բաժանման հետ, երբ բախվում եք նույն խնդրին:
Բովանդակություն: [Թաքցնել]
1 Տեքստի բջիջների բաժանում
Այս մասը հավաքում է այն իրավիճակները, որոնց կհանդիպեք տեքստային բջիջը մի քանի սյունակների բաժանելիս և տրամադրում է ձեզ համապատասխան մեթոդներ:
Օրինակ #1 Բջիջները բաժանել ստորակետերով, բացատով կամ այլ սահմանազատիչ(ներով)
Տեքստային բջիջը մի քանի սյունակների բաժանելու համար որոշակի սահմանազատիչով, ինչպիսիք են ստորակետը, բացատը, գծիկը և այլն, կարող եք կիրառել ստորև նշված մեթոդներից մեկը:
Բջիջները բաժանեք ըստ սահմանազատողի՝ «Տեքստ սյունակներ» հատկանիշով
The Տեքստը սյունակներում ֆունկցիան, որպես Excel ներկառուցված, հաճախ օգտագործվում է բջիջների բաժանման համար: Ինչպես ցույց է տրված ստորև ներկայացված սքրինշոթում, Տեքստային տողերի սյունակի բջիջները ստորակետերով բաժանելու համար կարող եք կիրառել «Տեքստ սյունակներ» ֆունկցիան հետևյալ կերպ:
1. Ընտրեք սյունակի տիրույթը, որը ցանկանում եք բաժանել ստորակետերով, սեղմեք Ամսաթիվ > Տեքստը սյունակներում.
2. Մեջ Տեքստը փոխել սյունակների կախարդի - Քայլ 1-ը 3-ից երկխոսության տուփ, պահեք այն Դիմակավորված ընտրված է ռադիո կոճակը, այնուհետև սեղմեք կոճակը հաջորդ կոճակը:
3. Մեջ Տեքստը փոխել սյունակների կախարդի - Քայլ 2-ը 3-ից երկխոսության վանդակում, նշեք սահմանազատիչ՝ ըստ ձեր կարիքների (այս դեպքում ես միայն ստուգում եմ Կոմբին վանդակը), այնուհետև կտտացրեք հաջորդ կոճակը:
4. Վերջին քայլի երկխոսության վանդակում սեղմեք կոճակը՝ առանձնացված տեքստերը դուրս բերելու համար բջիջ ընտրելու համար, այնուհետև սեղմեք կոճակը Ավարտել կոճակը:
Այնուհետև ընտրված տիրույթի տեքստերը բաժանվում են ստորակետով և տեղադրվում տարբեր սյունակներում, ինչպես ցույց է տրված ստորև:
Բջիջները բաժանել ըստ բանաձևի բաժանարարի
Դուք կարող եք կիրառել ստորև բերված բանաձևը՝ բջիջներում տեքստերը բաժանելու համար Excel-ում նշված սահմանազատիչով:
Ընդհանուր բանաձև
=TRIM(MID(SUBSTITUTE(A1,delim,REPT(" ",LEN(A1))),(N-1)*LEN(A1)+1,LEN(A1)))
Արձանագրություններ
Ապա շարունակեք կիրառել այս բանաձևը:
1. Ինչպես ցույց է տրված ստորև ներկայացված սքրինշոթում, նախ, դուք պետք է ստեղծեք օգնական տող 1, 2, 3... թվերով, որոնք տեղակայված են տարբեր բջիջներում:
ՆշումԱյստեղ 1, 2, 3... ներկայացնում են տեքստային տողի առաջին, երկրորդ և երրորդ ենթատողերը:
2. Ընտրեք բջիջը թիվ 1 բջիջի տակ, պատճենեք կամ մուտքագրեք ստորև բերված բանաձևը դրա մեջ և սեղմեք կոճակը Մտնել բանալին՝ տեքստային տողի առաջին ենթատողը ստանալու համար: Ընտրեք արդյունքի բջիջը, քաշեք այն Ավտոմատ լրացման բռնակ աջ և ներքև՝ մյուս ենթատողերը ստանալու համար: Տես սքրինշոթը.
=TRIM(MID(SUBSTITUTE($B5,",",REPT(" ",LEN($B5))),(D$4-1)*LEN($B5)+1,LEN($B5)))
ՆշումԲանաձևում ՝ «,” սահմանազատիչն է, որն օգտագործվում է տեքստային տողը B5-ում բաժանելու համար: Դուք կարող եք դրանք փոխել ըստ ձեր կարիքների:
Զարմանալի գործիքի միջոցով բաժանեք բջիջները սահմանազատիչով
Այստեղ խորհուրդ են տալիս Excel- ի համար նախատեսված գործիքներ'S Պառակտված բջիջներ գործառույթ, որը կօգնի ձեզ հեշտությամբ բաժանել բջիջները առանձին սյունակների կամ տողերի՝ Excel-ում որոշակի սահմանազատիչով:
1. Տեղադրելուց հետո Excel- ի համար նախատեսված գործիքներ, ընտրեք այն տիրույթը, որտեղ ցանկանում եք բաժանել տեքստային տողերը, այնուհետև սեղմեք Կուտոլս > Միաձուլում և պառակտում > Պառակտված բջիջներ.
2. Մեջ Պառակտված բջիջներ երկխոսության տուփ, դուք պետք է կազմաձևեք հետևյալը.
3. Հաջորդում Պառակտված բջիջներ երկխոսության վանդակում, ընտրեք բջիջ՝ ենթատողերը դուրս բերելու համար, այնուհետև կտտացրեք OK.
Այնուհետև ենթատողերը բաժանվում են տարբեր սյունակների կամ տողերի՝ հիմնվելով վերևում նշված 2-րդ քայլում:
Բաժանել սյունների:
Բաժանվել տողերի:
Օրինակ #2 Բաժանել բջիջները որոշակի երկարությամբ
Տեքստի տողը որոշակի երկարությամբ բաժանելու համար հետևյալ մեթոդները կարող են ձեզ լավություն անել:
Բջիջները բաժանել որոշակի երկարությամբ՝ «Text to Columns» հատկանիշով
The Տեքստը սյունակներում հատկությունը ապահովում է ա Հաստատված լայնություն տարբերակ, որը կօգնի ձեզ բաժանել տեքստային տողերը ընտրված բջիջներում Excel-ում որոշակի երկարությամբ:
Ինչպես ցույց է տրված ստորև ներկայացված սքրինշոթում, B5:B9 տիրույթի տեքստերը յուրաքանչյուր 3 նիշի սյունակների բաժանելու համար կարող եք անել հետևյալը, որպեսզի այն կատարվի:
1. Ընտրեք այն բջիջները, որտեղ ցանկանում եք բաժանել տեքստային տողերը:
2: սեղմեք Ամսաթիվ > Տեքստը սյունակներում.
3. Մեջ Փոխակերպել տեքստը սյունակների մոգ – քայլ 1-ից 3-ը երկխոսության տուփ, ընտրեք Հաստատված լայնություն ռադիո կոճակը եւ սեղմեք հաջորդ.
4. Հետո 2- ից 3 քայլ երկխոսության պատուհանը բացվում է: Մեջ Տվյալների նախադիտում բաժինը, սեղմեք առանցքի վրա ցանկալի դիրքի վրա, որպեսզի ստեղծեք ընդմիջման գիծ (տող սլաքով): Բոլոր ընդմիջման տողերը ստեղծելուց հետո սեղմեք հաջորդ առաջ գնալու կոճակը:
Այս դեպքում ես ստեղծում եմ ընդմիջման տողեր տեքստային տողի յուրաքանչյուր 3 նիշի համար:
5. Վերջին քայլի մոգում ընտրեք մի բջիջ՝ առանձնացված տեքստերը դուրս բերելու համար, այնուհետև սեղմեք Ավարտել կոճակը:
Այժմ ընտրված բջիջներում տեքստային տողերը բաժանվում են յուրաքանչյուր 3 նիշով, ինչպես ցույց է տրված ստորև ներկայացված սքրինշոթում:
Բջիջները որոշակի երկարությամբ բաժանեք զարմանալի գործիքի միջոցով
Excel-ում բջիջները որոշակի երկարությամբ բաժանելու համար կարող եք կիրառել Պառակտված բջիջներ առանձնահատկությունը Excel- ի համար նախատեսված գործիքներ հեշտությամբ կատարելու համար:
1. Ընտրեք տեքստային տողային բջիջները, որոնք ցանկանում եք բաժանել որոշակի երկարությամբ, սեղմեք Կուտոլս > Միաձուլում և պառակտում > Պառակտված բջիջներ.
2. Մեջ Պառակտված բջիջներ երկխոսության տուփ, դուք պետք է կազմաձևեք հետևյալը.
3. Հաջորդում Պառակտված բջիջներ երկխոսության վանդակում, ընտրեք բջիջ՝ բաժանվող տեքստերը տեղադրելու համար, այնուհետև կտտացրեք OK.
Այնուհետև ընտրված բջիջներում տեքստային տողերը բաժանվում են որոշակի երկարությամբ և տեղադրվում տարբեր սյունակներում:
Օրինակ #3 Բաժանել բջիջները որոշակի բառով
Ինչպես ցույց է տրված ստորև ներկայացված սքրինշոթում, B5:B9 տիրույթում տեքստային տողերը «վաճառք» բառով բաժանելու համար կարող եք կիրառել այս բաժնում ներկայացված բանաձևերը:
Ստացեք ենթատողը բջջի որոշակի բառից առաջ
LEFT և FIND ֆունկցիաների վրա հիմնված բանաձևի կիրառումը կարող է օգնել տեքստային տողի որոշակի բառից առաջ ստանալ ենթատողը:
Ընդհանուր բանաձև
=LEFT(A1,FIND("certain_word", A1)-1)
Արձանագրություններ
1. Ընտրեք դատարկ բջիջ, պատճենեք կամ մուտքագրեք ստորև բերված բանաձևը դրա մեջ և սեղմեք կոճակը Մտնել ստեղնը՝ որոշակի բառից առաջ ենթատողը ստանալու համար: Ընտրեք այս արդյունքի բջիջը, այնուհետև քաշեք այն Ավտոմատ լրացման բռնակ ներքև ՝ բանաձևը այլ բջիջների վրա կիրառելու համար:
=LEFT(B5,FIND("sales",B5)-1)
Ստացեք ենթատողը բջջի բառից հետո
Ենթատողը բառից առաջ ստանալուց հետո անհրաժեշտ է կիրառել ստորև բերված բանաձևը՝ դրանից հետո ենթատողը ստանալու համար:
Ընդհանուր բանաձև
=TRIM(MID(A1,SEARCH("certain_word",A1)+LEN("certain_word"),255))
Արձանագրություններ
1. Ընտրեք դատարկ բջիջ առաջին արդյունքի բջիջի կողքին (D5):
2. Պատճենեք կամ մուտքագրեք ներքևի բանաձևը դրա մեջ և սեղմեք Մտնել բանալի. Ընտրեք այս արդյունքի բջիջը, քաշեք այն Ավտոմատ լրացման բռնակ ներքև ՝ մնացած արդյունքները ստանալու համար:
=TRIM(MID(B5,SEARCH("sales",B5)+LEN("sales"),255))
Այժմ դուք տեքստային տողերը բաժանել եք տարբեր սյունակների՝ ըստ մի ամբողջ բառի:
Օրինակ #4 Բջիջները բաժանել ըստ տողերի ընդմիջման
Այս բաժինը ցույց է տալիս տարբեր մեթոդներ, որոնք կօգնեն ձեզ բաժանել տեքստային բջիջներն ըստ տողերի ընդմիջման Excel-ում:
Բջիջները բաժանել ըստ տողերի ընդմիջման՝ «Text to Columns» հատկանիշով
«Text to Columns» հատկությունը կարող է կիրառվել Excel-ում բջիջները բաժանելու համար՝ ըստ տողերի ընդմիջման: Դուք կարող եք անել հետևյալը.
1. Ընտրեք բջիջների շրջանակը, որտեղ ցանկանում եք տեքստերը բաժանել ըստ տողերի ընդմիջման:
2: սեղմեք Ամսաթիվ > Տեքստը սյունակներում.
3. Մեջ Տեքստը փոխել սյունակների կախարդի - Քայլ 1-ը 3-ից երկխոսության տուփ, ընտրեք Դիմակավորված ռադիո կոճակը և սեղմեք հաջորդ;
4. Մեջ 2- ից 3 քայլ Երկխոսության վանդակում, ապա նշեք ցանկացած գոյություն ունեցող Սահմանազատողներ ընտրությունները, ստուգեք այլ վանդակը, այնուհետև սեղմեք կոճակը Ctrl + J դյուրանցում. Դուք կարող եք տեսնել, որ միայն մի փոքր կետ է ցուցադրվում տեքստային տուփում, այնուհետև՝ Տվյալների նախադիտում վանդակում, տեքստերը բաժանված են տողերի ընդմիջումներով: Սեղմեք հաջորդ կոճակը:
5. Վերջին քայլի հրաշագործում ընտրեք նպատակակետ բջիջ՝ առանձնացված տեքստերը դուրս բերելու համար, այնուհետև սեղմեք Ավարտել կոճակը:
Այնուհետև ընտրված բջիջների տեքստերը բաժանվում են տարբեր սյունակների՝ ըստ տողերի ընդմիջումների:
Բջիջները բաժանել ըստ տողերի ընդմիջման բանաձևով
Հետևյալ բանաձևերը կարող են նաև օգնել Excel-ում բջիջները բաժանել տողերով:
Օգտագործելով վերևի նույն օրինակը, բաժանվելուց հետո դուք կստանաք երեք ենթատող տարբեր սյունակներում:
Ստացեք ենթատողը մինչև առաջին տողի ընդմիջումը
Նախ, մենք կարող ենք կիրառել բանաձև, որը հիմնված է LEFT եւ ՈՐՈՆՈՒՄ գործառույթները բաժանում են ենթատողը նախքան բջիջի առաջին տողի ընդմիջումը:
Ընդհանուր բանաձև
=LEFT(cell, SEARCH(CHAR(10),cell,1)-1)
Արձանագրություններ
1. Ընտրեք դատարկ բջիջ (այս դեպքում D5), պատճենեք կամ մուտքագրեք ստորև բերված բանաձևը և սեղմեք կոճակը Մտնել բանալի. Ընտրեք արդյունքի բջիջը և քաշեք այն Ավտոմատ լրացման բռնակ ներքեւ՝ ենթատողերը ստանալուց առաջ մյուս բջիջների առաջին տողերի ընդմիջումից առաջ:
=LEFT(B5, SEARCH(CHAR(10),B5,1)-1)
Ստացեք ենթատողը առաջին և երկրորդ տողերի ընդմիջումների միջև
Բջջի առաջին և երկրորդ տողերի ընդմիջումների միջև ենթատողը ստանալու համար հետևյալ բանաձևը կարող է ձեզ լավություն անել:
Ընդհանուր բանաձև
=MID(cell,SEARCH(CHAR(10),cell)+1,SEARCH(CHAR(10),cell,SEARCH(CHAR(10),cell)+1)-SEARCH(CHAR(10),cell)-1)
Արձանագրություններ
1. D5-ի կողքին ընտրեք բջիջ (E5), պատճենեք կամ մուտքագրեք ստորև բերված բանաձևը և սեղմեք կոճակը Մտնել բանալի. Ընտրեք արդյունքի բջիջը և քաշեք այն Ավտոմատ լրացման բռնակ ներքեւ՝ այլ բջիջների առաջին և երկրորդ տողերի ընդմիջումների միջև ընկած ենթատողերը ստանալու համար:
=MID(B5, SEARCH(CHAR(10),B5) + 1, SEARCH(CHAR(10),B5,SEARCH(CHAR(10),B5)+1) - SEARCH(CHAR(10),B5) - 1 )
Ստացեք ենթատողը երկրորդ տողի ընդմիջումից հետո
Առաջին քայլը ստորև բերված բանաձևով երկրորդ տողի ընդմիջումից հետո ենթատող ստանալն է:
Ընդհանուր բանաձև
=RIGHT(cell,LEN(cell) - SEARCH(CHAR(10),cell, SEARCH(CHAR(10), cell) + 1))
Արձանագրություններ
1. Ընտրեք բջիջ (այս դեպքում F5), պատճենեք կամ մուտքագրեք ստորև բերված բանաձևը դրա մեջ և սեղմեք կոճակը Մտնել բանալի. Ընտրեք արդյունքի բջիջը և քաշեք դրա AutoFill Handle-ը ներքև՝ մյուս բջիջների երկրորդ տողի ընդմիջումից հետո ենթատողերը ստանալու համար:
=RIGHT(B5,LEN(B5) - SEARCH(CHAR(10), B5, SEARCH(CHAR(10), B5) + 1))
Բջիջները բաժանել ըստ տողերի ընդմիջման VBA-ով
Այս բաժինը տրամադրում է VBA կոդ, որը կօգնի ձեզ հեշտությամբ բաժանել տեքստերը ընտրված բջիջներում ըստ տողերի ընդմիջման Excel-ում:
1. Սեղմեք ալտ + F11 բացել ստեղները Microsoft Visual Basic հավելվածների համար պատուհան.
2. Մեջ Microsoft Visual Basic հավելվածների համար պատուհանը, սեղմեք Տեղադրել > Մոդուլներ. Այնուհետև պատճենեք ստորև նշված VBA ծածկագիրը պատուհանում:
VBA կոդ՝ բաժանել բջիջները ըստ տողերի ընդմիջման Excel-ում
Sub ExtendOffice_SplitRangeTex()
'Updated by Extendoffice 20211116
Dim xStr() As String
Dim xRg As Range
Dim xCell As Range
Dim xI As Integer
Set xRg = Application.InputBox("Please select the range of cells where you want to split by line break:", "Kutools for Excel", "", , , , , 8)
If xRg Is Nothing Then Exit Sub
For xI = 1 To xRg.Count
Set xCell = xRg.Item(xI)
xStr = VBA.Split(xCell.Value, vbLf)
xCell.Resize(1, UBound(xStr) + 1).Offset(0, 1) = xStr
Next
End Sub
3. Սեղմեք F5 ծածկագիրը գործելու համար: Հետո ա Excel- ի համար նախատեսված գործիքներ Երկխոսության տուփը բացվում է, դուք պետք է ընտրեք բջիջների այն շրջանակը, որտեղ ցանկանում եք բաժանել ըստ տողերի ընդմիջման, և վերջապես սեղմեք OK կոճակը:
Այնուհետև ընտրված բջիջների տեքստերը միանգամից բաժանվում են տարբեր սյունակների՝ ըստ տողերի ընդմիջումների:
Բջիջները բաժանեք տողերով ընդմիջումով զարմանալի գործիքով
Այստեղ ներկայացրեք հարմար գործիք - Պառակտված բջիջներ օգտակարությունը Excel- ի համար նախատեսված գործիքներ. Այս գործիքի միջոցով դուք կարող եք տեքստերը բաժանել ընտրված բջիջներում մեծ մասամբ՝ ըստ տողերի ընդմիջման՝ ընդամենը մի քանի կտտոցով:
1. Ընտրեք բջիջների շրջանակը, որտեղ ցանկանում եք տեքստերը բաժանել ըստ տողերի ընդմիջման:
2: սեղմեք Կուտոլս > Միաձուլում և պառակտում > Պառակտված բջիջներ գործառույթն ապահովելու համար:
3. Մեջ Պառակտված բջիջներ երկխոսության տուփ, դուք պետք է կատարեք հետևյալ կարգավորումները:
4. Հաջորդ պատուհանում Պառակտված բջիջներ երկխոսության տուփ, ընտրեք դատարկ բջիջ՝ առանձնացված տեքստերը տեղադրելու համար և սեղմեք OK.
Այնուհետև ընտրված բջիջների տեքստերը բաժանվում են տարբեր սյունակների՝ ըստ տողերի ընդմիջումների, ինչպես ցույց է տրված ստորև ներկայացված սքրինշոթում:
Եթե ցանկանում եք ունենալ այս օգտակար ծառայության անվճար փորձարկում (30-օրյա), խնդրում ենք կտտացնել այն ներբեռնելու համար, և այնուհետև անցեք գործողությունը կիրառելու վերը նշված քայլերին համապատասխան:
Օրինակ #5 Բջիջները բաժանել միայն առաջին կամ վերջին բաժանարարով
Երբեմն ձեզ կարող է անհրաժեշտ լինել բջիջները բաժանել երկու մասի, նկատի ունենալով միայն առաջին կամ վերջին սահմանազատիչը, կարող եք փորձել ստորև բերված բանաձևերը:
Բջիջները բաժանել բանաձևերով առաջին սահմանաչափով
Ինչպես ցույց է տրված ստորև ներկայացված սքրինշոթում, B5:B9 միջակայքի յուրաքանչյուր բջիջը երկու մասի բաժանելու համար առաջին բացատով, դուք պետք է կիրառեք երկու բանաձև:
Ենթատողը բաժանեք առաջին բացատից առաջ
Ենթատողը առաջին բացատից առաջ բաժանելու համար կարող եք օգտագործել LEFT ֆունկցիայի և FIND ֆունկցիաների վրա հիմնված բանաձև:
Ընդհանուր բանաձև
=LEFT(cell,FIND("delimiter",cell)-1)
Արձանագրություններ
1. Ընտրեք բջիջ (այս դեպքում՝ D5) ենթատողը դուրս բերելու համար, պատճենեք կամ մուտքագրեք ստորև բերված բանաձևը դրա մեջ և սեղմեք կոճակը Մտնել բանալի. Ընտրեք արդյունքի բջիջը և ապա քաշեք այն Ավտոմատ լրացման բռնակ ներքեւ՝ այլ բջիջների ենթաշարանը ստանալու համար:
=LEFT(B5,FIND(" ",B5)-1)
Պառակտեք ենթատողը առաջին բացատից հետո
Այնուհետև կիրառեք ստորև բերված բանաձևը՝ բջիջի առաջին բացատից հետո ենթատողը ստանալու համար:
Ընդհանուր բանաձև
=RIGHT(cell,LEN(cell)-FIND("delimiter",cell))
Արձանագրություններ
1. Պատճենեք կամ մուտքագրեք ստորև բերված բանաձևը E5 բջիջի մեջ և սեղմեք կոճակը Մտնել արդյունք ստանալու բանալին: Ընտրեք այս արդյունքի բջիջը և քաշեք այն Ավտոմատ լրացման բռնակ ներքեւ՝ այլ բջիջների վերջին տարածությունից հետո ենթատողը ստանալու համար:
=RIGHT(B5,LEN(B5)-FIND(" ",B5))
ՆշումԲանաձևերում դուք կարող եք փոխել բջջային հղումը տեքստային տողի և սահմանազատողի՝ ըստ ձեր կարիքների:
Բջիջները բաժանել վերջին սահմանաչափով բանաձևերով
Բջիջների տիրույթում (B5:B9) տեքստերը երկու մասի բաժանելու համար վերջին բացատով, ինչպես ցույց է տրված սքրինշոթում, այս բաժնում ներկայացված երկու բանաձևերը կարող են օգնել ձեզ կատարել այն:
Ստացեք տեքստը վերջին սահմանաչափի ձախ կողմում
Տեքստը բջջի վերջին սահմանազատիչից ձախ կողմում ստանալու համար կարող եք կիրառել ստորև բերված բանաձևը.
Ընդհանուր բանաձև
=LEFT(B5,SEARCH("^",SUBSTITUTE(cell,"delimiter","^",LEN(cell)-LEN(SUBSTITUTE(cell,"delimiter",""))))-1)
Արձանագրություններ
1. Ընտրեք բջիջ՝ ձախ ենթատողը տեղադրելու համար, պատճենեք կամ մուտքագրեք ստորև բերված բանաձևը դրա մեջ և սեղմեք կոճակը Մտնել բանալի. Ընտրեք արդյունքի բջիջը և քաշեք այն Ավտոմատ լրացման բռնակ ներքև ՝ բանաձևը այլ բջիջների վրա կիրառելու համար:
=LEFT(B5,SEARCH("^",SUBSTITUTE(B5," ","^",LEN(B5)-LEN(SUBSTITUTE(B5," ",""))))-1)
Ստացեք տեքստը վերջին սահմանաչափի աջ կողմում
Այժմ մենք պետք է տեքստը հասցնենք այս դեպքում վերջին տարածության աջ կողմում:
Ընդհանուր բանաձև
=TRIM(RIGHT(SUBSTITUTE(cell,"delimiter",REPT("delimiter",LEN(cell))),LEN(cell)))
Արձանագրություններ
1. Ընտրեք բջիջ՝ ճիշտ ենթատողը տեղադրելու համար, պատճենեք կամ մուտքագրեք ստորև բերված բանաձևը դրա մեջ և սեղմեք կոճակը Մտնել բանալի. Ընտրեք արդյունքի բջիջը և քաշեք դրա Autofill Handle-ը՝ բանաձևը այլ բջիջների վրա կիրառելու համար:
=TRIM(RIGHT(SUBSTITUTE(B5," ",REPT(" ",LEN(B5))),LEN(B5)))
ՆշումԲանաձևերում դուք կարող եք փոխել բջջային հղումը տեքստային տողի և սահմանազատողի՝ ըստ ձեր կարիքների:
Օրինակ #6 Բջիջները բաժանել մեծատառով
Այս բաժինը ներկայացնում է օգտագործողի կողմից սահմանված գործառույթ՝ բառերը բջիջներում մեծատառով բաժանելու համար:
1. Սեղմեք ալտ + F11 բացել ստեղները Microsoft Visual Basic հավելվածների համար պատուհան.
2. Մեջ Microsoft Visual Basic հավելվածների համար պատուհանը, սեղմեք Տեղադրել > Մոդուլներ, ապա պատճենեք ստորև նշված VBA կոդը օրենսգրքի պատուհանում:
VBA կոդ. Excel-ում բջիջները բաժանել մեծատառով
Function GetName(s As String, Num As Long) As String
'Updated by Extendoffice 20211116
With CreateObject("VBSCript.RegExp")
.Global = True
.Pattern = "[A-Z][a-z]+|[A-Z]"
GetName = .Execute(s).Item(Num - 1)
End With
End Function
3. Սեղմեք ալտ + Q ստեղները փակելու համար Microsoft Visual Basic հավելվածների համար պատուհան.
4. Ընտրեք բջիջ (այս դեպքում՝ D5) բառը դուրս բերելու համար առաջին մեծատառից ձախ, մուտքագրեք ստորև բերված բանաձևը և սեղմեք կոճակը: Մտնել բանալի. Ընտրեք այս արդյունքի բջիջը և քաշեք այն Ավտոմատ լրացման բռնակ անմիջապես ներքև՝ մյուս բառերը ստանալու համար:
=IFERROR(GetName($B5,COLUMNS($D:D)),"")
ՆշումԿոդում $B5-ը այն բջիջն է, որը դուք կբաժանեք, $D:D-ը արդյունքի բջիջի սյունակն է: Խնդրում ենք փոխել դրանք ըստ ձեր սեփական տվյալների:
Օրինակ #7 Բաժանել անունները բջիջներում
Ենթադրենք, որ դուք ունեք լրիվ անունների սյունակ պարունակող աշխատանքային թերթ, և ցանկանում եք լրիվ անունը բաժանել առանձին սյունակների, օրինակ՝ անունն ու ազգանունը լրիվ անունից բաժանել կամ անունը, միջին կամ ազգանունը լրիվ անունից բաժանել: Այս բաժնում ներկայացված են մանրամասն քայլեր, որոնք կօգնեն ձեզ լուծել այս խնդիրները:
Բաժանեք լրիվ անունը անուն և ազգանուն
Ինչպես ցույց է տրված ստորև ներկայացված սքրինշոթում, անունը, հայրանունը և ազգանունը բաժանված են մեկ բացատով, լրիվ անունից միայն անունն ու ազգանունը բաժանելու և դրանք տարբեր սյունակներում դնելու համար, կարող եք կիրառել դրանցից մեկը: հետևյալ մեթոդները.
1) Բաժանեք լրիվ անունը անուն և ազգանուն բանաձևերով
Դուք պետք է առանձին կիրառեք երկու բանաձև՝ լրիվ անունը անուն և ազգանուն բաժանելու համար:
Անվանումը բաժանեք լրիվ անունից
Դուք կարող եք կիրառել բանաձև՝ հիմնված LEFT և SEARCH ֆունկցիաների վրա՝ անունը լրիվ անունից բաժանելու համար:
Ընդհանուր բանաձև
=LEFT(cell, SEARCH(" ", cell) - 1)
1. Ընտրեք բջիջ՝ առաջին անունը դուրս բերելու համար:
2. Պատճենեք կամ մուտքագրեք ներքևի բանաձևը դրա մեջ և սեղմեք Մտնել բանալի. Ընտրեք այս արդյունքի բջիջը և քաշեք այն Ավտոմատ լրացման բռնակ ներքև՝ անունները այլ լրիվ անուններից բաժանելու համար:
=LEFT(B5, SEARCH(" ", B5) - 1)
Այժմ դուք բաժանել եք բոլոր անունները լրիվ անուններից բջիջների նշված տիրույթում, շարունակեք կիրառել ստորև բերված բանաձևը՝ ազգանունները բաժանելու համար:
Ազգանունը բաժանել լրիվ անունից
Ընդհանուր բանաձև
=RIGHT(cell, LEN(cell) - SEARCH("^", SUBSTITUTE(cell," ", "^", LEN(cell) - LEN(SUBSTITUTE(cell, " ", "")))))
1. Ընտրեք բջիջ, որը գտնվում է անունի բջիջի կողքին:
2. Պատճենեք կամ մուտքագրեք ներքևի բանաձևը դրա մեջ և սեղմեք Մտնել բանալի. Ընտրեք այս արդյունքի բջիջը և քաշեք դրա Ինքնալրացման կարգավորիչը ներքև՝ այլ լրիվ անուններից ազգանունները ստանալու համար:
=RIGHT(B5, LEN(B5) - SEARCH("^", SUBSTITUTE(B5," ", "^", LEN(B5) - LEN(SUBSTITUTE(B5, " ", "")))))
ՆշումԲանաձևերում B5-ը լրիվ անվանական բջիջն է, որը ցանկանում եք բաժանել: Դուք կարող եք փոխել այն, ինչպես ձեզ հարկավոր է:
2) Զարմանալի գործիքով բաժանեք լրիվ անունը անուն և ազգանուն
Բանաձևը դժվար է հիշել Excel-ի շատ օգտվողների համար: Այստեղ խորհուրդ են տալիս Պառակտված անուններ առանձնահատկությունը Excel- ի համար նախատեսված գործիքներ. Այս հատկանիշով դուք կարող եք հեշտությամբ բաժանել լրիվ անունը անուն և ազգանուն՝ ընդամենը մի քանի կտտոցով:
1. Ընտրեք լրիվ անվանական բջիջների շրջանակը, սեղմեք Կուտոլս > Միաձուլում և պառակտում > Պառակտված անուններ.
2. Մեջ Պառակտված անուններ երկխոսության տուփ, միայն ստուգեք Անուն եւ Ազգանուն տուփի մեջ Պառակտված տեսակներ բաժինը, ապա կտտացրեք OK.
TipsԸնտրված միջակայքը ցուցադրվում է Տարածքը բաժանելու համար տուփ, կարող եք փոխել ըստ անհրաժեշտության։
3. Հետո մեկ այլ Պառակտված անուններ Երկխոսության տուփը հայտնվում է, ընտրեք նպատակակետ բջիջը և սեղմեք OK.
Այնուհետև ընտրված բջիջներում ամբողջական անունը կբաժանվի անուն-ազգանունի, ինչպես ցույց է տրված ստորև ներկայացված սքրինշոթում:
Եթե ցանկանում եք ունենալ այս օգտակար ծառայության անվճար փորձարկում (30-օրյա), խնդրում ենք կտտացնել այն ներբեռնելու համար, և այնուհետև անցեք գործողությունը կիրառելու վերը նշված քայլերին համապատասխան:
Բաժանեք լրիվ անունը անուն, միջին և ազգանուն
Ինչպես ցույց է տրված ստորև ներկայացված սքրինշոթում, կա լրիվ անվան սյունակ՝ անուն, հայրանուն և ազգանունով, որոնք բաժանված են մեկ բացատով: Ամբողջական անունը անուն, հայրանուն և ազգանուն բաժանելու և դրանք տարբեր սյունակներում դնելու համար ստորև ներկայացված մեթոդները կարող են օգնել ձեզ:
1) Բաժանեք լրիվ անունը անուն, միջին և ազգանուն՝ «Text to Columns»-ի միջոցով
Ներկառուցված գործառույթը՝ «Text to Columns»-ը կարող է օգնել ձեզ հեշտությամբ բաժանել լրիվ անունը անուն, հայրանուն և ազգանուն Excel-ում:
Դուք կարող եք Հետևեք վերը նշված քայլերին, որպեսզի կիրառեք «Տեքստ սյունակներ» գործառույթը.
Նշում2-ի Քայլ 3-ի հրաշագործում ստուգեք միայն Տարածություն տուփ:
2) Բանաձևերով բաժանեք լրիվ անունը անունի, միջին և ազգանունի
Կարող եք նաև կիրառել բանաձևեր՝ Excel-ում ամբողջական անունը անուն, հայրանուն և ազգանուն բաժանելու համար:
Ընդհանուր բանաձևեր, որոնք օգտագործվում են լրիվ անվանումը բաժանելու համար
Անվանումը բաժանեք
=LEFT(cell,SEARCH(" ", cell)-1)
Բաժանեք միջին անունը
=MID(cell, SEARCH(" ", cell) + 1, SEARCH(" ", cell, SEARCH(" ", cell)+1) - SEARCH(" ", cell)-1)
Բաժանեք ազգանունը
=RIGHT(cell,LEN(cell) - SEARCH(" ",cell, SEARCH(" ",cell,1)+1))
Այնուհետև կիրառեք բանաձևերը տարբեր բջիջներում՝ անուն, հայրանուն և ազգանուն ստանալու համար:
1. D5 բջիջում մուտքագրեք ստորև բերված բանաձևը և սեղմեք կոճակը Մտնել բանալի. Ընտրեք այս արդյունքի բջիջը և քաշեք դրա Ինքնալրացման բռնիչը ներքև՝ այլ լրիվ անունների անունը ստանալու համար:
=LEFT(B5,SEARCH(" ", B5)-1)
2. Մուտքագրեք ստորև բերված բանաձևը E5 բջիջում և սեղմեք կոճակը Մտնել բանալին՝ առաջին երկրորդ անունը ստանալու համար: Ընտրեք արդյունքի բջիջը և քաշեք դրա Autofill Handle-ը ներքև՝ մյուս միջին անունները ստանալու համար:
=MID(B5, SEARCH(" ", B5) + 1, SEARCH(" ", B5, SEARCH(" ", B5)+1) - SEARCH(" ", B5)-1)
3. Ազգանունները ստանալու համար F5 բջիջ մուտքագրեք ստորև բերված բանաձևը և սեղմեք Մտնել, այնուհետև ընտրեք արդյունքի բջիջը և քաշեք դրա Ավտոլրացման բռնիչը ձեզ անհրաժեշտ բջիջների վրայով:
=RIGHT(B5,LEN(B5) - SEARCH(" ",B5, SEARCH(" ",B5,1)+1))
3) Զարմանալի գործիքով բաժանեք լրիվ անունը առաջին, միջին և ազգանունի
Ահա ներածություն Excel- ի համար նախատեսված գործիքներ'S Պառակտված անուններ հնարավորություն, որը թույլ է տալիս միանգամից մի քանի կտտոցով բաժանել լրիվ անունը անուն, հայրանուն և ազգանուն:
1. Ընտրեք լրիվ անվանման բջիջները, որտեղ ցանկանում եք բաժանել, ապա սեղմեք Կուտոլս > Միաձուլում և պառակտում > Պառակտված անուններ.
2. Մեջ Պառակտված անուններ երկխոսության տուփ, դուք պետք է կազմաձևեք հետևյալը.
3. Հաջորդ պատուհանում Պառակտված անուններ երկխոսության վանդակում, ընտրեք նպատակակետ բջիջ՝ առանձնացված տեքստերը դուրս բերելու համար, այնուհետև կտտացրեք OK. Տես ստորև ներկայացված ցուցադրությունը:
Եթե ցանկանում եք ունենալ այս օգտակար ծառայության անվճար փորձարկում (30-օրյա), խնդրում ենք կտտացնել այն ներբեռնելու համար, և այնուհետև անցեք գործողությունը կիրառելու վերը նշված քայլերին համապատասխան:
Օրինակ #8 Տեքստը և թվերը բաժանել բջիջներում
Ենթադրենք, որ կա տեքստային տողերի ցանկ՝ խառը տեքստերով և թվերով, ինչպես ցույց է տրված ստորև ներկայացված սքրինշոթում, տեքստն ու թվերը առանձնացնելու և դրանք տարբեր սյունակներում տեղադրելու համար, մենք ձեզ համար տրամադրում ենք չորս եղանակ:
Տեքստը և թվերը բաժանել բանաձևերով
Հետևյալ բանաձևերով կարող եք տեքստը և թվերը մեկ բջիջից բաժանել երկու առանձնացված բջիջների:
Ընդհանուր բանաձևեր
Ստացեք տեքստ բջիջից
=LEFT(cell,MIN(FIND({0,1,2,3,4,5,6,7,8,9},cell&"0123456789"))-1)
Ստացեք թվեր բջիջից
=RIGHT(cell,LEN(B5)-MIN(FIND({0,1,2,3,4,5,6,7,8,9},cell&"0123456789"))+1)
Այնուհետև կիրառեք այս երկու բանաձևերը տարբեր բջիջներում՝ առանձին տեքստ և թվեր ստանալու համար:
1. Ընտրեք դատարկ բջիջ՝ առաջին տեքստային տողի տեքստը ցուցակում տեղադրելու համար, պատճենեք կամ մուտքագրեք ստորև բերված բանաձևը և սեղմեք կոճակը: Մտնել բանալի. Ընտրեք արդյունքի բջիջը և քաշեք դրա Ինքնալրացման բռնիչը ներքև՝ ցանկի այլ տեքստային տողերի տեքստը ստանալու համար:
=LEFT(B5,MIN(FIND({0,1,2,3,4,5,6,7,8,9},B5&"0123456789"))-1)
2. Ընտրեք բջիջ (E5) առաջին արդյունքի բջիջի կողքին (D5), պատճենեք կամ մուտքագրեք ստորև բերված բանաձևը և սեղմեք Մտնել. Ընտրեք արդյունքի բջիջը և քաշեք դրա Ինքնալրացման բռնիչը ներքև՝ ցուցակի այլ տեքստային տողերի համարները ստանալու համար:
=RIGHT(B5,LEN(B5)-MIN(FIND({0,1,2,3,4,5,6,7,8,9},B5&"0123456789"))+1)
Տեքստը և թվերը բաժանել Flash Fill-ով (2013 և ավելի ուշ տարբերակներ)
Եթե դուք օգտագործում եք Excel 2013 կամ ավելի ուշ տարբերակները, կարող եք կիրառել Flash լրացնել ներկառուցված տեքստը և թվերը մեկ բջիջից երկու սյունակ բաժանելու համար:
Նշում«Flash Fill» գործառույթն աշխատեցնելու համար դուք պետք է գտնեք արդյունքների սյունակները բնօրինակ տեքստային տողերի սյունակի կողքին: Օրինակ, եթե բնօրինակ տեքստային տողերը գտնվում են B սյունակում, ապա առանձնացված տեքստը և թվերը պետք է տեղադրվեն C և D սյունակներում: Տեսեք սքրինշոթը.
1. Ձեռքով մուտքագրեք C5 բջիջի առաջին տեքստային տողերի (D5) տեքստը:
2. Շարունակեք մուտքագրել C6 բջիջի երկրորդ տեքստային տողի (D6) տեքստը:
3. Ակտիվացրեք C7 բջիջը, սեղմեք Ամսաթիվ > Flash լրացնել.
Այնուհետև այլ տեքստային տողերի տեքստերը ավտոմատ կերպով լրացվում են բջիջներում, ինչպես ցույց է տրված ստորև ներկայացված սքրինշոթում:
4. Կրկնեք 1-ից 3-րդ քայլը՝ D սյունակի թվերը ստանալու համար:
Notes:
Տեքստը և թվերը բաժանել օգտագործողի կողմից սահմանված գործառույթով
Եթե ցուցակի տեքստային տողերը կանոնավոր չեն, վերը նշված երկու մեթոդները կարող են սխալ արդյունքներ տալ, ինչպես ցույց է տրված ստորև ներկայացված սքրինշոթում:
Այստեղ ներկայացրեք օգտատիրոջ կողմից սահմանված գործառույթը, որը կօգնի ձեզ բջջից տեքստը և թվերը բաժանել երկու սյունակների, անկախ նրանից, թե որտեղ են գտնվում թվերը տեքստային տողի մեջ: Տես սքրինշոթը.
1. Սեղմեք ալտ + F11 ստեղները:
2. Բացման մեջ Microsoft Visual Basic հավելվածների համար պատուհանը, սեղմեք Տեղադրել > Մոդուլներ, և այնուհետև պատճենեք ստորև ներկայացված VBA- ն օրենսգրքի պատուհանում:
VBA կոդ. Բջջից տեքստը և թվերը բաժանեք երկու սյունակի
Public Function SplitText(pWorkRng As Range, pIsNumber As Boolean) As String
'Update by Extendoffice 20211105
Dim xLen As Long
Dim xStr As String
xLen = VBA.Len(pWorkRng.Value)
For i = 1 To xLen
xStr = VBA.Mid(pWorkRng.Value, i, 1)
If ((VBA.IsNumeric(xStr) And pIsNumber) Or (Not (VBA.IsNumeric(xStr)) And Not (pIsNumber))) Then
SplitText = SplitText + xStr
End If
Next
End Function
3. Սեղմեք ալտ + Q ստեղները փակելու համար Microsoft Visual Basic հավելվածների համար պատուհան.
4. Ընտրեք բջիջ՝ առաջին տեքստային տողի տեքստը արտածելու համար, մուտքագրեք ստորև բերված բանաձևը և սեղմեք կոճակը Մտնել բանալի. Ընտրեք այս արդյունքի բջիջը և քաշեք դրա Ինքնալրացման բռնիչը ներքև՝ նույն ցանկում տեքստային այլ տողերի տեքստը ստանալու համար:
=SplitText(B5,FALSE)
5. Ընտրեք առաջին տեքստային արդյունքի բջիջի կողքին գտնվող բջիջը՝ թվերը դուրս բերելու համար, մուտքագրեք ստորև բերված բանաձևը և սեղմեք կոճակը Մտնել բանալի. Ընտրեք այս արդյունքի բջիջը և քաշեք դրա Ինքնալրացման բռնիչը ներքև՝ այլ տեքստային տողերի համարները ստանալու համար:
=SplitText(B5,TRUE)
Բաժանեք տեքստը և թվերը զարմանալի գործիքի միջոցով
Այստեղ խորհուրդ ենք տալիս տեքստը և թվերը միանգամից բջջից երկու սյունակի բաժանելու ամենադյուրին ճանապարհը: ԿիրառելովՊառակտված բջիջներ առանձնահատկությունը Excel- ի համար նախատեսված գործիքներ օգնում է ձեզ լուծել այս խնդիրը միայն մի քանի կտտոցով:
1. Ընտրեք տեքստային տողերի բջիջները, որտեղ ցանկանում եք տեքստը և թվերը բաժանել երկու սյունակի:
2: սեղմեք Կուտոլս > Միաձուլում և պառակտում > Պառակտված բջիջներ.
3. Մեջ Պառակտված բջիջներ երկխոսության տուփ, դուք պետք է կատարեք հետևյալ կարգավորումները:
4. Հաջորդում Պառակտված բջիջներ երկխոսության վանդակում ընտրեք մի բջիջ՝ առանձնացված տեքստը և թվերը դուրս բերելու համար, այնուհետև սեղմեք կոճակը OK կոճակը:
Այնուհետև կարող եք տեսնել, որ ընտրված բջիջներում տեքստը և թվերը բաժանված են միանգամից երկու սյունակի, ինչպես ցույց է տրված ստորև ներկայացված սքրինշոթում:
Եթե ցանկանում եք ունենալ այս օգտակար ծառայության անվճար փորձարկում (30-օրյա), խնդրում ենք կտտացնել այն ներբեռնելու համար, և այնուհետև անցեք գործողությունը կիրառելու վերը նշված քայլերին համապատասխան:
2. Բաժանել թվային բջիջները
Այս մասում նկարագրվում է, թե ինչպես կարելի է բաժանել թվային բջիջները երկու իրավիճակներում՝ մեկից ավելի թվանշան ունեցող թիվը բաժանել առանձին թվերի և համարները բաժանել տասնորդականով՝ ամբողջ թվերն ու տասնորդական մասերը բաժանելու համար:
Օրինակ #1. Բջիջները բաժանել թվանշաններով
Եթե ցանկանում եք մեկից ավելի թվանշաններով թիվը բաժանել առանձին թվերի տարբեր սյունակներում, փորձեք ստորև նշված մեթոդներից մեկը:
Բանաձևով բջջի մի թիվը բաժանեք առանձին թվերի
Ստորև բերված բանաձևը կարող է օգնել թվերը բաժանել առանձին թվերի և դրանք դնել տարբեր սյունակներում:
Ընդհանուր բանաձև
=MID($A1, COLUMNS($A$1:A$1), 1)
Արգումենտ
1. Ընտրեք դատարկ բջիջ՝ առաջին նիշը դուրս բերելու համար, մուտքագրեք ստորև բերված բանաձևը և սեղմեք կոճակը Մտնել բանալի.
=MID($B3, COLUMNS($B$3:B$3), 1)
2. Ընտրեք արդյունքի այս բջիջը և քաշեք դրա AutoFill Handle-ը դեպի աջ դեպի բջիջները՝ այլ թվանշաններ ստանալու համար: Պահպանեք բոլոր արդյունքի բջիջները ընտրված, այնուհետև քաշեք Ինքնալրացման բռնիչը ներքև՝ այլ թվերի անհատական թվանշանները ստանալու համար:
ՆշումԱյս բանաձևում B3-ը այն բջիջն է, որը պարունակում է այն թիվը, որը պետք է բաժանվի առանձին թվերի, և դուք կարող եք փոխել այն ըստ անհրաժեշտության:
VBA-ի միջոցով բջիջում թիվը բաժանեք առանձին թվերի
Ստորև բերված VBA կոդը կարող է նաև օգնել Excel-ում բջջի թվերը բաժանել առանձին թվերի: Դուք կարող եք անել հետևյալը.
1. Սեղմեք ալտ + F11 բացել ստեղները Microsoft Visual Basic հավելվածների համար պատուհան.
2. Մեջ Microsoft Visual Basic հավելվածների համար պատուհանը, սեղմեք Տեղադրել > Մոդուլներ, այնուհետև պատճենեք ներքևում գտնվող VBA-ն կոդի պատուհանում:
VBA կոդ. Excel-ում համարը բաժանեք առանձին թվերի
Sub SplitNumberIntoDigits()
'Updateby Extendoffice 2021118
Dim Rng As Range
Dim InputRng As Range, OutRng As Range
xTitleId = "Kutools for Excel"
Set InputRng = Application.Selection
Set InputRng = Application.InputBox("Range :", xTitleId, InputRng.Address, Type:=8)
Set OutRng = Application.InputBox("Out put to (single cell):", xTitleId, Type:=8)
xInt = InputRng.Row
Application.ScreenUpdating = False
For Each Rng In InputRng
xValue = Rng.Value
xRow = (Rng.Row - xInt) + 1
For I = 1 To VBA.Len(xValue)
OutRng.Cells(xRow, I).Value = VBA.Mid(xValue, I, 1)
Next
Next
Application.ScreenUpdating = True
End Sub
3. Սեղմեք F5 կոդը գործարկելու բանալին, ապա ա Excel- ի համար նախատեսված գործիքներ Երկխոսության տուփը բացվում է, դուք պետք է ընտրեք թվային բջիջների շրջանակը, որը դուք կբաժանեք, այնուհետև սեղմեք կոճակը OK կոճակը:
4. Երկրորդը Excel- ի համար նախատեսված գործիքներ Երկխոսության տուփը բացվում է, դուք պետք է ընտրեք բջիջ՝ առանձին թվանշանները դուրս բերելու համար, այնուհետև սեղմեք OK.
ՆշումԱյս կոդը կարող է բառը բաժանել նաև առանձին տառերի:
Այնուհետև ընտրված բջիջներում թվերը բաժանվում են առանձին թվերի և տեղադրվում տարբեր սյունակներում:
Հեշտությամբ բաժանեք թիվը առանձին թվերի՝ զարմանալի գործիքի միջոցով
Excel- ի համար նախատեսված գործիքներ'S Պառակտված բջիջներ ֆունկցիան հարմար գործիք է, որը կօգնի ձեզ հեշտությամբ բաժանել համարները առանձին թվերի Excel-ում:
1. Տեղադրելուց հետո Excel- ի համար նախատեսված գործիքներ, ընտրեք թվային բջիջների շրջանակը, որը կբաժանեք, սեղմեք Կուտոլս > Միաձուլում և պառակտում > Պառակտված բջիջներ.
2. Մեջ Պառակտված բջիջներ երկխոսության տուփ, կատարեք հետևյալ կարգավորումները:
3. Բացման մեջ Պառակտված բջիջներ երկխոսության վանդակում ընտրեք դատարկ բջիջ՝ թվանշանները դուրս բերելու համար, այնուհետև կտտացրեք կոճակին OK կոճակը:
Այնուհետև ընտրված բջիջներում թվերը միանգամից բաժանվում են առանձին թվերի:
Եթե ցանկանում եք ունենալ այս օգտակար ծառայության անվճար փորձարկում (30-օրյա), խնդրում ենք կտտացնել այն ներբեռնելու համար, և այնուհետև անցեք գործողությունը կիրառելու վերը նշված քայլերին համապատասխան:
Օրինակ #2 Բաժանել թիվը տասնորդականով
Այս բաժինը քննարկում է Excel-ում թիվը ամբողջ թվերի և տասնորդական մասերի բաժանելու մի քանի մեթոդներ:
Բանաձևերով թիվը բաժանել տասնորդականի
TRUNC ֆունկցիան կարող է կիրառվել Excel-ում տասնորդական թվերը բաժանելու համար: Դուք կարող եք անել հետևյալը.
Ընդհանուր բանաձևեր
Ստացեք ամբողջ թվային մասը
=TRUNC(A1)
Ստացեք տասնորդական մասը
=A1-TRUNC(A1)
Արգումենտ
Այժմ դուք կարող եք կիրառել այս երկու բանաձևերը՝ Excel-ում տասնորդական բջիջներում թվերը բաժանելու համար:
1. Ընտրեք բջիջ՝ առաջին թվային բջիջի ամբողջական մասը տեղադրելու համար, մուտքագրեք ստորև բերված բանաձևը և սեղմեք կոճակը. Մտնել բանալի. Ընտրեք արդյունքի բջիջը և քաշեք դրա Ավտոլրացման բռնիչը ներքև՝ այլ թվային բջիջների ամբողջ թվերը ստանալու համար:
=TRUNC(B5)
2. Ընտրեք առաջին արդյունքի բջիջի կողքին գտնվող բջիջը տասնորդական մասը տեղադրելու համար, մուտքագրեք ստորև բերված բանաձևը և սեղմեք կոճակը Մտնել բանալի. Ընտրեք այս արդյունքի բջիջը և քաշեք դրա Ինքնալրացման բռնիչը ներքև՝ այլ թվային բջիջների տասնորդականները ստանալու համար:
=B5-TRUNC(B5)
Բաժանել թիվը տասնորդականի վրա՝ Տեքստը սյունակներով
Կարող եք կիրառել Տեքստը սյունակներում Excel-ում թիվը տասնորդականով բաժանելու հատկություն:
1. Ընտրեք թվային բջիջների տիրույթը, որը կբաժանեք տասնորդական թվերով, այնուհետև սեղմեք Ամսաթիվ > Տեքստը սյունակներում.
2. Մեջ Տեքստը փոխել սյունակների կախարդի - Քայլ 1-ը 3-ից երկխոսության տուփ, ընտրեք Դիմակավորված ռադիո կոճակը և կտտացրեք այն հաջորդ կոճակը:
3. Մեջ 2- ից 3 քայլ երկխոսության տուփ, միայն ստուգեք այլ վանդակը, մուտքագրեք կետ տեքստային վանդակում, այնուհետև սեղմեք կոճակը հաջորդ կոճակը:
4. Մեջ 3- ից 3 քայլ երկխոսության տուփ, կտտացրեք կոճակ՝ նպատակակետ բջիջ ընտրելու համար, որը կարտադրի բաժանված ամբողջ թվերը և տասնորդականները, և վերջապես կտտացրեք Ավարտել կոճակ Տեսեք,
Այնուհետև կարող եք տեսնել, որ ամբողջ և տասնորդական մասերը բաժանված են ընտրված բջիջներից, ինչպես ցույց է տրված ստորև ներկայացված սքրինշոթում: Այնուամենայնիվ, տասնորդական մասը կորցնում է իր բացասական նշանը, որը կարող է անհրաժեշտ լինել օգտագործողի համար:
Բաժանել թիվը տասնորդականով Flash Fill-ով (2013 և ավելի ուշ տարբերակներ)
Վերոնշյալ օրինակում մենք ներկայացրեցինք կիրառությունը Flash լրացնել Բջիջներում տեքստը և թվերը բաժանելու ֆունկցիա, և այստեղ մենք կներկայացնենք նույն մեթոդը՝ թվերը տասնորդականով բաժանելու համար:
1. Մուտքագրեք մի քանի օրինակ: Այս դեպքում C5-ում մուտքագրում ենք B5-ի ամբողջական մասը, C6-ում մուտքագրում ենք B6-ի ամբողջական մասը: Տես սքրինշոթը.
ՆշումԲացասական թվերի դեպքում մի մոռացեք միասին մուտքագրել մինուս նշանը:
3. Ընտրեք բջիջները, ներառյալ մի քանի օրինակ սյունակում, որը ցանկանում եք լրացնել, գնացեք սեղմելու համար Ամսաթիվ > Flash լրացնել.
Այնուհետև ամբողջ թվերը հանվում են նշված թվային բջիջներից, ինչպես ցույց է տրված ստորև ներկայացված սքրինշոթում:
4. Կրկնեք վերը նշված քայլերը՝ նույն թվով բջիջներից տասնորդականները բաժանելու համար:
3. Բաժանել ամսաթվի բջիջները
Մեկ այլ իրավիճակ, որը հաճախ հանդիպում է, ամսաթվի բջիջների բաժանումն է: Եթե Ձեզ անհրաժեշտ է ամսաթվի բջիջները բաժանել առանձին օրվա, ամսվա և տարվա, կամ ամսաթվի բջիջները բաժանել առանձին ամսաթվի և ժամի, օգտագործեք հետևյալ լուծումը՝ կախված ձեր կարիքներից:
Օրինակ #1 Ամսաթվի բջիջները բաժանեք առանձին օրվա, ամսվա և տարվա
Ենթադրելով, որ դուք ունեք B5:B9 տիրույթի ամսաթվերի ցանկ, և ցանկանում եք յուրաքանչյուր ամսաթվի արժեքը բաժանել երեք առանձին սյունակների՝ օրվա, ամսվա և տարվա համար: Ահա երեք մեթոդ, որոնք կօգնեն ձեզ հասնել ամսաթվերի բաժանման արդյունքին:
Բանաձևերով տարեթվի բջիջները բաժանեք օրվա, ամսվա և տարվա
Դուք կարող եք կիրառել երեք բանաձև՝ հիմնվելով ԱՄՍԱԹԻՎ գործառույթը, ԱՄԻՍ գործառույթը եւ այլն ՏԱՐԻՆ Excel-ում ամսաթիվը առանձին օրվա, ամսվա և տարվա բաժանելու գործառույթ:
Ընդհանուր բանաձևեր
=DATE(A1)
=MONTH(A1)
=YEAR(A1)
Արգումենտ
1. Ստեղծեք երեք սյունակ՝ առանձին օրը, ամիսը և տարին տեղադրելու համար:
2. Ընտրեք օր սյունակի առաջին բջիջը, մուտքագրեք ստորև բերված բանաձևը և սեղմեք կոճակը Մտնել բանալին՝ առաջին ամսաթվի բջիջի օրը (B5) ստանալու համար: Ընտրեք այս արդյունքի բջիջը և քաշեք դրա Ինքնալրացման բռնիչը ներքև՝ այլ ամսաթվերի բջիջների օրերը ստանալու համար:
=DAY(B5)
3. Կատարեք նույն գործողությունը, ինչ քայլ 1-ում, որպեսզի կիրառեք հետևյալ բանաձևերը Ամիս և տարի սյունակ՝ ամսաթվի բջիջներից առանձին ամիս և տարի ստանալու համար:
Ստացեք ամսաթվի ամիսը
=MONTH(B5)
Ստացեք ամսաթվի տարին
=YEAR(B5)
Տեքստը սյունակների միջոցով տարանջատեք ամսաթվի բջիջները օրվա, ամսվա և տարվա
Դուք կարող եք հետևեք վերը նշված քայլերին, որպեսզի կիրառեք «Տեքստ սյունակներ» գործառույթը Excel-ում ամսաթվի բջիջները բաժանել առանձին օրվա, ամսվա և տարվա:
Նշում: Մեջ 2- ից 3 քայլ երկխոսության տուփ, միայն ստուգեք այլ վանդակում և մուտքագրեք a / խորհրդանիշը տեքստային վանդակում:
Բաժանեք ամսաթվի բջիջները օրվա, ամսվա և տարվա զարմանալի գործիքի միջոցով
Ստորև ներկայացված ցուցադրումը ցույց է տալիս, թե ինչպես կարելի է բաժանել ամսաթիվը առանձին ամսվա, օրվա և տարվա հետ Պառակտված բջիջներ առանձնահատկությունը Excel- ի համար նախատեսված գործիքներ.
Այս հատկությունը օգնում է ձեզ հասնել ամսաթվերի մեծաքանակ բաժանման արդյունքին՝ ընդամենը մի քանի կտտոցով:
Կտտացրեք ՝ այս գործառույթի մասին ավելին իմանալու համար:
Եթե ցանկանում եք ունենալ այս օգտակար ծառայության անվճար փորձարկում (30-օրյա), խնդրում ենք կտտացնել այն ներբեռնելու համար, և այնուհետև անցեք գործողությունը կիրառելու վերը նշված քայլերին համապատասխան:
Օրինակ #2 Բաժանել ամսաթիվը և ժամը մեկ խցում
Ենթադրենք, որ B5:B9-ում կա ամսաթվերի ժամերի ցանկ, և դուք ցանկանում եք բաժանել ամսաթվերը և ժամերը առանձին սյունակների, այս բաժինը ցույց կտա տարբեր եղանակներ, որոնք կօգնեն ձեզ դա անել:
Բաժանեք ամսաթիվը և ժամը բանաձևով բջիջում
Դուք կարող եք կիրառել հետևյալ բանաձևերը՝ Excel-ում ամսաթիվը և ժամը տարբեր սյունակներ բաժանելու համար:
1. Պատրաստեք երկու սյունակ՝ ամսաթվերը և ժամերը տեղադրելու համար:
2. Դուք պետք է սահմանեք ամսաթվի սյունակի բջիջները Ամսաթիվ ձևաչափել և սահմանել ժամանակի սյունակի բջիջները ժամանակ ձեւաչափը.
3. Ընտրեք առաջին բջիջը Ամսաթիվ սյունակում, մուտքագրեք ստորև բերված բանաձևը և սեղմեք կոճակը Մտնել բանալին՝ B5-ի ամսաթիվը ստանալու համար: Ընտրեք այս արդյունքի բջիջը և քաշեք դրա Ինքնալրացման կարգավորիչը՝ մյուս ամսաթվերը ստանալու համար:
=INT(B5)
4. Ժամանակի սյունակում կիրառեք հետևյալ բանաձևը՝ B5:B9-ի ժամանակները ստանալու համար:
=B5-D5
Բաժանել ամսաթիվը և ժամը բջիջում Flash Fill-ով (2013 և ավելի ուշ տարբերակներ)
Եթե դուք օգտագործում եք Excel 2013-ը և ավելի ուշ տարբերակները, կարող եք կիրառել ներկառուցված Flash Fill ֆունկցիան՝ ամսաթիվը և ժամը բաժանելու տարբեր սյունակների:
1. Ստեղծեք Ամսաթիվ և Ժամ սյունակները և մուտքագրեք մի քանի օրինակ, որը ցանկանում եք որպես արդյունք: Մեջ Ամսաթիվ սյունակում, C5-ում մուտքագրում ենք B5-ի ամսաթիվը, C6-ում՝ B6-ի ամսաթիվը: Մեջ ժամանակ սյունակում, մենք մուտքագրում ենք B5-ի ժամանակը D5-ում և մուտքագրում B6-ի ժամանակը D6-ում: Տես սքրինշոթը.
2. Ընտրեք Ամսաթիվ սյունակը (ներառյալ մի քանի օրինակներ), որը ցանկանում եք լրացնել, գնացեք սեղմեք Ամսաթիվ > Flash լրացնել.
3. Ընտրեք Ժամանակի սյունակը (ներառյալ մի քանի օրինակներ), որը ցանկանում եք լրացնել, ապա միացրեք Flash լրացնել հատկանիշը նույնպես: Այնուհետև B5:B9-ում ամսաթվերը և ժամերը բաժանվում են առանձին սյունակների, ինչպես ցույց է տրված ստորև ներկայացված ցուցադրությունում:
Այժմ դուք սովորել եք, թե ինչպես բաժանել բջիջները Excel-ում տարբեր մեթոդներով տարբեր իրավիճակներում: Դուք կկարողանաք լավագույն որոշում կայացնել՝ որոշելու, թե որ մեթոդն եք ընտրում, որը կախված է ձեր կոնկրետ սցենարից:
Գրասենյակի արտադրողականության լավագույն գործիքները
Լրացրեք ձեր Excel-ի հմտությունները Kutools-ի հետ Excel-ի համար և փորձեք արդյունավետությունը, ինչպես երբեք: Kutools-ը Excel-ի համար առաջարկում է ավելի քան 300 առաջադեմ առանձնահատկություններ՝ արտադրողականությունը բարձրացնելու և ժամանակ խնայելու համար: Սեղմեք այստեղ՝ Ձեզ ամենաշատ անհրաժեշտ հատկանիշը ստանալու համար...
Office Tab- ը Tabbed ինտերֆեյսը բերում է Office, և ձեր աշխատանքը շատ ավելի դյուրին դարձրեք
- Միացնել ներդիրներով խմբագրումը և ընթերցումը Word, Excel, PowerPoint- ով, Հրատարակիչ, Access, Visio և Project:
- Բացեք և ստեղծեք բազմաթիվ փաստաթղթեր նույն պատուհանի նոր ներդիրներում, այլ ոչ թե նոր պատուհաններում:
- Բարձրացնում է ձեր արտադրողականությունը 50%-ով և նվազեցնում մկնիկի հարյուրավոր սեղմումները ձեզ համար ամեն օր: