Note: The other languages of the website are Google-translated. Back to English
Մուտք  \/ 
x
or
x
Գրանցում  \/ 
x

or

VLOOKUP գործառույթ ՝ Excel- ում մի քանի հիմնական և առաջադեմ օրինակներով

Excel- ում VLOOKUP գործառույթը հզոր գործառույթ է Excel- ի օգտվողների մեծ մասի համար, որն օգտագործվում է տվյալների տիրույթի ձախ մասում արժեք փնտրելու և նույն շարքում համապատասխան սյունակի վերադարձման համար `նշած սյունակից, ինչպես ցույց է տրված նկարում , Այս ձեռնարկը խոսում է այն մասին, թե ինչպես օգտագործել VLOOKUP գործառույթը Excel- ի մի քանի հիմնական և առաջադեմ օրինակներով:

Բովանդակություն:

1. VLOOKUP գործառույթի ներդրում. Շարահյուսություն և փաստարկներ

2. VLOOKUP- ի հիմնական օրինակներ

3. VLOOKUP- ի առաջադեմ օրինակներ

4. VLOOKUP- ի համապատասխան արժեքները պահպանում են բջիջների ձևաչափումը

5. Ներբեռնեք VLOOKUP ֆայլերի նմուշը


VLOOKUP գործառույթի ներդրում. Շարահյուսություն և փաստարկներ

VLOOKUP գործառույթի շարահյուսությունը.

=VLOOKUP (lookup_value, table_array, col_index_num, [range_lookup])

Արձանագրություններ.

Փնտրման_ արժեքԱրժեքը, որը ցանկանում եք որոնել: Այն պետք է լինի table_array տիրույթի առաջին սյունակում:

Աղյուսակ_ զանգվածՏվյալների տիրույթը կամ աղյուսակը, որտեղ որոնման արժեքի սյունն է և արդյունքի արժեքի սյունը:

Col_index_numՍյունակի քանակը, որից կվերադարձվի համապատասխան արժեքը: Այն սկսվում է 1-ով `աղյուսակի զանգվածի ձախակողմյան սյունակից:

Range_lookupՏրամաբանական արժեք, որը որոշում է, թե արդյոք այս VLOOKUP գործառույթը կվերադարձնի ճշգրիտ համընկնումը կամ մոտավոր համընկնումը:

  • Մոտավոր համընկնում - 1 / TRՇՄԱՐՏՈՒԹՅՈՒՆԵթե ​​ճշգրիտ համընկնում չգտնվի, բանաձևը որոնում է ամենամոտ համընկնումը ՝ ամենամեծ արժեքը, որը փոքր է որոնման արժեքից: Այս դեպքում դուք պետք է տեսակավորեք որոնման սյունը աճման կարգով:
    = VLOOKUP (որոնման_ արժեքը, աղյուսակի_հավաքվածքը, col_index, TRUE)
    = VLOOKUP (որոնման_ արժեքը, աղյուսակի_հավաքվածքը, col_index, 1)
  • Actշգրիտ համընկնում - 0 / ԿԵ: Սա օգտագործվում է որոնման արժեքին ճիշտ հավասար արժեք որոնելու համար: Եթե ​​ճշգրիտ համընկնում չգտնվի, ապա սխալ կլինի N # A սխալի արժեքը:
    = VLOOKUP (որոնման_ արժեքը, աղյուսակի_հավաքվածքը, col_index- ը, FALSE)
    = VLOOKUP (որոնման_ արժեքը, աղյուսակի_հավաքվածքը, col_index, 0)

Նշումներ:

  • 1. Vlookup գործառույթը արժեք է փնտրում միայն ձախից աջ:
  • 2. Եթե փնտրման արժեքի հիման վրա կան բազմաթիվ համապատասխանող արժեքներ, ապա միայն առաջին համապատասխանեցվածը կվերադարձվի ՝ օգտագործելով Vlookup գործառույթը:
  • 3. Այն կվերադարձնի # N / A սխալի արժեքը, եթե որոնման արժեքը հնարավոր չէ գտնել:

VLOOKUP- ի հիմնական օրինակներ

1. Կատարեք ճշգրիտ համընկնում Vlookup- ի հետ և մոտավոր համընկնում Vlookup- ի հետ

Doշգրիտ համապատասխանեք Vlookup- ին Excel- ում

Սովորաբար, եթե դուք ճշգրիտ համապատասխանություն եք փնտրում Vlookup գործառույթի հետ, ապա վերջին փաստարկում պարզապես անհրաժեշտ է օգտագործել FALSE:

Օրինակ, հատուկ ID համարների հիման վրա մաթեմատիկայի համապատասխան միավորներ ստանալու համար կատարեք հետևյալ կերպ.

1. Կիրառեք ստորև բերված բանաձևը դատարկ բջիջի մեջ, որտեղ ցանկանում եք արդյունք ստանալ.

=VLOOKUP(F2,$A$2:$D$7,3,FALSE)

2, Եվ հետո, լրացնելու բռնիչը ներքև քաշեք դեպի այն բջիջները, որոնք ցանկանում եք լրացնել այս բանաձևը, և ​​արդյունքները կստանաք ըստ ձեզ: Տեսեք,

Նշումներ:

  • 1. Վերոնշյալ բանաձևում F2 այն արժեքն է, որը ցանկանում եք վերադարձնել դրա համապատասխան արժեքը, A2: D7 սեղանի զանգվածն է, համարը 3 սյունակի համարն է, որից վերադարձվում է ձեր համապատասխան արժեքը և ԿԵՂԾ վերաբերում է ճշգրիտ համընկնումին:
  • 2. Եթե ձեր չափանիշի տվյալները չեն գտնվել տվյալների տիրույթում, կցուցադրվի սխալի արժեք # N / A:

Excel- ում կատարեք մոտավոր համընկնում Vlookup- ի հետ

Մոտավոր համընկնումն օգտակար է տվյալների տիրույթների միջեւ արժեքները որոնելու համար: Եթե ​​ճշգրիտ համընկնումը չգտնվի, մոտավոր Vlookup- ը կվերադարձնի ամենամեծ արժեքը, որը փոքր է որոնման արժեքից:

Օրինակ, եթե ունեք հետևյալ տիրույթի տվյալները, նշված պատվերները Պատվերների սյունակում չեն, ինչպե՞ս ստանալ B սյունակում իր ամենամոտ Discեղչը:

1, Մուտքագրեք հետևյալ բանաձևը այն բջիջում, որտեղ ցանկանում եք տեղադրել արդյունքը.

=VLOOKUP(D2,$A$2:$B$9,2,TRUE)

2, Դրանից հետո այս բանաձևը կիրառելու համար քաշեք լրացնելու բռնիչը դեպի բջիջները, և կստանաք մոտավոր համընկնումներ ՝ տրված արժեքների հիման վրա, տես նկարի նկարը.

Նշումներ:

  • 1. Վերոնշյալ բանաձևում D2 այն արժեքն է, որը դուք ցանկանում եք վերադարձնել իր հարաբերական տեղեկատվությունը, A2: B9 տվյալների տիրույթն է, համարը 2 նշում է սյունակի համարը, որ ձեր համապատասխան արժեքը վերադարձվում է և TRUE վերաբերում է մոտավոր համընկնումին:
  • 2. Մոտավոր համընկնումը կվերադարձնի ամենամեծ արժեքը, որը փոքր է ձեր որոնման որոշակի արժեքից:
  • 3. Մոտավոր համընկնումի արժեք ստանալու համար Vlookup գործառույթն օգտագործելու համար դուք պետք է տեսակավորեք տվյալների տիրույթի ձախ ձախ սյունը աճման կարգով, հակառակ դեպքում դա կվերադարձնի սխալ արդյունք:

2. Excel- ում գործերով զգայուն Vlookup կատարեք

Լռելյայնորեն, Vlookup գործառույթը կատարում է գործի նկատմամբ անզգայուն որոնում, ինչը նշանակում է, որ այն փոքրատառ և մեծատառ նիշերին վերաբերվում է որպես նույնական: Imeամանակ առ ժամանակ կարող է անհրաժեշտ լինել Excel- ում գործի վրա զգայուն որոնում կատարել, ինդեքսը, համապատասխանությունը և ճշգրիտ գործառույթները կամ որոնման և ճշգրիտ գործառույթները կարող են ձեզ լավություն բերել:

Օրինակ, ես ունեմ հետևյալ տվյալների տիրույթը, որը ID սյունը պարունակում է տեքստային տող `մեծատառով կամ փոքրատառով, այժմ ուզում եմ վերադարձնել տրված նույնականացման համարի համապատասխան մաթեմատիկական գնահատականը:

Բանաձև 1. Օգտագործելով ACՇՏ, ԻՆԴԵՔՍ, ՀԱՇԻՎ գործառույթներ

1, Խնդրում ենք մուտքագրել կամ պատճենել զանգվածի ստորև բերված բանաձևը դատարկ վանդակում, որտեղ ցանկանում եք արդյունքը ստանալ.

=INDEX($C$2:$C$10,MATCH(TRUE,EXACT(F2,$A$2:$A$10),0))

2, Հետո, սեղմեք Ctrl + Shift + Մուտք ստեղները միաժամանակ `առաջին արդյունքը ստանալու համար, ապա ընտրեք բանաձևի բջիջը, լրացնելու բռնիչը ներքև քաշեք դեպի այն բջիջները, որոնք ցանկանում եք լրացնել այս բանաձևը, այնուհետև կստանաք ձեզ անհրաժեշտ ճիշտ արդյունքները: Տեսեք,

Նշումներ:

  • 1. Վերոնշյալ բանաձևում A2: A10 սյունն է, որը պարունակում է հատուկ արժեքներ, որոնցում ցանկանում եք փնտրել, F2 որոնման արժեքն է, C2: C10 սյունն է, որտեղից արդյունքը կվերադարձվի:
  • 2. Եթե մի քանի համընկնում գտնվի, այս բանաձևը միշտ կվերադարձնի առաջին համընկնումը:

Բանաձև 2. Օգտագործման և ճշգրիտ գործառույթների օգտագործումը

1. Ստորև բերված բանաձևը կիրառեք դատարկ բջիջի մեջ, որտեղ ցանկանում եք արդյունք ստանալ.

=LOOKUP(2,1/EXACT(F2,$A$2:$A$10),$C$2:$C$10)

2. Այնուհետեւ, լրացրեք բռնիչը ներքև քաշեք դեպի այն բջիջները, որոնք ցանկանում եք պատճենել այս բանաձևը, և ​​կստանաք համապատասխան արժեքներ տառատեսակի հետ, ինչպես ցույց է տրված ստորև նշված նկարում.

Նշումներ:

  • 1. Վերոնշյալ բանաձևում A2: A10 սյունն է, որը պարունակում է հատուկ արժեքներ, որոնցում ցանկանում եք փնտրել, F2 որոնման արժեքն է, C2: C10 սյունն է, որտեղից արդյունքը կվերադարձվի:
  • 2. Եթե գտնվեն բազմաթիվ համընկնումներ, այս բանաձևը միշտ կվերադարձնի վերջին հանդիպումը:

3. Vlookup- ի արժեքները աջից ձախ Excel- ում

Vlookup ֆունկցիան միշտ որոնում է տվյալների տիրույթի ձախ ձախ սյունակում գտնվող արժեքը և համապատասխան արժեքը վերադարձնում սյունակից աջ: Եթե ​​ցանկանում եք կատարել հակառակ Vlookup, ինչը նշանակում է որոնել որոշակի արժեք աջից և վերադարձնել դրա համապատասխան արժեքը ձախ սյունակում, ինչպես ցույց է տրված ստորև նշված նկարը.

Կտտացրեք ՝ այս գործի վերաբերյալ մանրամասները քայլ առ քայլ իմանալու համար


4. Vlookup- ի Excel- ում երկրորդ, n- րդ կամ վերջին համապատասխանող արժեքը

Սովորաբար, եթե Vlookup գործառույթն օգտագործելիս հայտնաբերվում են համապատասխանության բազմաթիվ արժեքներ, կվերադարձվի միայն առաջին համապատասխան գրառումը: Այս բաժնում ես կխոսեմ այն ​​մասին, թե ինչպես ստանալ երկրորդ, n- րդ կամ վերջին համապատասխանող արժեքը Vlookup գործառույթի հետ:

Vlookup և վերադարձնել երկրորդ կամ n- ին համապատասխանող արժեքը

Ենթադրենք, որ դուք ունեք A սյունակի անունների ցուցակ, B սյունակում ձեռք բերած վերապատրաստման դասընթաց, և այժմ դուք փնտրում եք տվյալ հաճախորդի կողմից գնված 2-րդ կամ XNUMX-րդ դասընթացները: Տեսեք,

1, Տրված չափանիշների հիման վրա երկրորդ կամ n- ի համապատասխանեցման արժեքը ստանալու համար խնդրում ենք կիրառել զանգվածի հետևյալ բանաձևը դատարկ բջիջի մեջ.

=INDEX($B$2:$B$14,SMALL(IF(E2=$A$2:$A$14,ROW($A$2:$A$14)-ROW($A$2)+1),2))

2, Դրանից հետո սեղմեք Ctrl + Shift + Մուտք ստեղները միասին `առաջին արդյունքը ստանալու համար, ապա ընտրեք բանաձևի բջիջը, լրացնելու բռնիչը ներքև քաշեք դեպի այն բջիջները, որոնք ցանկանում եք լրացնել այս բանաձևը, և ​​տրված անունների վրա հիմնված բոլոր երկրորդ համապատասխան արժեքները միանգամից ցուցադրվել են, տե՛ս նկարը.

Նշում:

  • Այս բանաձևում A2: A14 ընդգրկույթն է ՝ որոնման բոլոր արժեքներով, B2: B14 համապատասխան արժեքների շարք է, որից ուզում եք վերադառնալ, E2 որոնման արժեքն է և վերջին համարը 2 նշում է երկրորդ համապատասխանեցված արժեքը, որը ցանկանում եք ստանալ, եթե ուզում եք վերադարձնել համապատասխանող երրորդ արժեքը, պարզապես անհրաժեշտ է այն փոխել 3-ի, որքան ձեզ հարկավոր է:

Vlookup և վերադարձեք համապատասխանության վերջին արժեքը

Եթե ​​ցանկանում եք դիտել և վերադարձնել համապատասխանության վերջին արժեքը, ինչպես ցույց է տրված նկարում, Vlookup և վերադարձնել համապատասխանության վերջին արժեքը ձեռնարկը կարող է օգնել ձեզ մանրամասնորեն գտնել վերջին համապատասխանող արժեքը:


5. Vlookup- ի համապատասխանեցված արժեքները տրված երկու արժեքների կամ ամսաթվերի միջև

Երբեմն գուցե ցանկանաք երկու արժեքների կամ ամսաթվերի միջև արժեքներ որոնել և համապատասխան արդյունքները վերադարձնել, ինչպես ցույց է տրված ստորև նշված էկրանի նկարը, այս դեպքում կարող եք օգտագործել LOOKUP գործառույթը և տեսակավորված աղյուսակը:

Vlookup- ի համապատասխանեցված արժեքները տրված երկու արժեքների կամ ամսաթվերի միջև բանաձևի հետ

1, Նախ, ձեր բնօրինակ աղյուսակը պետք է լինի տեսակավորված տվյալների տիրույթ: Եվ ապա, պատճենեք կամ մուտքագրեք հետևյալ բանաձևը դատարկ բջիջում.

=LOOKUP(2,1/($A$2:$A$6<=E2)/($B$2:$B$6>=E2),$C$2:$C$6)

2, Այնուհետև քաշեք լրացման բռնիչը ՝ այս բանաձևը լրացնելու համար ձեզ անհրաժեշտ այլ բջիջները լրացնելու համար, և այժմ դուք կստանաք բոլոր համապատասխան գրառումները ՝ տրված արժեքի հիման վրա, տես նկարի նկարը.

Նշումներ:

  • 1. Վերոնշյալ բանաձևում A2: A6 փոքր արժեքների տիրույթն է և B2: B6 ձեր տվյալների տիրույթում ավելի մեծ թվերի տիրույթն է, E2 տրված արժեքն է, որը ցանկանում եք ստանալ դրա համապատասխան արժեքը, C2: C6 սյունակի տվյալներն են, որոնցից ցանկանում եք արդյունահանել:
  • 2. Այս բանաձևը կարող է օգտագործվել նաև երկու ամսաթվերի միջև համապատասխան արժեքներ հանելու համար, ինչպես ցույց է տրված ստորև նշված էկրանի նկարը.

Vlookup- ի համապատասխան արժեքները տրված երկու արժեքների կամ ամսաթվերի միջև `օգտակար հատկությամբ

Եթե ​​դուք ցավոտ եք վերը նշված բանաձևով, ապա ես կներկայացնեմ մի հեշտ գործիք - Excel- ի համար նախատեսված գործիքներԻր Փնտրեք երկու արժեքների միջև առանձնահատկությունը, դուք կարող եք վերադարձնել համապատասխան նյութը ՝ հիմնվելով որոշակի արժեքի կամ ամսաթվի վրա երկու արժեքների կամ ամսաթվերի միջև ՝ առանց հիշելու որևէ բանաձև:   Կտտացրեք Kutools- ի Excel- ի համար ներբեռնելու համար:


6. Vlookup գործառույթում մասնակի համընկնումների համար վայրի քարտեր օգտագործելը

Excel- ում վայրի քարտերը կարող են օգտագործվել Vlookup գործառույթի շրջանակներում, ինչը թույլ է տալիս մասնակի համապատասխանություն կատարել որոնման արժեքի հետ: Օրինակ, որոնման արժեքի մի մասի վրա հիմնված աղյուսակից համապատասխան արժեքը վերադարձնելու համար կարող եք օգտագործել Vlookup- ը:

Ենթադրելով, որ ես ունեմ տվյալների մի շարք, ինչպես ցույց է տրված սքրինշոթից ներքևում, այժմ ուզում եմ արդյունքը հանել ՝ ելնելով անունից (ոչ լրիվ անունից): Ինչպե՞ս կարող է լուծել այս խնդիրը Excel- ում:

1, Նորմալ Vlookup գործառույթը ճիշտ չի աշխատում, դուք պետք է միանաք տեքստին կամ բջջային տեղեկանքին վայրի քարտով, խնդրում ենք պատճենել կամ մուտքագրել հետևյալ բանաձևը դատարկ բջիջում.

=VLOOKUP(E2&"*", $A$2:$C$11, 3, FALSE)

2, Դրանից հետո, քաշեք լրացնելու բռնիչը, այս բանաձևը լրացնելու համար անհրաժեշտ այլ բջիջներ, և բոլոր համապատասխան միավորները վերադարձվել են, ինչպես ցույց է տրված ստորև նշված էկրանի նկարը.

Նշումներ:

  • 1. Վերոնշյալ բանաձևում E2 & ”*” որոնման արժեքն է, արժեքը E2 եւ * վայրի քարտ («*» - ը նշում է ցանկացած նիշ կամ որևէ նիշ), A2: C11 որոնման տիրույթն է, համարը 3 սյունակը, որը պարունակում է վերադարձման արժեք:
  • 2. Վլոկափը վայրի քարտեր օգտագործելիս, Vlookup գործառույթի վերջին փաստարկի համար անհրաժեշտ է ճշգրիտ համընկման ռեժիմ սահմանել ՍՈՒՏ-ի կամ 0-ի հետ:

Հուշում.

1. Գտեք և վերադարձեք որոշակի արժեքով ավարտվող համապատասխանող արժեքները, խնդրում ենք կիրառել այս բանաձևը. =VLOOKUP("*"&E2, $A$2:$C$11, 3, FALSE)

2. Տեքստի տողի մի մասի վրա հիմնված համապատասխան արժեքը որոնելու և վերադարձնելու համար ՝ լինի արդյոք նշված տեքստը տեքստի տողի առջևում, ետևում կամ մեջտեղում, պարզապես անհրաժեշտ է միացնել երկու * նիշ բջիջի տեղեկանքի կամ տեքստի շուրջ: Խնդրում ենք անել այս բանաձևով. =VLOOKUP("*"&D2&"*", $A$2:$B$11, 2, FALSE)


7. Vlookup- ի արժեքները մեկ այլ աշխատանքային թերթից

Սովորաբար, գուցե ստիպված լինեք աշխատել մեկից ավելի աշխատանքային թերթիկի հետ, Vlookup գործառույթը կարող է օգտագործվել մեկ այլ թերթից տվյալների որոնման համար, ինչպես նույնը, ինչ մեկ աշխատանքային թերթում:

Օրինակ, դուք ունեք երկու աշխատանքային թերթ, ինչպես ցույց է տրված ստորև նշված էկրանի նկարը, ձեր կողմից նշված աշխատաթերթից համապատասխան տվյալները որոնելու և վերադարձնելու համար կատարեք հետևյալ քայլերը.

1. Խնդրում ենք մուտքագրել կամ պատճենել ներքևի բանաձևը դատարկ վանդակում, որտեղ ցանկանում եք ստանալ համապատասխանեցված իրերը.

=VLOOKUP(A2,'Data sheet'!$A$2:$C$15,3,0)

2. Այնուհետեւ, լրացրեք բռնիչը ներքև քաշեք դեպի այն բջիջները, որոնք ցանկանում եք կիրառել այս բանաձևը, և ​​դուք կստանաք համապատասխան արդյունքներ, ինչպես ձեզ հարկավոր է, տես նկարի նկարը.

Նշում: Վերոնշյալ բանաձևում.

  • A2 ներկայացնում է որոնման արժեքը;
  • Տվյալների թերթիկ աշխատաթերթի անունն է, որից ուզում եք որոնել տվյալները. (Եթե թերթիկի անունը պարունակում է տարածություն կամ կետադրական նիշեր, ապա թերթի անվան շուրջ պետք է կցեք առանձին մեջբերումներ, հակառակ դեպքում, կարող եք ուղղակիորեն օգտագործել թերթի անունը, ինչպես = VLOOKUP (A2, Տվյալների թերթիկ. $ A $ 2: $ C $ 15,3,0));
  • A2: C15 տվյալների շղթայում տվյալների տիրույթն է, որտեղ մենք որոնում ենք տվյալներ.
  • համարը 3 սյունակի համարն է, որը պարունակում է համապատասխան տվյալներ, որոնցից ցանկանում եք վերադարձնել:

8. Vlookup- ի արժեքները մեկ այլ աշխատանքային գրքից

Այս բաժինը կխոսի որոնման և վերադարձնելու համապատասխան աշխատանքային արժեքները այլ աշխատանքային գրքից ՝ օգտագործելով Vlookup գործառույթը:

Օրինակ ՝ առաջին աշխատանքային գիրքը պարունակում է ապրանքների և ծախսերի ցուցակներ, այժմ դուք ցանկանում եք համապատասխան արդյունքը արդյունահանել երկրորդ աշխատանքային գրքում ՝ հիմնվելով ապրանքի նյութի վրա, ինչպես ցույց է տրված նկարում:

1, Մեկ այլ աշխատանքային գրքից հարաբերական ծախսը վերցնելու համար նախ բացեք և՛ այն աշխատանքային գրքերը, որոնք ցանկանում եք օգտագործել, ապա կիրառեք հետևյալ բանաձևը այն բջիջում, որտեղ ցանկանում եք տեղադրել արդյունքը.

=VLOOKUP(B2,'[Product list.xlsx]Sheet1'!$A$2:$B$6,2,0)

2, Այնուհետև քաշեք և պատճենեք այս բանաձևը ձեզ համար անհրաժեշտ այլ բջիջների վրա: Տեսեք,

Նշումներ:

  • 1. Վերոնշյալ բանաձևում.
    B2 ներկայացնում է որոնման արժեքը;
    [Ապրանքների ցուցակ. Xlsx] Թերթ 1 աշխատանքային գրքի և աշխատանքային թերթի անվանումն է, որից ցանկանում եք որոնել տվյալները, (աշխատանքային գրքի հղումը կցված է քառակուսի փակագծերում, իսկ աշխատանքային տետրը + թերթիկը կցված է առանձին գնանշումներով);
    A2: B6 տվյալների տիրույթն է մեկ այլ աշխատանքային գրքի աշխատանքային թերթում, որտեղ մենք որոնում ենք տվյալներ.
    համարը 2 սյունակի համարն է, որը պարունակում է համապատասխան տվյալներ, որոնցից ցանկանում եք վերադարձնել:
  • 2. Եթե որոնման աշխատանքային գիրքը փակ է, որոնման աշխատանքային գրքի համար ամբողջ ֆայլի ուղին կցուցադրվի բանաձևում, ինչպես ցույց է տրված հետևյալ նկարը.

9. Vlookup և վերադարձնել դատարկ կամ հատուկ տեքստ 0-ի կամ # N / A սխալի արժեքի փոխարեն

Սովորաբար, երբ vlookup գործառույթը կիրառում եք համապատասխան արժեքը վերադարձնելու համար, եթե ձեր համապատասխան բջիջը դատարկ է, այն կվերադարձնի 0, և եթե ձեր համապատասխան արժեքը չգտնվի, դուք կստանաք սխալ # N / A արժեք, ինչպես ցույց է տրված նկարում: 0 կամ # N / A արժեքը դատարկ բջիջով կամ ձեզ դուր եկած այլ արժեքով ցուցադրելու փոխարեն, սա Vlookup- ը 0 կամ N / A- ի փոխարեն դատարկ կամ որոշակի արժեք վերադարձնելու համար ձեռնարկը կարող է քայլ առ քայլ լավություն տալ ձեզ:


VLOOKUP- ի առաջադեմ օրինակներ

1. Երկկողմանի որոնում Vlookup գործառույթով (Vlookup շարքում և սյունակում)

Երբեմն կարող է անհրաժեշտ լինել կատարել երկչափ որոնում, ինչը նշանակում է, որ Vlookup- ը միաժամանակ լինի և շարքում, և սյունակում: Ասենք, եթե ունեք տվյալների հետևյալ շարքը, և այժմ, գուցե անհրաժեշտ լինի որոշակի արտադրանքի արժեքը ստանալ նշված եռամսյակում: Այս բաժինը կներկայացնի Excel- ում այս գործով զբաղվելու որոշ բանաձև:

Բանաձև 1. Օգտագործելով VLOOKUP և MATCH գործառույթներ

Excel- ում երկկողմանի որոնում կատարելու համար կարող եք օգտագործել VLOOKUP և MATCH գործառույթների համադրություն, խնդրում ենք կիրառել հետևյալ բանաձևը դատարկ բջիջում, ապա սեղմել Մտնել արդյունքը ստանալու բանալին:

=VLOOKUP(H1, $A$2:$E$6, MATCH(H2, $A$1:$E$1, 0), FALSE)

Նշում: Վերոնշյալ բանաձևում.

  • H1որոնման արժեքը սյունակում, որի հիման վրա ցանկանում եք ստանալ համապատասխան արժեքը.
  • A2: E6տվյալների տիրույթը, ներառյալ տողի վերնագրերը.
  • H2տողի որոնման արժեքը, որի վրա ցանկանում եք ստանալ համապատասխան արժեքը `հիմնվելով;
  • A1: E1սյունակի վերնագրերի բջիջները.

Բանաձև 2. Օգտագործելով INDEX և MATCH գործառույթները

Ահա ևս մեկ բանաձև, որը կարող է նաև օգնել ձեզ իրականացնել երկչափ որոնում, խնդրում ենք կիրառել ստորև բերված բանաձևը, ապա սեղմել Մտնել բանալին ՝ անհրաժեշտ արդյունքն ստանալու համար:

=INDEX($B$2:$E$6, MATCH(H1, $A$2:$A$6, 0), MATCH(H2, $B$1:$E$1, 0))

Նշում: Վերոնշյալ բանաձևում.

  • B2: E6տվյալների միջակայքը համապատասխան նյութը վերադարձնելու համար;
  • H1որոնման արժեքը սյունակում, որի հիման վրա ցանկանում եք ստանալ համապատասխան արժեքը.
  • A2: A6տողի վերնագրերը պարունակում են այն ապրանքը, որը ցանկանում եք փնտրել:
  • H2տողի որոնման արժեքը, որի վրա ցանկանում եք ստանալ համապատասխան արժեքը `հիմնվելով;
  • B1: E1սյունակի վերնագրերը պարունակում են այն եռամսյակը, որը ցանկանում եք փնտրել:

2. Vlookup- ի համապատասխանող արժեքը `հիմնված երկու կամ ավելի չափանիշների վրա

Ձեզ համար հեշտ է փնտրել համապատասխանող արժեքը մեկ չափանիշի հիման վրա, բայց եթե ունեք երկու կամ ավելի չափանիշ, ի՞նչ կարող եք անել: Excel- ում LOOKUP կամ MATCH և INDEX գործառույթները կարող են օգնել ձեզ լուծել այս աշխատանքը արագ և հեշտությամբ:

Օրինակ, ես ունեմ ստորև բերված տվյալների աղյուսակը `համապատասխան ապրանքի և չափի հիման վրա համապատասխան գինը վերադարձնելու համար հետևյալ բանաձևերը կարող են օգնել ձեզ:

Ֆորմուլա 1. Օգտագործելով LOOKUP գործառույթը

Խնդրում ենք կիրառել ստորև բերված բանաձևը այն բջիջում, որտեղ ցանկանում եք արդյունք ստանալ, և այնուհետև սեղմել Enter ստեղնը, տես նկարի նկարը.

=LOOKUP(2,1/($A$2:$A$12=G1)/($B$2:$B$12=G2),($D$2:$D$12))

Նշումներ:

  • 1. Վերոնշյալ բանաձևում.
    A2: A12 = G1նշանակում է ՝ որոնել G1– ի չափանիշները A2 տիրույթում ՝ A12;
    B2: B12 = G2նշանակում է ՝ B2 տիրույթում որոնել G2– ի չափանիշները. B12;
    D2: D12միջակայքը, որը ցանկանում եք վերադարձնել համապատասխան արժեքը:
  • 2. Եթե ունեք ավելի քան երկու չափանիշ, ապա պարզապես անհրաժեշտ է միացնել մնացած չափանիշները բանաձևում, ինչպիսիք են. =LOOKUP(2,1/($A$2:$A$12=G1)/($B$2:$B$12=G2)/($C$2:$C$12=G3),($D$2:$D$12))

Բանաձև 2. Օգտագործելով INDEXT և MATCH գործառույթները

Indexուցանիշի և Համապատասխանության գործառույթի համադրությունը կարող է օգտագործվել նաև բազմաթիվ չափանիշների հիման վրա համապատասխանեցված արժեքը վերադարձնելու համար: Խնդրում ենք պատճենել կամ մուտքագրել հետևյալ բանաձևը.

=INDEX($D$2:$D$12,MATCH(1,($A$2:$A$12=G1)*($B$2:$B$12=G2),0))

Դրանից հետո, միասին սեղմեք Ctrl + Shift + Enter ստեղները ՝ ստանալու համար անհրաժեշտ հարաբերական արժեքը: Տեսեք,

Նշումներ:

  • 1. Վերոնշյալ բանաձևում.
    A2: A12 = G1նշանակում է ՝ որոնել G1– ի չափանիշները A2 տիրույթում ՝ A12;
    B2: B12 = G2նշանակում է ՝ B2 տիրույթում որոնել G2– ի չափանիշները. B12;
    D2: D12միջակայքը, որը ցանկանում եք վերադարձնել համապատասխան արժեքը:
  • 2. Եթե ունեք ավելի քան երկու չափանիշ, ապա պարզապես անհրաժեշտ է միացնել նոր չափանիշները բանաձևում, ինչպիսիք են. =INDEX($D$2:$D$12,MATCH(1,($A$2:$A$12=G1)*($B$2:$B$12=G2)*($C$2:$C$12=G3),0))

3. Vlookup ՝ մի քանի համընկնող արժեքներ մեկ կամ մի քանի պայմաններով վերադարձնելու համար

Excel- ում Vlookup ֆունկցիան որոնում է մի արժեք և վերադարձնում է առաջին համապատասխանեցման արժեքը միայն այն դեպքում, եթե հայտնաբերված են բազմաթիվ համապատասխան արժեքներ: Երբեմն գուցե ցանկանաք հետ բերել բոլոր համապատասխան արժեքները անընդմեջ, սյունակում կամ մեկ խցում: Այս բաժնում կխոսվի այն մասին, թե ինչպես վերադարձնել համապատասխան գրության բազմաթիվ արժեքները աշխատանքային գրքում մեկ կամ մի քանի պայմանների հետ:

Vlookup- ի բոլոր համապատասխան արժեքները, որոնք հիմնված են հորիզոնականորեն մեկ կամ մի քանի պայմանների վրա

Vlookup- ի բոլոր համապատասխան արժեքները, որոնք հիմնված են մեկ պայմանի վրա, հորիզոնական կերպով.

Vlookup- ին և հորիզոնականորեն մեկ հատուկ արժեքի վրա հիմնված բոլոր համապատասխան արժեքները վերադարձնելու համար ընդհանուր բանաձևն է.

=IFERROR(INDEX(return_range, SMALL(IF(lookup_value = lookup_range, ROW(return_range) - m, ""), COLUMN() - n)), "")
Նշում: m վերադարձի միջակայքում մինուս 1-ի առաջին բջիջի տողի համարն է:
      n առաջին բանաձևի բջիջի մինուս 1 սյունակի համարն է:

1, Ստորև բերված բանաձևը կիրառեք դատարկ վանդակի մեջ, այնուհետև սեղմեք Ctrl + Shift + Մուտք ստեղները միասին ՝ առաջին համապատասխան արժեքը ստանալու համար, տե՛ս նկարը.

=IFERROR(INDEX($C$2:$C$20, SMALL(IF($F1=$A$2:$A$20, ROW($C$2:$C$20)-1,""), COLUMN()-5)),"")

2, Եվ հետո, ընտրեք առաջին բանաձևի բջիջը և լրացրեք բռնիչը դեպի աջ բջիջները քաշեք, մինչև դատարկ բջիջը ցուցադրվի, և բոլոր համապատասխան տարրերը արդյունահանվեն, տես նկարի նկարը.

Հուշում.

Եթե ​​վերադարձված ցուցակում կան կրկնօրինակ համապատասխանեցված արժեքներ, կրկնօրինակներն անտեսելու համար օգտագործեք այս բանաձևերը, ապա սեղմեք Մտնել առաջին արդյունքը ստանալու համար. =IFERROR(INDEX($C$2:$C$20,MATCH($F1,$A$2:$A$20,0)),"")

Շարունակեք մուտքագրել այս բանաձևը. =IFERROR(INDEX($C$2:$C$20,MATCH(1,($F1=$A$2:$A$20)*ISNA(MATCH($C$2:$C$20,$F2:F2,0)),0)),"") առաջին արդյունքի կողքին գտնվող բջիջը և այնուհետև սեղմել Ctrl + Shift + Մուտք ստեղները միասին ՝ երկրորդ արդյունքը ստանալու համար, ապա քաշեք այս բանաձևը դեպի աջ բջիջներ ՝ մնացած բոլոր համապատասխան արժեքները ստանալու համար մինչև դատարկ բջիջը ցուցադրվի, տես նկարի նկարը.


Vlookup- ի բոլոր համապատասխան արժեքները, որոնք հիմնված են հորիզոնական երկու կամ ավելի պայմանների վրա.

Vlookup- ին և հորիզոնական ավելի ճշգրիտ արժեքների վրա հիմնված բոլոր համապատասխան արժեքները վերադարձնելու համար ընդհանուր բանաձևն է.

=IFERROR(INDEX(return_range, SMALL(IF(1 = ((--(lookup_value1=lookup_range1)) * (--(lookup_value2 = lookup_range2))), ROW(return_range) - m, ""), COLUMN() - n)),"")
Նշում: m վերադարձի միջակայքում մինուս 1-ի առաջին բջիջի տողի համարն է:
      n առաջին բանաձևի բջիջի մինուս 1 սյունակի համարն է:

1, Կիրառեք հետևյալ բանաձևը դատարկ բջիջի մեջ, որտեղ ցանկանում եք արդյունքը դուրս բերել.

=IFERROR(INDEX($C$2:$C$20, SMALL(IF(1=((--($F1=$A$2:$A$20)) * (--($F2=$B$2:$B$20))), ROW($C$2:$C$20)-1,""), COLUMN()-5)),"")

2, Դրանից հետո ընտրեք բանաձևի բջիջը և լրացրեք բռնիչը դեպի աջ բջիջները քաշեք, մինչև դատարկ բջիջը ցուցադրվի, և հատուկ չափանիշների հիման վրա բոլոր համապատասխան արժեքները վերադարձվեն, տես նկարի նկարը.

ՆշումԼրացուցիչ չափանիշների համար պարզապես անհրաժեշտ է միանալ lookup_value- ին և lookup_range- ին բանաձևի մեջ, ինչպիսիք են. =IFERROR(INDEX(return_range, SMALL(IF(1 = ((--(lookup_value1=lookup_range1)) * (--(lookup_value2 = lookup_range2) * (--(lookup_value3 =lookup_range3)))), ROW(return_range) - m, ""), COLUMN() - n)),"").


Vlookup- ը ուղղահայաց մեկ կամ մի քանի պայմանների վրա հիմնված բոլոր համապատասխան արժեքները

Vlookup- ի բոլոր համապատասխան արժեքները, որոնք հիմնված են ուղղահայաց մեկ պայմանի վրա.

Vlookup- ին և ուղղահայաց մեկ հատուկ արժեքի վրա հիմնված բոլոր համապատասխան արժեքները վերադարձնելու համար ընդհանուր բանաձևն է.

=IFERROR(INDEX(return_range, SMALL(IF(lookup_value = lookup_range, ROW(return_range )- m ,""), ROW() - n )),"")
Նշում: m վերադարձի միջակայքում մինուս 1-ի առաջին բջիջի տողի համարն է:
      n առաջին բանաձևի բջիջի մինուս 1 տողի համարն է:

1, Պատճենեք կամ մուտքագրեք հետևյալ բանաձևը այն բջիջում, որտեղ ցանկանում եք արդյունք ստանալ, ապա սեղմել Ctrl + Shift + Մուտք ստեղները միասին ՝ առաջին համապատասխան արժեքը ստանալու համար, տե՛ս նկարը.

=IFERROR(INDEX($C$2:$C$20, SMALL(IF(E$2=$A$2:$A$20, ROW($C$2:$C$20)-1,""), ROW()-1)),"")

2, Դրանից հետո ընտրեք բանաձևի առաջին բջիջը և լրացնելու բռնիչը ներքև քաշեք դեպի այլ բջիջներ, մինչև դատարկ բջիջը ցուցադրվի, և բոլոր համապատասխան տարրերը ցուցակագրվեն սյունակում, տես նկարի նկարը.

Հուշում.

Վերադարձված համապատասխանող արժեքների կրկնօրինակներն անտեսելու համար օգտագործեք այս բանաձևերը. =IFERROR(INDEX($C$2:$C$20,MATCH(0,COUNTIF($F$1:F1,$C$2:$C$20)+($A$2:$A$20<>$E$2),0)),"")

Այնուհետեւ սեղմեք Ctrl + Shift + Մուտք ստեղները միասին `առաջին համապատասխանեցված արժեքը ստանալու համար, ապա այս բանաձևի բջիջը ներքև քաշեք դեպի այլ բջիջներ, մինչև դատարկ բջիջը ցուցադրվի, և արդյունքը կստանաք, ինչպես ձեզ հարկավոր է


Vlookup- ի բոլոր համապատասխան արժեքները, որոնք հիմնված են ուղղահայաց երկու կամ ավելի պայմանների վրա.

Vlookup- ին և վերադարձնելու բոլոր համապատասխանող արժեքները, որոնք հիմնված են ավելի առանձնահատուկ արժեքների վրա ուղղահայաց, ընդհանուր բանաձևն է.

=IFERROR(INDEX(return_range, SMALL(IF(1=((--(lookup_value1=lookup_range1)) * ( --(lookup_value2=lookup_range2))), ROW(return_range)-m,""), ROW()-n)),"")
Նշում: m վերադարձի միջակայքում մինուս 1-ի առաջին բջիջի տողի համարն է:
      n առաջին բանաձևի բջիջի մինուս 1 տողի համարն է:

1, Ստորև բերված բանաձևը պատճենեք դատարկ բջիջի մեջ և այնուհետև սեղմեք Ctrl + Shift + Մուտք ստեղները միասին `առաջին համապատասխան իրը ստանալու համար:

=IFERROR(INDEX($C$2:$C$20, SMALL(IF(1=((--($E$2=$A$2:$A$20)) * (--($F$2=$B$2:$B$20))), ROW($C$2:$C$20)-1,""), ROW()-1)),"")

2, Դրանից հետո քաշեք բանաձևի բջիջը դեպի այլ բջիջներ, մինչև դատարկ բջիջը ցուցադրվի, տեսեք,

ՆշումԼրացուցիչ չափանիշների համար պարզապես անհրաժեշտ է միանալ lookup_value- ին և lookup_range- ին բանաձևի մեջ, ինչպիսիք են. =IFERROR(INDEX(return_range, SMALL(IF(1 = ((--(lookup_value1=lookup_range1)) * (--(lookup_value2 = lookup_range2) * (--(lookup_value3 =lookup_range3)))), ROW(return_range) - m, ""), ROW() - n)),"").


Vlookup- ը երկու կամ ավելի պայմանների վրա հիմնված բոլոր համապատասխան արժեքները մեկ խցում

Եթե ​​ցանկանում եք Vlookup- ին վերադարձնել և մի քանի համապատասխանեցված արժեքներ վերադարձնել մեկ տարրի `նշված տարանջատիչով, TEXTJOIN- ի նոր գործառույթը կօգնի ձեզ լուծել այս աշխատանքը արագ և հեշտությամբ:

Vlookup- ի բոլոր համապատասխան արժեքները, որոնք հիմնված են մեկ պայմանի մեջ մեկ բջիջում.

Ստորև ներկայացված պարզ բանաձևը կիրառեք դատարկ վանդակի մեջ և այնուհետև սեղմեք Ctrl + Shift + Մուտք ստեղները միասին ՝ արդյունքը ստանալու համար.

=TEXTJOIN(",",TRUE,IF($A$2:$A$20=F1,$C$2:$C$20,""))

Հուշում.

Վերադարձված համապատասխանող արժեքների կրկնօրինակներն անտեսելու համար օգտագործեք այս բանաձևերը. =TEXTJOIN(",", TRUE, IF(IFERROR(MATCH($C$2:$C$20, IF(F1=$A$2:$A$20, $C$2:$C$20, ""), 0),"")=MATCH(ROW($C$2:$C$20), ROW($C$2:$C$20)), $C$2:$C$20, ""))


Vlookup- ը երկու կամ ավելի պայմանների վրա հիմնված բոլոր համապատասխան արժեքները մեկ բջիջի մեջ.

Բազմաթիվ պայմանների հետ գործ ունենալու համար, երբ բոլոր համապատասխանեցված արժեքները մեկ բջիջ վերադառնալիս, կիրառեք ստորև բերված բանաձևը, ապա սեղմեք Ctrl + Shift + Մուտք ստեղները միասին ՝ արդյունքը ստանալու համար.

=TEXTJOIN(",",TRUE,IF(($A$2:$A$20=F1)*($B$2:$B$20=F2),$C$2:$C$20,""))

Նշումներ:

1. TEXTJOIN գործառույթը հասանելի է միայն Excel 2019-ում և Office 365-ում:

2. Եթե օգտագործում եք Excel 2016 և ավելի վաղ տարբերակները, խնդրում ենք օգտագործել ստորև նշված հոդվածների օգտագործողի կողմից սահմանված գործառույթը.


4. Vlookup ՝ համապատասխան բջիջի ամբողջ կամ ամբողջ շարքը վերադարձնելու համար

Այս բաժնում ես կխոսեմ այն ​​մասին, թե ինչպես վերականգնել համապատասխան արժեքի ամբողջ շարքը ՝ օգտագործելով Vlookup գործառույթը:

1, Ստորև բերված բանաձևը պատճենեք կամ մուտքագրեք դատարկ բջիջ, որտեղ ցանկանում եք արդյունքը դուրս բերել, և սեղմել Մտնել առաջին արժեքը ստանալու բանալին:

=VLOOKUP($F$2,$A$1:$D$12,COLUMN(A1),FALSE)

2, Դրանից հետո քաշեք բանաձևի բջիջը աջ կողմում, մինչև ամբողջ շարքի տվյալները ցուցադրվեն, տես նկարի նկարը.

ՆշումՎերոհիշյալ բանաձևում F2 որոնման արժեքն է, որի հիման վրա ցանկանում եք վերադարձնել ամբողջ տողը, A1: D12 տվյալների տիրույթն է, որը ցանկանում եք օգտագործել, A1 նշում է սյունակի առաջին համարը ձեր տվյալների տիրույթում:

Հուշում.

Եթե ​​համապատասխան տողերի հիման վրա հայտնաբերվել են բազմաթիվ տողեր, համապատասխան բոլոր տողերը վերադարձնելու համար կիրառեք այս բանաձևը. =IFERROR(INDEX(A:A,SMALL(IF(ISNUMBER(SEARCH($F$2,$A$2:$A$12)),ROW($A$2:$A$12),""),ROW()-1)),""), ապա սեղմեք Ctrl + Shift + Մուտք ստեղները միասին ՝ առաջին արդյունքը ստանալու համար, այնուհետև լրացնելու բռնիչը քաշեք դեպի բջիջները, տես նկարի նկարը.

Եվ այնուհետև բջիջների միջով ներքև քաշեք լրացման բռնիչը `բոլոր համապատասխան տողերը ստանալու համար, ինչպես ցույց է տրված նկարում նշված է


5. Excel- ում կատարեք մի քանի Vlookup գործառույթ (տեղադրված Vlookup)

Երբեմն գուցե ցանկանաք արժեքներ որոնել բազմաթիվ աղյուսակներում, եթե աղյուսակներից որևէ մեկը պարունակում է որոնման տվյալ արժեքը, ինչպես ցույց է տրված ստորև նշված էկրանի նկարը, այս դեպքում դուք կարող եք համատեղել մեկ կամ ավելի Vlookup գործառույթներ IFERROR գործառույթի հետ միասին ՝ բազմակի որոնում կատարելու համար:

Ներդրված Vlookup գործառույթի ընդհանուր բանաձևն է.

=IFERROR(VLOOKUP(lookup_value,table1,col,0),IFERROR(VLOOKUP(lookup_value,table2,col,0),VLOOKUP(lookup_value,table3,col,0)))

Նշում:

  • lookup_valueարժեքը, որը դուք փնտրում եք;
  • Table1- ը, Table2- ը, Table3- ը, .... աղյուսակները, որոնցում գոյություն ունեն որոնման արժեքը և վերադարձի արժեքը.
  • հետաղյուսակի սյունակի համարը, որից ուզում եք վերադարձնել համապատասխան արժեքը:
  • 0Սա օգտագործվում է ճշգրիտ համընկնման համար:

1, Խնդրում ենք կիրառել հետևյալ բանաձևը դատարկ բջիջում, որտեղ ցանկանում եք արդյունքը դնել.

=IFERROR(VLOOKUP(J3,$A$3:$B$7,2,0),IFERROR(VLOOKUP(J3,$D$3:$E$7,2,0),VLOOKUP(J3,$G$3:$H$7,2,0)))

2, Դրանից հետո, լրացրեք բռնիչը ներքև քաշեք դեպի այն բջիջները, որոնք ցանկանում եք կիրառել այս բանաձևը, և ​​բոլոր համապատասխան արժեքները վերադարձվել են, ինչպես ցույց է տրված ստորև նշված նկարում.

Նշումներ:

  • 1. Վերոնշյալ բանաձևում J3 այն արժեքն է, որը դուք փնտրում եք. A3: B7, D3: E7, G3: H7 աղյուսակի տիրույթներն են, որոնցում գոյություն ունի որոնման արժեքը և վերադարձի արժեքը. Համարը 2 միջակայքում սյունակի համարն է `համապատասխանող արժեքը վերադարձնելու համար:
  • 2. Եթե որոնման արժեքը հնարավոր չէ գտնել, ապա սխալի արժեք է ցուցադրվում `սխալը ընթերցելի տեքստով փոխարինելու համար օգտագործեք այս բանաձևը. =IFERROR(VLOOKUP(J3,$A$3:$B$7,2,0),IFERROR(VLOOKUP(J3,$D$3:$E$7,2,0),IFERROR(VLOOKUP(J3,$G$3:$H$7,2,0),"can't find")))

6. Vlookup ՝ ստուգելու համար, արդյոք արժեքը գոյություն ունի ՝ հիմնվելով մեկ այլ սյունակի ցուցակի տվյալների վրա

Vlookup գործառույթը կարող է նաև օգնել ձեզ ստուգել, ​​թե արդյոք արժեքները գոյություն ունեն մեկ այլ ցուցակի հիման վրա, օրինակ, եթե ուզում եք C սյունակում փնտրել անունները և պարզապես վերադարձնել Այո կամ Ոչ, եթե անունը հայտնաբերված է, թե ոչ A սյունակում, ցույց է տրված:

1, Խնդրում ենք կիրառել հետևյալ բանաձևը դատարկ բջիջում.

=IF(ISNA(VLOOKUP(C2,$A$2:$A$10,1,FALSE)), "No", "Yes")

2, Դրանից հետո քաշեք լրացման բռնակը ներքև դեպի այն բջիջները, որոնք ցանկանում եք լրացնել այս բանաձևը, և ​​արդյունքը կստանաք ըստ անհրաժեշտության: Տեսեք,

ՆշումՎերոհիշյալ բանաձևում C2 որոնման արժեքն է, որը ցանկանում եք ստուգել. A2: A10 ընդգրկույթի ցանկն է, որտեղից կգտնվեն որոնման արժեքները. համարը 1 սյունակի համարն է, որտեղից ուզում եք արժեք վերցնել ձեր տիրույթում:


7. Vlookup և գումարեք տողերի կամ սյունակների բոլոր համապատասխան արժեքները

Եթե ​​աշխատում եք թվային տվյալների հետ, երբեմն, աղյուսակից համապատասխան արժեքներ արդյունահանելիս, գուցե նաև անհրաժեշտ լինի թվերը մի քանի սյունակում կամ շարքում ամփոփել: Այս բաժնում կներկայացվեն մի քանի բանաձևեր, Excel- ում այս աշխատանքը ավարտելու համար:

Vlookup և գումարեք բոլոր համապատասխան արժեքները անընդմեջ կամ բազմաթիվ տողերում

Ենթադրենք, դուք ունեք ապրանքների ցուցակ մի քանի ամսվա ընթացքում վաճառքով, ինչպես ցույց է տրված նկարներից ներքևում, այժմ անհրաժեշտ է ամփոփել բոլոր պատվերների բոլոր պատվերները ՝ հիմնվելով տվյալ ապրանքների վրա:

Vlookup և ամփոփեք անընդմեջ առաջին համապատասխան արժեքները.

1, Խնդրում ենք պատճենել կամ մուտքագրել հետևյալ բանաձևը դատարկ բջիջում, ապա սեղմել Ctrl + Shift + Մուտք ստեղները միասին ՝ առաջին արդյունքը ստանալու համար:

=SUM(VLOOKUP(H2, $A$2:$F$9, {2,3,4,5,6}, FALSE))

2, Դրանից հետո քաշեք լրացման բռնակը ներքև ՝ այս բանաձևը պատճենելու համար ձեզ անհրաժեշտ այլ բջիջներում, և առաջին համապատասխան արժեքի շարքի բոլոր արժեքներն ամփոփված են միասին, տես նկարի նկարը.

ՆշումՎերոհիշյալ բանաձևում. H2 այն բջիջն է, որը պարունակում է ձեր որոնած արժեքը. A2: F9 տվյալների տիրույթն է (առանց սյունակի վերնագրերի), որոնք ներառում են որոնման արժեքը և համապատասխանեցված արժեքները. Համարը 2,3,4,5,6 {} միջակայքի ընդհանուր գումարը հաշվարկելու համար օգտագործվող սյունակների համարներ են:


Vlookup և գումարեք բոլոր համապատասխան արժեքները բազմակի շարքերում.

Վերոնշյալ բանաձևը կարող է ընդամենը անընդմեջ գումարներ գումարել առաջին համապատասխանեցված արժեքի համար: Եթե ​​ցանկանում եք ամփոփել բոլոր համընկնումները մի շարք շարքերում, օգտագործեք հետևյալ բանաձևը, ապա լրացրեք բռնիչը ներքև քաշեք այն բջիջները, որոնք ցանկանում եք կիրառել այս բանաձևը, և ​​կստանաք ձեր համար անհրաժեշտ արդյունքը, տես նկարի նկարը.

=SUMPRODUCT(($A$2:$A$9=H2)*$B$2:$F$9)

ՆշումՎերոհիշյալ բանաձևում. H2 որոնման արժեքն է, որը դուք փնտրում եք. A2: A9 տողի վերնագրերն են, որոնք պարունակում են որոնման արժեքը. B2: F9 թվային արժեքների տվյալների տիրույթը, որը ցանկանում եք ամփոփել:


Vlookup և ամփոփեք բոլոր համապատասխան արժեքները սյունակում կամ բազմակի սյունակում

Vlookup և ամփոփեք առաջին համապատասխանեցված արժեքները սյունակում.

Եթե ​​ցանկանում եք ամփոփել որոշակի ամիսների ընդհանուր արժեքը, ինչպես ցույց է տրված ստորև նշված նկարում

Կիրառեք ստորև բերված բանաձևը դատարկ բջիջի մեջ և այնուհետև քաշեք լրացման բռնիչը ներքև ՝ այս բանաձևը այլ բջիջներին պատճենելու համար, այժմ սյունակում նշված հատուկ ամսվա հիման վրա առաջին համապատասխանեցված արժեքներն ամփոփվել են միասին, տեսեք,

=SUM(INDEX($B$2:$F$9,0,MATCH(H2,$B$1:$F$1,0)))

ՆշումՎերոհիշյալ բանաձևում. H2 որոնման արժեքն է, որը դուք փնտրում եք. B1: F1 սյունակի վերնագրերն են, որոնք պարունակում են որոնման արժեքը. B2: F9 թվային արժեքների տվյալների տիրույթը, որը ցանկանում եք ամփոփել:


Vlookup և գումարեք բոլոր համապատասխան արժեքները բազմաթիվ սյունակներում.

Vlookup- ին և բազմաթիվ սյունակներում բոլոր համապատասխան արժեքները գումարելու համար պետք է օգտագործեք հետևյալ բանաձևը.

=SUMPRODUCT($B$2:$F$9*(($B$1:$F$1)=H2))

ՆշումՎերոհիշյալ բանաձևում. H2 որոնման արժեքն է, որը դուք փնտրում եք. B1: F1 սյունակի վերնագրերն են, որոնք պարունակում են որոնման արժեքը. B2: F9 թվային արժեքների տվյալների տիրույթը, որը ցանկանում եք ամփոփել:


Vlookup և ամփոփեք առաջին հատկանիշով կամ բոլոր համապատասխան արժեքները հզոր հատկանիշով

Գուցե վերոհիշյալ բանաձևերը դժվար է հիշել ձեզ համար, այս դեպքում ես խորհուրդ կտամ հարմար հատկություն. Փնտրել և գումարել of Excel- ի համար նախատեսված գործիքներ, այս ֆունկցիայի միջոցով կարող եք արդյունքը հնարավորինս հեշտ ստանալ:    Կտտացրեք Kutools- ի Excel- ի համար ներբեռնելու համար:


Vlookup և գումարեք բոլոր համապատասխան արժեքները ինչպես շարքերում, այնպես էլ սյունակներում

Եթե ​​ցանկանում եք ամփոփել արժեքները, երբ դուք պետք է համընկնեք և՛ սյունակին, և՛ տողին, օրինակ ՝ մարտ ամսվա սվիտերի արտադրանքի ընդհանուր արժեքը ստանալու համար, ինչպես ցույց է տրված նկարում:

Խնդրում ենք կիրառել հետևյալ բանաձևը բջիջի մեջ և այնուհետև սեղմել Մտնել ստեղն արդյունք ստանալու համար, տես նկարի նկարը.

=SUMPRODUCT(($B$2:$F$9)*($B$1:$F$1=I2)*($A$2:$A$9=H2))

ՆշումՎերոհիշյալ բանաձևում. B2: F9 այն թվային արժեքների տվյալների տիրույթն է, որը ցանկանում եք ամփոփել. B1: F1 is սյունակի վերնագրերը պարունակում են որոնման արժեք, որի հիման վրա ցանկանում եք ամփոփել. I2 որոնման արժեքն է ձեր որոնած սյունակի վերնագրերում. A2: A9 տողի վերնագրերը պարունակում են որոնման արժեք, որի հիման վրա ցանկանում եք ամփոփել. H2 ձեր որոնած շարքի վերնագրերի մեջ որոնման արժեքն է:


8. Vlookup ՝ երկու աղյուսակ միաձուլելու համար, որոնք հիմնված են մեկ կամ ավելի հիմնական սյունակների վրա

Ձեր ամենօրյա աշխատանքում, տվյալները վերլուծելիս, կարող է անհրաժեշտ լինել հավաքել բոլոր անհրաժեշտ տեղեկությունները մեկ աղյուսակում, որը հիմնված է մեկ կամ մի քանի առանցքային սյունակների վրա: Այս աշխատանքը լուծելու համար Vlookup գործառույթը կարող է նաև ձեզ լավություն բերել:

Vlookup ՝ մեկ առանցքային սյունակի հիման վրա երկու աղյուսակ միավորելու համար

Օրինակ, դուք ունեք երկու աղյուսակ, առաջին աղյուսակը պարունակում է ապրանքների և անունների տվյալներ, իսկ երկրորդ աղյուսակը պարունակում է ապրանքներ և պատվերներ, այժմ դուք ցանկանում եք համատեղել այս երկու աղյուսակները `ընդհանուր արտադրանքի սյունակը համապատասխանեցնելով մեկ աղյուսակի:

Բանաձև 1. Օգտագործելով VLOOKUP գործառույթ

Բանալին սյունակի հիման վրա երկու աղյուսակները միաձուլելու համար խնդրում ենք կիրառել հետևյալ բանաձևը դատարկ բջիջի մեջ, որտեղ ցանկանում եք արդյունքը ստանալ, ապա լրացնելով բռնիչը ներքև քաշել դեպի այն բջիջները, որոնք ցանկանում եք կիրառել այս բանաձևը, դուք ստացեք միաձուլված աղյուսակ ՝ պատվերի սյունակին, որը միանում է առանցքային սյունակի տվյալների վրա հիմնված առաջին աղյուսակի տվյալների:

=VLOOKUP($A2,$E$2:$F$8,2,FALSE)

ՆշումՎերոհիշյալ բանաձևում A2 այն արժեքն է, որը դուք փնտրում եք, E2: F8 որոնման աղյուսակն է, համարը 2 աղյուսակի սյունակի համարն է, որից պետք է վերցնել արժեքը:

Բանաձև 2. Օգտագործելով INDEX և MATCH գործառույթները

Եթե ​​աջ կողմում գտնվող ձեր ընդհանուր տվյալները և երկրորդ աղյուսակում գտնվող ձախ սյունակում վերադարձված տվյալները, պատվերի սյունը միացնելու համար, Vlookup գործառույթն ի վիճակի չէ կատարել աշխատանքը: Աջից ձախ հայացք գցելու համար Vlookup գործառույթը փոխարինելու համար կարող եք օգտագործել INDEX և MATCH գործառույթները:

Խնդրում ենք պատճենել կամ մուտքագրել ներքևի բանաձևը դատարկ բջիջ, այնուհետև պատճենել բանաձևը սյունակում, և պատվերի սյունը միացել է առաջին աղյուսակին, տես նկարի նկարը.

=INDEX($E$2:$E$8, MATCH($A2, $F$2:$F$8, 0))

ՆշումՎերոհիշյալ բանաձևում A2 որոնման արժեքն է, որը դուք փնտրում եք, E2: E8 տվյալների շարք է, որը ցանկանում եք վերադարձնել, F2: F8 որոնման տիրույթ է, որը պարունակում է որոնման արժեք:


Vlookup ՝ մի քանի հիմնական սյունակների վրա հիմնված երկու աղյուսակներ միացնելու համար

Եթե ​​երկու աղյուսակները, որոնց ուզում եք միանալ, ունեն բազմաթիվ առանցքային սյունակներ, այս ընդհանուր սյունակների հիման վրա աղյուսակները միացնելու համար INDEX և MATCH գործառույթները կարող են օգնել ձեզ:

Բազմաթիվ առանցքային սյունների վրա հիմնված երկու աղյուսակների միաձուլման ընդհանուր բանաձևն է.

=INDEX(lookup_table, MATCH(1, (lookup_value1=lookup_range1) * (lookup_value2=lookup_range2), 0), return_column_number)

1, Ստորև բերված բանաձևը կիրառեք դատարկ վանդակի մեջ, որտեղ ցանկանում եք տեղադրել արդյունքը, և այնուհետև սեղմել Ctrl + Shift + Մուտք ստեղները միասին ՝ առաջին համապատասխան արժեքը ստանալու համար, տե՛ս նկարը.

=INDEX($E$2:$G$9, MATCH(1, ($A2=$E$2:$E$9) * ($B2=$F$2:$F$9), 0), 3)

ՆշումՎերոհիշյալ բանաձևում այն, ինչ ներկայացնում են բջիջների հղումները, ինչպես ցույց է տրված ստորև նշված նկարը.

2. Ապա, ընտրեք առաջին բանաձևի բջիջը և քաշեք լրացման բռնակը, որպեսզի այս բանաձևը պատճենեք այլ բջիջներին, որքան ձեզ հարկավոր է.

TipsExcel- ի 2016 և ավելի ուշ տարբերակներում կարող եք նաև օգտագործել այն Power հարցում առանձնահատկություն `երկու կամ ավելի աղյուսակներ միաձուլելու մեկում` հիմնված հիմնական սյունակների վրա: Խնդրում ենք սեղմել ՝ մանրամասները քայլ առ քայլ իմանալու համար.

9. Vlookup- ի համապատասխանող արժեքները բազմաթիվ աշխատանքային թերթերում

Երբևէ փորձե՞լ եք Vlookup- ի արժեքները բազմակի աշխատանքային թերթի վրա: Ենթադրելով, որ ես ունեմ հետևյալ երեք աշխատանքային թերթերը `տվյալների տիրույթով, և այժմ ես ուզում եմ համապատասխան արժեքների մի մասը ստանալ` հիմնվելով այս երեք աշխատանքային թերթերի չափանիշների վրա, որպեսզի արդյունքը ստանամ, ինչպես ցույց է տրված նկարում: Այս դեպքում Vlookup- ի արժեքները բազմակի աշխատանքային թերթերում ձեռնարկը կարող է քայլ առ քայլ լավություն տալ ձեզ:


VLOOKUP- ի համապատասխան արժեքները պահպանում են բջիջների ձևաչափումը

1. Vlookup ՝ բջջի ձևաչափումը (բջջի գույնը, տառատեսակի գույնը) ՝ որոնման արժեքի հետ միասին

Ինչպես բոլորս գիտենք, Vlookup- ի նորմալ գործառույթը կարող է մեզ օգնել միայն վերադարձնել համապատասխան արժեքը տվյալների մեկ այլ տիրույթից, բայց երբեմն գուցե ցանկանաք, որ բջիջի ձևաչափման հետ մեկտեղ վերադարձնեք համապատասխան արժեքը, ինչպիսիք են լրացման գույնը, տառատեսակի գույնը, տառատեսակի ոճը ինչպես ցույց է տրված նկարում Այս բաժնում կխոսվի այն մասին, թե ինչպես կարելի է Excel- ում վերադարձված արժեքով ստանալ բջիջի ձևաչափումը:

Խնդրում ենք արեք հետևյալ քայլերը ՝ բջջի ձևաչափմանը զուգահեռ որոնելու և վերադարձնելու դրա համապատասխան արժեքը.

1, Աշխատաթերթում պարունակում են տվյալներ, որոնք ցանկանում եք Vlookup- ին, աջով կտտացրեք թերթիկի ներդիրին և ընտրեք Դիտել կոդը համատեքստային ընտրացանկից: Տեսեք,

2, Բացվածքում Microsoft Visual Basic հավելվածների համար պատուհան, խնդրում ենք պատճենել ներքևում գտնվող VBA կոդը օրենսգրքի պատուհանում:

VBA կոդ 1. Vlookup բջջային ձևաչափում ստանալու համար `որոնման արժեքի հետ միասին

Sub Worksheet_Change(ByVal Target As Range)
'Updateby Extendoffice
    Dim I As Long
    Dim xKeys As Long
    Dim xDicStr As String
    On Error Resume Next
    Application.ScreenUpdating = False
    xKeys = UBound(xDic.Keys)
    If xKeys >= 0 Then
        For I = 0 To UBound(xDic.Keys)
            xDicStr = xDic.Items(I)
            If xDicStr <> "" Then
                Range(xDic.Keys(I)).Interior.Color = _
                Range(xDic.Items(I)).Interior.Color
                Range(xDic.Keys(I)).Font.FontStyle = _
                Range(xDic.Items(I)).Font.FontStyle
                Range(xDic.Keys(I)).Font.Size = _
                Range(xDic.Items(I)).Font.Size
                Range(xDic.Keys(I)).Font.Color = _
                Range(xDic.Items(I)).Font.Color
                Range(xDic.Keys(I)).Font.Name = _
                Range(xDic.Items(I)).Font.Name
                Range(xDic.Keys(I)).Font.Underline = _
                Range(xDic.Items(I)).Font.Underline
            Else
                Range(xDic.Keys(I)).Interior.Color = xlNone
            End If
        Next
        Set xDic = Nothing
    End If
    Application.ScreenUpdating = True
End Sub

3, Դեռևս Microsoft Visual Basic հավելվածների համար պատուհանը, սեղմեք Տեղադրել > Մոդուլներ, ապա պատճենեք ներքևի VBA կոդը 2 Մոդուլի պատուհանում:

VBA կոդ 2. Vlookup բջջային ձևաչափում ստանալու համար `որոնման արժեքի հետ միասին

Public xDic As New Dictionary
Function LookupKeepFormat (ByRef FndValue, ByRef LookupRng As Range, ByRef xCol As Long)
    Dim xFindCell As Range
    On Error Resume Next
    Set xFindCell = LookupRng.Find(FndValue, , xlValues, xlWhole)
    If xFindCell Is Nothing Then
        LookupKeepFormat = ""
        xDic.Add Application.Caller.Address, ""
    Else
        LookupKeepFormat = xFindCell.Offset(0, xCol - 1).Value
        xDic.Add Application.Caller.Address, xFindCell.Offset(0, xCol - 1).Address
    End If
End Function

4, Վերոնշյալ կոդերը տեղադրելուց հետո կտտացրեք Գործիքներ > Սայլակ է Microsoft Visual Basic հավելվածների համար պատուհան Ապա ստուգեք Microsoft Script Runtime վանդակում Հղումներ - VBAP նախագիծ երկխոսության տուփ: Տեսեք սքրինշոթեր.

5, Դրանից հետո կտտացրեք OK երկխոսության տուփը փակելու համար, և այնուհետև պահպանել և փակել կոդերի պատուհանը, այժմ վերադարձեք աշխատանքային թերթը և այնուհետև կիրառեք այս բանաձևը. =LookupKeepFormat(E2,$A$1:$C$10,3) դատարկ բջիջի մեջ, որտեղ ցանկանում եք արդյունքը դուրս բերել, ապա սեղմել Enter ստեղնը: Տեսեք,

ՆշումՎերոհիշյալ բանաձևում E2 այն արժեքն է, որը դուք կփնտրեք, A1: C10 աղյուսակի տիրույթն է և համարը 3 այն աղյուսակի սյունակի համարն է, որը ցանկանում եք վերադարձված համապատասխան արժեքը:

6, Դրանից հետո ընտրեք արդյունքի առաջին բջիջը և ներքև քաշեք լրացման բռնիչը ՝ բոլոր արդյունքները դրանց ձևաչափման հետ միասին ստանալու համար: Տեսեք նկարը


2. Ամսաթվի ձևաչափը պահեք Vlookup- ի վերադարձված արժեքից

Սովորաբար, Vloook ֆունկցիան օգտագործելիս `համապատասխան ամսաթիվը ձևաչափի արժեքը որոնելու և վերադարձնելու համար, համարի որոշ ձևաչափ կցուցադրվի, ինչպես ցույց է տրված նկարում: Ամսաթվի ձևաչափը վերադարձված արդյունքից պահելու համար հարկավոր է TEXT գործառույթը կցել Vlookup գործառույթին:

Խնդրում ենք կիրառել ստորև բերված բանաձևը դատարկ բջիջի մեջ, ապա քաշել լրացման բռնիչը, որպեսզի այս բանաձեւը պատճենվի այլ բջիջների վրա, և բոլոր համապատասխան ամսաթվերը վերադարձվել են, ինչպես ցույց է տրված ստորև նշված նկարը

=TEXT(VLOOKUP(E2,$A$2:$C$9,3,FALSE),"mm/dd/yyyy")

ՆշումՎերոհիշյալ բանաձևում E2 տեսքի արժեքն է, A2: C9 որոնման տիրույթն է, համարը 3 սյունակի համարն է, որը ցանկանում եք վերադարձված արժեքը, mm/dd/yyy ամսաթվի ձևաչափն է, որը ցանկանում եք պահել:


3. Vlookup և վերադարձնել համապատասխան արժեքը բջջային մեկնաբանության հետ

Երբևէ փորձե՞լ եք Vlookup- ին վերադարձնել ոչ միայն համապատասխան բջջային տվյալները, այլ նաև բջջային մեկնաբանությունը, ինչպես նաև Excel- ում, ինչպես ցույց է տրված հետևյալ նկարը: Այս խնդիրը լուծելու համար օգտագործողի կողմից սահմանված ստորև նշված գործառույթը կարող է ձեզ լավություն բերել:

1, Պահեք պահեք ALT + F11 բացել ստեղները Microsoft Visual Basic հավելվածների համար պատուհան.

2: Սեղմեք Տեղադրել > Մոդուլներ, ապա պատճենեք և տեղադրեք հետևյալ կոդը Մոդուլի պատուհանում:

VBA կոդ. Vlookup և վերադարձի համապատասխան արժեքը բջջային մեկնաբանության հետ.

Function VlookupComment(LookVal As Variant, FTable As Range, FColumn As Long, FType As Long) As Variant
'Updateby Extendoffice
    Application.Volatile
    Dim xRet As Variant 'could be an error
    Dim xCell As Range
    xRet = Application.Match(LookVal, FTable.Columns(1), FType)
    If IsError(xRet) Then
        VlookupComment = "Not Found"
    Else
        Set xCell = FTable.Columns(FColumn).Cells(1)(xRet)
        VlookupComment = xCell.Value
        With Application.Caller
            If Not .Comment Is Nothing Then
                .Comment.Delete
            End If
            If Not xCell.Comment Is Nothing Then
                .AddComment xCell.Comment.Text
            End If
        End With
    End If
End Function

3, Դրանից հետո պահեք և փակեք ծածկագրի պատուհանը, մուտքագրեք այս բանաձևը. =vlookupcomment(D2,$A$2:$B$9,2,FALSE) արդյունքը գտնելու համար դատարկ վանդակի մեջ և այնուհետև քաշեք լրացման բռնիչը ՝ այս բանաձևը այլ բջիջներին պատճենելու համար, այժմ համապատասխանեցված արժեքները, ինչպես նաև մեկնաբանությունները միանգամից վերադարձվում են, տեսեք,

ՆշումՎերոհիշյալ բանաձևում D2 որոնման արժեքն է, որը ցանկանում եք վերադարձնել դրա համապատասխան արժեքը, A2: B9 տվյալների աղյուսակն է, որը ցանկանում եք օգտագործել, համարը 2 սյունակի համարն է, որը պարունակում է համապատասխան արժեք, որը ցանկանում եք վերադարձնել:


4. Alբաղվեք Vlookup- ի տեքստի և իրական թվերի հետ

Օրինակ, ես ունեմ տվյալների մի շարք, սկզբնական աղյուսակում նույնականացման համարը համարի ձևաչափ է, որոնման վանդակում, որը պահվում է որպես տեքստ, նորմալ Vlookup գործառույթը կիրառելիս # N / A սխալի արդյունք է ցուցադրվում, ինչպես ցույց է տրված ստորև նշված նկարում ցույց է տրված: Այս դեպքում ինչպե՞ս կարող եք ճիշտ տեղեկատվություն ստանալ, եթե աղյուսակում որոնման համարը և սկզբնական համարը ունեն տվյալների տարբեր ձևաչափ:

Vlookup գործառույթում տեքստի և իրական թվերի հետ գործ ունենալու համար խնդրում ենք կիրառել հետևյալ բանաձևը դատարկ բջիջում, ապա քաշել լրացման բռնիչը ներքև ՝ այս բանաձևը պատճենելու համար, և դուք կստանաք ճիշտ արդյունքներ, ինչպես ցույց է տրված ստորև նշված նկարում.

=IFERROR(VLOOKUP(VALUE(D2),$A$2:$B$8,2,0),VLOOKUP(TEXT(D2,0),$A$2:$B$8,2,0))

Նշումներ:

  • 1. Վերոնշյալ բանաձևում D2 որոնման արժեքն է, որը ցանկանում եք վերադարձնել դրա համապատասխան արժեքը, A2: B8 տվյալների աղյուսակն է, որը ցանկանում եք օգտագործել, համարը 2 սյունակի համարն է, որը պարունակում է համապատասխան արժեք, որը ցանկանում եք վերադարձնել:
  • 2. Այս բանաձևը լավ է աշխատում նաև, եթե վստահ չեք, թե որտեղ ունեք թվեր և որտեղ ունեք տեքստ:

Ներբեռնեք VLOOKUP ֆայլերի նմուշը

Vlookup_basic_examples.xlsx

Advanced_Vlookup_examples.xlsx

Vlookup_keep_cell_formatting.zip



  • Super Formula Bar (հեշտությամբ խմբագրեք տեքստի և բանաձևի բազմաթիվ տողեր); Ընթերցանության դասավորությունը (հեշտությամբ կարդալ և խմբագրել մեծ թվով բջիջներ); Տեղադրել ֆիլտրացված տիրույթում...
  • Միաձուլել բջիջները / տողերը / սյունակները և տվյալների պահում; Պառակտված բջիջների պարունակությունը; Միավորել կրկնօրինակ տողերն ու գումարը / միջինը... Կանխել կրկնօրինակ բջիջները; Համեմատեք միջակայքերը...
  • Ընտրեք Կրկնօրինակ կամ Եզակի Շարքեր; Ընտրեք դատարկ շարքեր (բոլոր բջիջները դատարկ են); Super Find և Fuzzy Find շատ աշխատանքային գրքույկներում; Պատահական ընտրություն ...
  • Actշգրիտ պատճեն Բազմաթիվ բջիջներ ՝ առանց բանաձևի հղումը փոխելու; Ավտոմատ ստեղծեք հղումներ դեպի մի քանի թերթեր; Տեղադրեք փամփուշտներ, Տուփեր և ավելին ...
  • Սիրված և արագ ներդիր բանաձևեր, Ընդգրկույթներ, գծապատկերներ և նկարներ; Ryածկագրել բջիջները գաղտնաբառով; Ստեղծեք փոստային ցուցակ և նամակներ ուղարկել ...
  • Քաղվածք տեքստ, Տեքստ ավելացնել, հեռացնել ըստ դիրքի, Հեռացնել տարածությունը; Ստեղծել և տպել էջային ենթագոտիներ; Փոխարկել բջիջների բովանդակության և մեկնաբանությունների միջև...
  • Սուպեր զտիչ (պահպանել և կիրառել ֆիլտրի սխեմաները այլ թերթերի վրա); Ընդլայնված տեսակավորում ըստ ամիս / շաբաթ / օր, հաճախականություն և ավելին; Հատուկ զտիչ համարձակ, շեղատառով ...
  • Միավորել աշխատանքային տետրերը և աշխատանքային թերթերը; Միավորել աղյուսակները ՝ հիմնված հիմնական սյունակների վրա; Տվյալները բաժանեք մի քանի թերթերի; Խմբաքանակի փոխակերպում xls, xlsx և PDF...
  • Առանցք սեղանի խմբավորում ըստ շաբաթվա համարը, շաբաթվա օրը և ավելին ... Showույց տալ ապակողպված, կողպված բջիջները տարբեր գույներով; Նշեք այն բջիջները, որոնք ունեն բանաձև / անուն...
kte էջանիշը 201905
  • Միացնել ներդիրներով խմբագրումը և ընթերցումը Word, Excel, PowerPoint- ով, Հրատարակիչ, Access, Visio և Project:
  • Բացեք և ստեղծեք բազմաթիվ փաստաթղթեր նույն պատուհանի նոր ներդիրներում, այլ ոչ թե նոր պատուհաններում:
  • Բարձրացնում է ձեր արտադրողականությունը 50%-ով և նվազեցնում մկնիկի հարյուրավոր կտտոցները ձեզ համար ամեն օր:
officetab ներքևում
Say something here...
symbols left.
You are guest
or post as a guest, but your post won't be published automatically.
Loading comment... The comment will be refreshed after 00:00.

Be the first to comment.