Ինչպե՞ս պահպանել աշխատանքային թերթը որպես PDF ֆայլ և էլեկտրոնային փոստով ուղարկել այն որպես հավելված Outlook- ի միջոցով:

Որոշ դեպքերում կարող է անհրաժեշտ լինել Outlook- ի միջոցով աշխատանքային թերթ ուղարկել որպես PDF ֆայլ: Սովորաբար, դուք պետք է ձեռքով պահեք աշխատաթերթը որպես PDF ֆայլ, ապա այս PDF ֆայլով նոր էլփոստ ստեղծեք որպես կցորդ ձեր Outlook- ում և վերջապես ուղարկեք այն: Ձեռքով քայլ առ քայլ հասնելը ժամանակատար է: Այս հոդվածում մենք ձեզ ցույց կտանք, թե ինչպես արագ պահպանել աշխատանքային թերթը որպես PDF ֆայլ և այն ավտոմատ կերպով ուղարկել որպես հավելված Excel- ի Outlook- ի միջոցով:

Պահեք աշխատանքային թերթը որպես PDF ֆայլ և էլփոստով ուղարկեք այն որպես հավելված VBA կոդով

Պահեք աշխատանքային թերթը որպես PDF ֆայլ և էլփոստով ուղարկեք այն որպես հավելված VBA կոդով

Կարող եք գործարկել ստորև ներկայացված VBA կոդը ՝ ակտիվ աշխատանքային թերթը որպես PDF ֆայլ ինքնաբերաբար պահելու համար, այնուհետև ուղարկելով այն որպես հավելված Outlook- ի միջոցով: Խնդրում եմ, արեք հետևյալ կերպ.

1. Բացեք աշխատանքային թերթը, որը կփրկեք որպես PDF և ուղարկեք, ապա սեղմեք ալտ + F11 ստեղները միաժամանակ բացելու համար Microsoft Visual Basic հավելվածների համար պատուհան.

2. Մեջ Microsoft Visual Basic հավելվածների համար պատուհանը, սեղմեք Տեղադրել > Մոդուլներ, Դրանից հետո պատճենեք և տեղադրեք ներքևում նշված VBA կոդը ՝ Կոդ պատուհան Տեսեք,

VBA կոդ. Պահպանեք աշխատանքային թերթը որպես PDF ֆայլ և էլեկտրոնային փոստով ուղարկեք այն որպես հավելված

Sub Saveaspdfandsend()
Dim xSht As Worksheet
Dim xFileDlg As FileDialog
Dim xFolder As String
Dim xYesorNo As Integer
Dim xOutlookObj As Object
Dim xEmailObj As Object
Dim xUsedRng As Range

Set xSht = ActiveSheet
Set xFileDlg = Application.FileDialog(msoFileDialogFolderPicker)

If xFileDlg.Show = True Then
   xFolder = xFileDlg.SelectedItems(1)
Else
   MsgBox "You must specify a folder to save the PDF into." & vbCrLf & vbCrLf & "Press OK to exit this macro.", vbCritical, "Must Specify Destination Folder"
   Exit Sub
End If
xFolder = xFolder + "\" + xSht.Name + ".pdf"

'Check if file already exist
If Len(Dir(xFolder)) > 0 Then
    xYesorNo = MsgBox(xFolder & " already exists." & vbCrLf & vbCrLf & "Do you want to overwrite it?", _
                      vbYesNo + vbQuestion, "File Exists")
    On Error Resume Next
    If xYesorNo = vbYes Then
        Kill xFolder
    Else
        MsgBox "if you don't overwrite the existing PDF, I can't continue." _
                    & vbCrLf & vbCrLf & "Press OK to exit this macro.", vbCritical, "Exiting Macro"
        Exit Sub
    End If
    If Err.Number <> 0 Then
        MsgBox "Unable to delete existing file.  Please make sure the file is not open or write protected." _
                    & vbCrLf & vbCrLf & "Press OK to exit this macro.", vbCritical, "Unable to Delete File"
        Exit Sub
    End If
End If

Set xUsedRng = xSht.UsedRange
If Application.WorksheetFunction.CountA(xUsedRng.Cells) <> 0 Then
    'Save as PDF file 
    xSht.ExportAsFixedFormat Type:=xlTypePDF, Filename:=xFolder, Quality:=xlQualityStandard
    
    'Create Outlook email 
    Set xOutlookObj = CreateObject("Outlook.Application")
    Set xEmailObj = xOutlookObj.CreateItem(0)
    With xEmailObj
        .Display
        .To = ""
        .CC = ""
        .Subject = xSht.Name + ".pdf"
        .Attachments.Add xFolder
        If DisplayEmail = False Then
            '.Send
        End If
    End With
Else
  MsgBox "The active worksheet cannot be blank"
  Exit Sub
End If
End Sub

3. Սեղմեք F5 ծածկագիրը գործելու համար: Մեջ Թերթել երկխոսության տուփ, խնդրում ենք ընտրել պանակ ՝ այս PDF ֆայլը պահելու համար, ապա կտտացրեք OK կոճակը:

Notes:

Առնչվող հոդվածներ:

• Ինչպե՞ս պահպանել Excel ֆայլի անունը ժամանակային դրոշմակնիքով:
• Ինչպե՞ս օգտագործել Save As գործառույթը ՝ Excel- ում առկա ֆայլը ավտոմատ կերպով վերագրելու համար:
• Ինչպե՞ս պահպանել, արտահանել բազմաթիվ / բոլոր թերթերը Excel- ում առանձնացնել CSV կամ տեքստային ֆայլեր:
• Ինչպե՞ս անջատել կամ թույլ չտալ Excel- ում Save & Save As ընտրանքները:
• Ինչպե՞ս անջատել աշխատանքային գրքի պահպանումը, բայց միայն թույլատրել պահպանել, ինչպես Excel- ում: