Ինչպե՞ս գործարկել բազմաթիվ մակրոներ Excel- ում աջ կտտացնելու ցանկից:

Եթե ​​ձեր աշխատանքային գրքում կան բազմաթիվ vba մակրոներ, ապա պետք է բացեք VBA պատուհանը, ապա ընտրեք մակրոը, երբ անհրաժեշտ է գործարկել կոդը: Այս հոդվածում ես կցանկանայի խոսել այն մասին, թե ինչպես գործարկել մակրոները աջ սեղմման ընտրացանկից ՝ ձեր աշխատանքն ավելի արդյունավետ դարձնելու համար, ինչպես ցույց է տրված ձախ էկրանի նկարը:

Գործարկեք բազմաթիվ մակրոներ աջ սեղմման ցանկից ՝ VBA կոդերով

Գործարկեք բազմաթիվ մակրոներ աջ սեղմման ցանկից ՝ VBA կոդերով

Աջ կտտոցի ընտրացանկից աշխատանքային գրքում մակրո կոդերը գործարկելու համար հետևյալ քայլերը կարող են օգնել ձեզ, խնդրում ենք արեք հետևյալը.

1, Անցք դեպի Alt + F11 բացել ստեղները Microsoft Visual Basic հավելվածների համար պատուհան.

2, Հետո կրկնակի կտտացրեք Այս գործառույթը ձախում Նախագիծ պատուհանը, ապա պատճենեք և կպցրեք ստորև նշված VBA կոդը դատարկ մոդուլի մեջ:

Private Sub Workbook_Open()
Run "LoadMacro"
End Sub
Private Sub Workbook_Activate()
Run "LoadMacro"
End Sub
Private Sub Workbook_Deactivate()
Run "ClearMacro"
End Sub
Private Sub Workbook_BeforeClose(Cancel As Boolean)
Run "ClearMacro"
ThisWorkbook.Save
End Sub

3, Դեռևս Microsoft Visual Basic հավելվածների համար պատուհանը, սեղմեք Տեղադրել > Մոդուլներ, և տեղադրեք հետևյալ կոդը այս մոդուլի մեջ:

Private Sub LoadMacro()
Dim xArrMenu As Variant
Dim xStrLine, xSreBtnName As String
Dim xObjCBCF, xObjCntrAll As CommandBarControl
Dim xObjCBCs As CommandBars
Dim xObjCBBtn As CommandBarButton
Dim xIntLine, xFNum As Integer
Dim xObjComponent As Object
Run "ClearMacro"
Set xObjCBCF = Application.CommandBars("Cell").Controls.Add(msoControlPopup, before:=1)
xObjCBCF.Caption = " Run Macro "
xObjCBCF.BeginGroup = False
For Each xObjComponent In ActiveWorkbook.VBProject.VBComponents
    If xObjComponent.Type = 1 Then
        For xIntLine = 1 To xObjComponent.CodeModule.CountOfLines
        xStrLine = xObjComponent.CodeModule.Lines(xIntLine, 1)
        xStrLine = Trim(xStrLine)
            If (InStr(xStrLine, "()") > 0) And (Left(xStrLine, 11) = "Private Sub" Or Left(xStrLine, 3) = "Sub") Then
            xSreBtnName = ""
            If "Private Sub" = Left(xStrLine, 11) Then
                xSreBtnName = Trim(Mid(xStrLine, 12, InStr(xStrLine, "()") - 12))
            ElseIf "Sub" = Left(xStrLine, 3) Then
               xSreBtnName = Trim(Mid(xStrLine, 4, InStr(xStrLine, "()") - 4))
            End If
            If xSreBtnName <> "" And xSreBtnName <> "RightClickReset" And xSreBtnName <> "LoadMacro" And xSreBtnName <> "ActionMacro" Then
                Set xObjCBBtn = xObjCBCF.Controls.Add
                With xObjCBBtn
                    .FaceId = 186
                    .Style = msoButtonIconAndCaption
                    .Caption = xSreBtnName
                    .OnAction = "ActionMacro"
                End With
            End If
            End If
        Next xIntLine
    End If
Next xObjComponent
End Sub
Private Sub ClearMacro()
On Error Resume Next
CommandBars("Cell").Controls(" Run Macro ").Delete
Err.Clear
CommandBars("Cell").Reset
End Sub
Private Sub ActionMacro()
On Error GoTo Err1
With Application
Run .CommandBars("Cell").Controls(1).Controls(.Caller(1)).Caption
End With
Exit Sub
Err1:
    MsgBox "Invalid"
End Sub

4, Կոդերը տեղադրելուց հետո կտտացրեք Գործիքներ > ՍայլակԵւ Հղումներ-VBAP նախագիծ ցուցադրվում է երկխոսության տուփը, ապա ստուգում Microsoft Visual Basic ծրագրերի ընդլայնում 5.3 տարբերակը Հասանելի հղումներ ցուցակի տուփ, տես նկարի նկարը.

5. Այնուհետեւ կտտացրեք OK երկխոսությունից դուրս գալու համար այժմ դուք պետք է պահեք այս աշխատանքային գիրքը որպես Excel մակրոներով աշխատունակ գիրք ձևաչափը, տես նկարի նկարը.

6, Վերջապես խնդրում ենք վերսկսել աշխատանքային գրքույկը ՝ ծածկագրերի ազդեցությունն ստանալու համար, և այժմ, երբ աջ կոճակի վրա կտտացնում եք բջիջին, ա Գործարկել մակրո տարբերակը տեղադրվում է աջ կտտոցի ընտրացանկում, և ձեր աշխատանքային գրքում բոլոր մակրոները նշված են ենթամենյուում ՝ որպես հետևյալ նկարներ.

7, Դրանից հետո դուք կարող եք գործարկել կոդը պարզապես սեղմելով այն: