Ինչպե՞ս ինքնաբերաբար լրացնել տեքստային տուփը Excel- ում մուտքագրելիս:

Լռելյայն, Excel- ը կարող է հիշել, թե ինչ եք մուտքագրել ընթացիկ աշխատանքային թերթի բջիջներում և հաջորդ անգամ ինքնալրացնել այս բովանդակությունը, երբ հարակից նախնական նամակը մուտքագրեք նոր բջիջ: Այնուամենայնիվ, եթե ուզում եք աշխատաթերթում մուտքագրած ձեր բոլոր բովանդակությունը դարձնել տեքստային տուփում (ActiveX Control) ինքնալրացման, ինչպե՞ս կարող եք անել: Այս հոդվածը կտրամադրի VBA եղանակ, որը կօգնի ձեզ տեքստային տուփը ավտոմատ կերպով լրացնելիս ներսում նախնական նամակ մուտքագրելիս:

VBA կոդով մուտքագրելիս տեքստային տուփը ավտոմատ կերպով լրացրեք

VBA կոդով մուտքագրելիս տեքստային տուփը ավտոմատ կերպով լրացրեք

Տեքստային տուփի ինքնալրացման համար տեքստային տուփի ավտոմատ լրացում կատարելու համար արեք հետևյալը.

1. Խնդրում ենք մուտքագրել տեքստային տուփ ՝ կտտացնելով Երեվակիչ > Տեղադրել > Տեքստային տուփ (ActiveX կառավարման), Տեսեք,

2. Եվ հետո կտտացրեք Երեվակիչ > Տեղադրել > Ցուցակի տուփ (ActiveX հսկողություն) ցուցակի վանդակը ներդնելու համար ընթացիկ աշխատանքային թերթը: Տեսեք,

3. Աջ կտտացրեք թերթիկի ներդիրին, ապա կտտացրեք Դիտել կոդը համատեքստային ընտրացանկից, ինչպես ցույց է տրված նկարի ներքևում:

4. Մեջ Microsoft Visual Basic հավելվածների համար պատուհանը, խնդրում ենք պատճենել և տեղադրեք ներքևում գտնվող VBA կոդի ծածկագիր կոդի պատուհանում: Եվ հետո կտտացրեք Գործիքներ > Սայլակ, ապա ստուգեք Microsoft Scripting Runtime տուփի մեջ Հղումներ - VBAP նախագիծ երկխոսության տուփ: Տեսեք,

VBA կոդ. Մուտքագրելիս ավտոմատ լրացնել տեքստային տուփը

Dim xRg As Range
Dim xDic As New Dictionary
Private Sub ListBox1_DblClick(ByVal Cancel As MSForms.ReturnBoolean)
    Me.TextBox1.Value = Me.ListBox1.Value
End Sub
Private Sub Worksheet_Change(ByVal Target As Range)
    Dim xVal As String
    On Error Resume Next
    If IsNumeric(Target.Value) Then
        xVal = Str(Target.Value)
    Else
        xVal = Target.Value
    End If
    If xVal <> "" Then
        If Not xDic.Exists(xVal) Then
            xDic.Add xVal, xVal
        End If
    End If
End Sub
Private Sub Worksheet_SelectionChange(ByVal Target As Range)
    Me.ListBox1.Visible = False
End Sub
Private Sub Worksheet_Activate()
    Dim I As Long
    Dim xStr As String
    On Error Resume Next
    If xRg Is Nothing Then
        Set xRg = ActiveSheet.UsedRange
    End If
    Me.ListBox1.Visible = False
    xDic.RemoveAll
    With Me.ListBox1
        For I = 1 To xRg.Count
            xStr = xRg(I).Value
            If xStr <> "" Then
                .AddItem xStr
                If Not xDic.Exists(xStr) Then
                    xDic.Add xStr, xStr
                End If
            End If
        Next
    End With
End Sub
Private Sub TextBox1_KeyUp(ByVal KeyCode As MSForms.ReturnInteger, ByVal Shift As Integer)
    With Me.ListBox1
        .Top = Me.TextBox1.Top
        .Left = Me.TextBox1.Left + Me.TextBox1.Width
        .Width = Me.TextBox1.Width
    End With
    TextBoxVal Me.TextBox1.Object
End Sub
Sub TextBoxVal(xTextBox As Variant)
    Dim I As Long
    Dim xStr As String
    On Error Resume Next
    Application.ScreenUpdating = False
    If xRg Is Nothing Then Exit Sub
    Me.ListBox1.Clear
    xStr = xTextBox.Value
    If xStr = "" Then
        Me.ListBox1.Visible = False
        Application.EnableEvents = True
        Exit Sub
    End If
    For I = 0 To UBound(xDic.Items)
        If Left(xDic.Items(I), Len(xStr)) = xStr Then
            Me.ListBox1.AddItem xDic.Items(I)
        End If
    Next
    Me.ListBox1.Visible = True
    If Me.ListBox1.ListCount > 0 Then
        With xTextBox
            .Value = Me.ListBox1.List(0)
            .SelStart = Len(xStr)
            .SelLength = Len(Me.ListBox1.List(0))
        End With
    End If
    Me.ListBox1.Activate
    Me.ListBox1.Selected(0) = True
    Application.ScreenUpdating = True
End Sub
Private Sub ListBox1_KeyDown(ByVal KeyCode As MSForms.ReturnInteger, ByVal Shift As Integer)
    If KeyCode = 13 Then
        Me.TextBox1.Value = Me.ListBox1.Value
    End If
End Sub

ՆշումԿոդում, ListBox1- ը և Տեքստային տուփ 1 ցուցակի վանդակի և տեքստի տուփի անունն են, որոնք դուք տեղադրել եք ձեր աշխատանքային էջում:

5. Սեղմեք ալտ + Q ստեղները դուրս գալու համար Microsoft Visual Basic հավելվածների համար պատուհան.

6. Անջատեք Դիզայնի ռեժիմը ՝ կտտացնելով Երեվակիչ > Դիզայնի ռեժիմ աշխատանքային թերթում:

7. Այժմ անցեք մեկ այլ աշխատանքային թերթի, ապա վերադառնաք նախորդ աշխատանքային թերթին ՝ VBA կոդն ակտիվացնելու համար:

Այսուհետեւ. Տեքստային տուփի մեջ սկզբնական նամակ մուտքագրելիս բոլոր տեքստերը, որոնք սկսվում են այդ տառով, որը դուք մուտքագրել եք աշխատաթերթը, կցուցադրվեն տուփի աջ կողմում գտնվող ցուցակի վանդակում: Խնդրում ենք կրկնակի սեղմել ձեր անհրաժեշտին `այն տեքստային տուփ մուտքագրելու համար: Տեսեք,

Նշում: Դուք կարող եք օգտագործել Up or Down սլաքի ստեղնը ցուցակի վանդակում գտնվող բոլոր ինքնալրացման տեքստերի միջև տեղափոխելու համար, ապա սեղմել Մտնել ստեղնը, որը անհրաժեշտ է մուտքագրել տեքստային տուփ:

Առնչվող հոդվածներ քանակը:

• Ինչպե՞ս ավտոմատ կերպով ընտրել տեքստային տուփի տեքստը, երբ այն ընտրված է Excel- ում:
• Ինչպե՞ս մաքրել տեքստային տուփի պարունակությունը Excel- ում կտտացնելիս:
• Ինչպե՞ս միացնել բազմաթիվ բջիջների տեքստերը Excel- ում տեքստային տուփի մեջ:
• Ինչպե՞ս անջատել խմբագրումը տեքստային տուփում `կանխելու համար օգտագործողի մուտքագրումը Excel- ում:
• Ինչպե՞ս ձևափոխել տեքստային տուփը որպես տոկոս Excel- ում: